app-misc/khard: Bump to 0.19.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

app-misc/khard/Manifest

@@ -1 +1,2 @@
 DIST khard-0.18.0.tar.gz 602016 BLAKE2B 856190b5972c6b912977a69a4786779d59fafbdea1bc323c8ca8af56c7ce33e09efbe58734db261437ea0e654a8457086174becedb76dacf802f975847e03c63 SHA512 eb1e82b5350febdd388b251514562a2d3776d5f5c8b3c70cd73153eaedc7ac3504b25d88179eced26c96ced90785fac9267cc23b2425fac816c233a2e1f2b9df
+DIST khard-0.19.1.tar.gz 605230 BLAKE2B d0b0186c3006aa44dbdbf61afb81a2e9dbe0f2ecc439d2ebcd1ba33620dbb4f11bf8146e127f8cc8dc18db490b65d4bb1f2dde3962748f0570cf9f529d394ae5 SHA512 619678902abee2561f2cef8d525d9688269f9f4da244b1c5cf97a9c2f15f5d08f80d09bc08304dfe3a7ca44dd5082e0152c5dce82063b6f98ea12b961b34bdf4

app-misc/khard/khard-0.19.1.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+inherit distutils-r1
+
+DESCRIPTION="Console CardDAV client"
+HOMEPAGE="
+	https://github.com/lucc/khard
+	https://pypi.org/project/khard/
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+
+if [[ "${PV}" == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lucc/khard"
+else
+	inherit pypi
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+RDEPEND="
+	dev-python/atomicwrites[${PYTHON_USEDEP}]
+	dev-python/configobj[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml-clib[${PYTHON_USEDEP}]
+	dev-python/unidecode[${PYTHON_USEDEP}]
+	dev-python/vobject[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	)
+	doc? (
+		dev-python/sphinx-autoapi
+		dev-python/sphinx-rtd-theme
+		dev-python/sphinx-autodoc-typehints
+	)
+"
+
+DOCS=(
+	CHANGES
+	CONTRIBUTING.rst
+	README.md
+	doc/source/examples/khard.conf.example
+)
+
+distutils_enable_tests unittest
+distutils_enable_sphinx docs \
+	dev-python/sphinx-autoapi \
+	dev-python/sphinx-autodoc-typehints
+
+python_compile_all() {
+	use doc && emake -j1 -C doc/ html text man info
+}
+
+python_install_all() {
+	if use doc; then
+		DOCS+=( doc/build/text/. )
+		HTML_DOCS+=( doc/build/html/. )
+
+		doman doc/build/man/*
+		doinfo doc/build/texinfo/*.info
+	fi
+
+	insinto /usr/share/zsh/site-functions
+	doins misc/zsh/_khard
+
+	distutils-r1_python_install_all
+}