app-editors/gedit-plugins: 3.30.1 → 3.32.2

Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Sobhan Mohammadpour <sobhan@gentoo.org>

app-editors/gedit-plugins/Manifest

@@ -1 +1,2 @@
 DIST gedit-plugins-3.30.1.tar.xz 1354644 BLAKE2B ee42fb2fe47c9219442e0bbdaf21a14a834b8bc38558713ccf0ad384814812fd71f4d318624b4d2c149b26d304203a2b954ef49c3299877f4d067ae181bfe1d5 SHA512 0e777779288b51015d7ab539bf896a00d5226560f2cc2211daf777da87824eed858255318c421524933a540135e4bfdcc294ba7ed89f680a35aa48f7279cbc94
+DIST gedit-plugins-3.32.2.tar.xz 1474264 BLAKE2B feb116ec201b9eb9630570818cc288f0044ecfc174fc84c7d812aa6dfba5cc3748b4e2351ffa2be0d3a593a58b2318c4296b54b84476fc887195ee27f27bb597 SHA512 2767bc766daba5e1c81ef5a00bc3589a301c02e0286a6622cf11a03b5b391ecbcf9456187563dad4f2916610ee9ddca4414ff4beb639820954385ee3f8091d2a

app-editors/gedit-plugins/gedit-plugins-3.32.2.ebuild

@@ -0,0 +1,93 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+GNOME2_LA_PUNT="yes" # plugins are dlopened
+PYTHON_COMPAT=( python3_{5,6} )
+PYTHON_REQ_USE="xml"
+VALA_MIN_API_VERSION="0.28"
+
+inherit eutils gnome2 multilib python-single-r1 vala
+
+DESCRIPTION="Official plugins for gedit"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gedit/ShippedPlugins"
+
+LICENSE="GPL-2+"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+
+IUSE_plugins="charmap git terminal vala"
+IUSE="+python ${IUSE_plugins}"
+# python-single-r1 would request disabling PYTHON_TARGETS on libpeas
+REQUIRED_USE="
+	charmap? ( python )
+	git? ( python )
+	python? ( ${PYTHON_REQUIRED_USE} )
+	terminal? ( python )
+"
+
+RDEPEND="
+	>=app-editors/gedit-3.16
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/libpeas-1.7.0[gtk]
+	>=x11-libs/gtk+-3.9:3
+	>=x11-libs/gtksourceview-4.0.2:4
+	python? (
+		${PYTHON_DEPS}
+		>=app-editors/gedit-3.16[introspection,python,${PYTHON_USEDEP}]
+		dev-libs/libpeas[python,${PYTHON_USEDEP}]
+		>=dev-python/dbus-python-0.82[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+		>=x11-libs/gtk+-3.9:3[introspection]
+		>=x11-libs/gtksourceview-3.14:3.0[introspection]
+		x11-libs/pango[introspection]
+		x11-libs/gdk-pixbuf:2[introspection]
+	)
+	charmap? ( >=gnome-extra/gucharmap-3:2.90[introspection] )
+	git? ( >=dev-libs/libgit2-glib-0.0.6 )
+	terminal? ( >=x11-libs/vte-0.52:2.91[introspection] )
+	vala? ( $(vala_depend) )
+" # vte-0.52+ for feed_child API compatibility
+DEPEND="${RDEPEND}
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use python && [[ ${MERGE_TYPE} != binary ]] && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable python) \
+		$(use_enable vala)
+}
+
+src_install() {
+	gnome2_src_install
+
+	# FIXME: crazy !!!
+	if use python; then
+		find "${ED}"/usr/share/gedit -name "*.py*" -delete || die
+		find "${ED}"/usr/share/gedit -type d -empty -delete || die
+	fi
+
+	# FIXME: upstream made this automagic...
+	clean_plugin charmap
+	clean_plugin git
+	clean_plugin terminal
+}
+
+clean_plugin() {
+	if use !${1} ; then
+		rm -rf "${ED}"/usr/share/gedit/plugins/${1}*
+		rm -rf "${ED}"/usr/$(get_libdir)/gedit/plugins/${1}*
+	fi
+}