dev-python/argon2-cffi-bindings: Added v21.2.0

Closes: https://bugs.gentoo.org/827890
Signed-off-by: Michael Seifert <m.seifert@digitalernachschub.de>
Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/argon2-cffi-bindings/Manifest

@@ -0,0 +1 @@
+DIST argon2-cffi-bindings-21.2.0.tar.gz 1779911 BLAKE2B 3e2e2252e37678661502ca15425196b91a7952d0bb5c7ae4ed35132e9085fbbe5d817c9c1bdec7d94eb583ab6baf9d1e1e454a24415bde1408287c5606745fb9 SHA512 71d023ae96073ed78599e4f4e42f8efcc985cc329adeea00b14b54eaac1e6a545e6ad9b7f4cfdc60a4e9c396f95053c0ccb6f6f67d92f70265f91315fff4a390

dev-python/argon2-cffi-bindings/argon2-cffi-bindings-21.2.0.ebuild

@@ -0,0 +1,34 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Low-level CFFI bindings for the Argon2 password hashing library"
+HOMEPAGE="https://github.com/hynek/argon2-cffi-bindings"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cpu_flags_x86_sse2"
+
+DEPEND="app-crypt/argon2:="
+BDEPEND="virtual/python-cffi[${PYTHON_USEDEP}]"
+RDEPEND="
+	${DEPEND}
+	${BDEPEND}
+"
+
+DOCS=( CHANGELOG.md README.md )
+
+distutils_enable_tests pytest
+
+src_configure() {
+	export ARGON2_CFFI_USE_SYSTEM=1
+	# We cannot call usex in global scope, so we invoke it in src_configure
+	export ARGON2_CFFI_USE_SSE2=$(usex cpu_flags_x86_sse2 1 0)
+	distutils-r1_src_configure
+}

dev-python/argon2-cffi-bindings/metadata.xml

@@ -0,0 +1,20 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person" proxied="yes">
+    <email>m.seifert@digitalernachschub.de</email>
+    <name>Michael Seifert</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <maintainer type="project" proxied="proxy">
+    <email>proxy-maint@gentoo.org</email>
+    <name>Proxy Maintainers</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="pypi">argon2-cffi-bindings</remote-id>
+    <remote-id type="github">hynek/argon2-cffi-bindings</remote-id>
+  </upstream>
+</pkgmetadata>