dev-libs/libgweather: Version bump

Package-Manager: portage-2.3.0_rc1

dev-libs/libgweather/Manifest

@@ -1 +1,2 @@
 DIST libgweather-3.18.1.tar.xz 3430524 SHA256 94b2292f8f7616e2aa81b1516befd7b27682b20acecbd5d656b6954990ca7ad0 SHA512 1fc6fda3610bcb4efd0eae57ce8706f126301f5d8399ff765d00c9cc8a513150d07cd098bc53e372b338b7801bd003d651cea0f5832edb990197d456bc89370f WHIRLPOOL 19a7ec0d72f3f4740e7c1acfa83eaf6136e6523a094c6b70e85b3bafaed553e4fa6746fea31a10db888c29dc2556559dca7600be2d78b8c98f0a6d32af88bacf
+DIST libgweather-3.20.1.tar.xz 3423740 SHA256 81eb829fab6375cc9a4d448ae0f790e48f9720e91eb74678b22264cfbc8938d0 SHA512 4b9403b289d1d99e03aceb6207854369a5b92ea25a784aed322aed2b7e1e4c3b548e256e4222ea05206effb7de403b343031278503429433591496e50a708f23 WHIRLPOOL 2d943a7674f240e77656f1365c29926d44942ec87fa2785eb290dbd6b6bffbe1d99c3e6e8984175b01007d5a4df93ea9b4d9acc5abc27e93bde915d6e04bff0c

dev-libs/libgweather/libgweather-3.20.1.ebuild

@@ -0,0 +1,53 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="Library to access weather information from online services"
+HOMEPAGE="https://wiki.gnome.org/Projects/LibGWeather"
+
+LICENSE="GPL-2+"
+SLOT="2/3-6" # subslot = 3-(libgweather-3 soname suffix)
+IUSE="glade +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+
+COMMON_DEPEND="
+	>=x11-libs/gtk+-3.13.5:3[introspection?]
+	>=dev-libs/glib-2.35.1:2
+	>=net-libs/libsoup-2.44:2.4
+	>=dev-libs/libxml2-2.6.0
+	sci-geosciences/geocode-glib
+	>=sys-libs/timezone-data-2010k
+
+	glade? ( >=dev-util/glade-3.16:3.10 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<gnome-base/gnome-applets-2.22.0
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/gtk-doc-am-1.11
+	>=dev-util/intltool-0.50
+	>=sys-devel/gettext-0.18
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		$(use_enable glade glade-catalog) \
+		$(use_enable introspection) \
+		$(use_enable vala)
+}