mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 10:37:22 -08:00
dev-util/intel_clc: Version bump to 24.2.4
Signed-off-by: Matt Turner <mattst88@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST mesa-24.1.7.tar.xz 29206724 BLAKE2B b3102fcf96c032d07826186c2d60dc93e5c17b26f725c20cf1e402d1cfbaaba9809bff7a04d3df0179d2ec8606bc9fb391761d17a148671b9270cf2aaca0324d SHA512 890f6387963bbb86a85305ea963cca326a3b3f8f8758ae2082fd62c52df77c2883a359341e91f36614fea59219394ef78f799a334080699a0bb71d984a68cb01
|
||||
DIST mesa-24.2.3.tar.xz 29465732 BLAKE2B 3c480bd9f5948ae4d66a833cfc059b1b872fca989296a070deaa46aeb72298eaca6a3fa9d13574859623cec4a6af978f44d2c9562b9757be2257364c27600be6 SHA512 7a1ace23568d1907b778a2859f97c8988a414ba74e02e1fb5af6f95f768e1b1a2dfdaf412b0d655678ed915d28273953fd1236ebcd87553a1880f1a7f3ea4d44
|
||||
DIST mesa-24.2.4.tar.xz 29510040 BLAKE2B a0a977e5032e1c9a5b59dc9212d50b6f023fb9d42d325e692a3c680e77a06e2ccd66843b9eaeeadbf3614b65798c5c4649fb0bb74f134334e662ee9dd47ac21f SHA512 f0f1c23591cce85966efaf3988afdb14b64ceb7216b3994e8fc50e8ddc62c35a84b2013285c84080d963aec2afb94dac345f5f00e7ccf9ae7e9ab3f5b9ba0bcb
|
||||
|
||||
@@ -0,0 +1,93 @@
|
||||
# Copyright 2023-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
LLVM_COMPAT=( {16..18} )
|
||||
PYTHON_COMPAT=( python3_{10..13} )
|
||||
|
||||
inherit llvm-r1 meson python-any-r1
|
||||
|
||||
MY_PV="${PV/_/-}"
|
||||
|
||||
DESCRIPTION="intel_clc tool used for building OpenCL C to SPIR-V"
|
||||
HOMEPAGE="https://mesa3d.org/"
|
||||
|
||||
if [[ ${PV} == 9999 ]]; then
|
||||
S="${WORKDIR}/intel_clc-${MY_PV}"
|
||||
EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/mesa.git"
|
||||
inherit git-r3
|
||||
else
|
||||
S="${WORKDIR}/mesa-${MY_PV}"
|
||||
SRC_URI="https://archive.mesa3d.org/mesa-${MY_PV}.tar.xz"
|
||||
KEYWORDS="~amd64 ~x86"
|
||||
fi
|
||||
|
||||
LICENSE="MIT SGI-B-2.0"
|
||||
SLOT="0"
|
||||
IUSE="debug"
|
||||
|
||||
RDEPEND="
|
||||
dev-libs/libclc
|
||||
dev-util/spirv-tools
|
||||
>=sys-libs/zlib-1.2.8:=
|
||||
x11-libs/libdrm
|
||||
$(llvm_gen_dep '
|
||||
dev-util/spirv-llvm-translator:${LLVM_SLOT}
|
||||
sys-devel/clang:${LLVM_SLOT}=
|
||||
sys-devel/llvm:${LLVM_SLOT}=
|
||||
')
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
dev-libs/expat
|
||||
"
|
||||
BDEPEND="
|
||||
${PYTHON_DEPS}
|
||||
$(python_gen_any_dep "
|
||||
>=dev-python/mako-0.8.0[\${PYTHON_USEDEP}]
|
||||
dev-python/packaging[\${PYTHON_USEDEP}]
|
||||
dev-python/pyyaml[\${PYTHON_USEDEP}]
|
||||
")
|
||||
virtual/pkgconfig
|
||||
"
|
||||
|
||||
python_check_deps() {
|
||||
python_has_version -b ">=dev-python/mako-0.8.0[${PYTHON_USEDEP}]" &&
|
||||
python_has_version -b "dev-python/packaging[${PYTHON_USEDEP}]" &&
|
||||
python_has_version -b "dev-python/pyyaml[${PYTHON_USEDEP}]" || return 1
|
||||
}
|
||||
|
||||
pkg_setup() {
|
||||
llvm-r1_pkg_setup
|
||||
python-any-r1_pkg_setup
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
PKG_CONFIG_PATH="$(get_llvm_prefix)/$(get_libdir)/pkgconfig"
|
||||
|
||||
use debug && EMESON_BUILDTYPE=debug
|
||||
|
||||
local emesonargs=(
|
||||
-Dllvm=enabled
|
||||
-Dshared-llvm=enabled
|
||||
-Dintel-clc=enabled
|
||||
|
||||
-Dgallium-drivers=''
|
||||
-Dvulkan-drivers=''
|
||||
|
||||
# Set platforms empty to avoid the default "auto" setting. If
|
||||
# platforms is empty meson.build will add surfaceless.
|
||||
-Dplatforms=''
|
||||
|
||||
-Dglx=disabled
|
||||
-Dlibunwind=disabled
|
||||
-Dzstd=disabled
|
||||
|
||||
-Db_ndebug=$(usex debug false true)
|
||||
)
|
||||
meson_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
dobin "${BUILD_DIR}"/src/intel/compiler/intel_clc
|
||||
}
|
||||
Reference in New Issue
Block a user