media-video/mediainfo: version bump to 18.03

media-video/mediainfo/Manifest

@@ -1 +1,2 @@
 DIST mediainfo_17.12.tar.xz 1335676 BLAKE2B 66bf02f74a63b40446cb061fe6422c84d61cb10db53394a7b356e0c0b76a7c934548bf75a8e8e5556a3fab2bd2f65c2a8c3d57040bd404e5258f0cfa4f87bbd9 SHA512 3fd6c8538c7703e657c6c20fec3ba071e5575f6010f41188bdd46749ecad9bddfa2362a5f0df6c23aa98375bb9078f14704b0729d1c54174449871992b968ff9
+DIST mediainfo_18.03.tar.xz 1328024 BLAKE2B 3d304d7894b02f0f9355217b4c3a3f26a85e88d7be7c66a16ad8a8995421a51cf32c6f0f358aa7fbf246a1deb710cecec13a1be3f1700247c132b248624a414f SHA512 c4ed389c9d6a918196d3337fd5f50229e9e3b565745fc328462de7e0fe3a55496300ef5e2f784027669ff6f2428c5d573c5941eb0b26276dca6dc93a1286fbc1

media-video/mediainfo/mediainfo-18.03.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+WX_GTK_VER="3.0"
+
+inherit gnome2-utils xdg-utils autotools wxwidgets
+
+DESCRIPTION="MediaInfo supplies technical and tag information about media files"
+HOMEPAGE="https://mediaarea.net/mediainfo/ https://github.com/MediaArea/MediaInfo"
+SRC_URI="https://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl mms wxwidgets"
+
+RDEPEND="sys-libs/zlib
+	>=media-libs/libzen-0.4.37
+	~media-libs/lib${P}[curl=,mms=]
+	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/MediaInfo
+
+pkg_setup() {
+	TARGETS="CLI"
+	use wxwidgets && TARGETS+=" GUI"
+}
+
+src_prepare() {
+	eapply_user
+
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target} || die
+		sed -i -e "s:-O2::" configure.ac || die
+		eautoreconf
+	done
+}
+
+src_configure() {
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target} || die
+		local args=""
+		[[ ${target} == "GUI" ]] && args="--with-wxwidgets --with-wx-gui"
+		econf ${args}
+	done
+}
+
+src_compile() {
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target} || die
+		default
+	done
+}
+src_install() {
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target} || die
+		default
+		dodoc "${S}"/History_${target}.txt
+	done
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}