app-emacs/org-mode: drop old 9.7.37

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

app-emacs/org-mode/Manifest

@@ -1,3 +1,2 @@
-DIST org-mode-9.7.37.tar.xz 1715336 BLAKE2B 262945343a3ab09f3d4c0737bf0afbb6283937efcd927187d8d8f3a6b7c255bfe65e0dd7acf4d9228141b02481301f2a397cdb72d6f692979e9de7cd201e8f76 SHA512 1a6714d80643021a0e8a0b6e2975680aa299e33653e45fc73502fba4522d58f05512a5bfc42b9d494750dbafe6035a2990775b5b2c704d8982067560043e77c8
 DIST org-mode-9.7.38.tar.xz 1715364 BLAKE2B c60bea04c24149cd06b093c1a2483952b3457085507c116baebdf4c03c77fc02b5f2968fcbca5f330984a8a8dcbacb80f4ee81ef160c5c2d8376ec6c74544f35 SHA512 bbb4c297eb17d0e0d938b2e6fb296d5536aed46a78fbb09c518d10df0fdad9c6766588a9730491eabecd25a85afb89b10b888bc837d5a47c0011756f4ba18c8f
 DIST org-mode-9.7.39.tar.xz 1715308 BLAKE2B 9b9845efc3ac34ebe031ebe86801fe48faacf60e6e070ebbcec94cbc041e36e74c3fa7a8571ffdb86f2f039c1f8e69a2cb2f2fc89b69e764e6f326b65b2269eb SHA512 1c82ba36ccd4229d719a6553b200d6c6d5b4986962793327f1234aa82ada4b17d096a83c7f1322d04e8ae5fa3a7042a41e0a0c47c3569f1ad7ec0282cf128349

app-emacs/org-mode/org-mode-9.7.37.ebuild

@@ -1,81 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit elisp readme.gentoo-r1
-
-DESCRIPTION="An Emacs mode for notes and project planning"
-HOMEPAGE="https://orgmode.org/"
-
-if [[ "${PV}" == 9999 ]] ; then
-	inherit git-r3
-
-	EGIT_REPO_URI="https://git.savannah.gnu.org/git/emacs/${PN}"
-	EGIT_CHECKOUT_DIR="${WORKDIR}/org"
-	S="${WORKDIR}/org"
-else
-	# git archive --prefix=${P}/ release_${PV} | xz > ${P}.tar.xz
-	SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~riscv ~x86"
-fi
-
-LICENSE="GPL-3+ FDL-1.3+ CC-BY-SA-3.0 odt-schema? ( OASIS-Open )"
-SLOT="0"
-IUSE="doc odt-schema"
-
-BDEPEND="
-	doc? (
-		virtual/texi2dvi
-	)
-"
-
-DOCS=( README.org CONTRIBUTE.org etc/ORG-NEWS )
-SITEFILE="50${PN}-gentoo.el"
-
-src_prepare() {
-	elisp_src_prepare
-
-	# Remove failing tests.
-	rm ./testing/lisp/test-{ob,ob-exp,ob-tangle,ob-shell,org,org-clock}.el \
-		|| die "failed to remove some test files"
-
-	EMAKEARGS=(
-		ORGVERSION="${PV}"
-		ETCDIRS="styles csl $(use odt-schema && echo schema)"
-		lispdir="${EPREFIX}${SITELISP}/${PN}"
-		datadir="${EPREFIX}${SITEETC}/${PN}"
-		infodir="${EPREFIX}/usr/share/info"
-	)
-}
-
-src_compile() {
-	emake -j1 "${EMAKEARGS[@]}"
-
-	if use doc ; then
-		emake -j1 pdf
-		emake -j1 card
-	fi
-}
-
-src_test() {
-	local -x LANG="C"
-
-	emake -j1 "${EMAKEARGS[@]}" TEST_NO_AUTOCLEAN="TRUE" test-dirty
-}
-
-src_install() {
-	if use doc ; then
-		DOCS+=( doc/org.pdf doc/orgcard.pdf doc/orgguide.pdf )
-	fi
-
-	emake -j1 "${EMAKEARGS[@]}" DESTDIR="${D}" install
-	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
-	einstalldocs
-
-	local DOC_CONTENTS="Org mode has a large variety of run-time dependencies,
-		so you may have to install one or more additional packages.
-		A non-exhaustive list of these dependencies may be found at
-		<http://orgmode.org/worg/org-dependencies.html>."
-	readme.gentoo_create_doc
-}