kde-apps/lokalize: 22.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/lokalize/Manifest

@@ -1,2 +1,3 @@
 DIST lokalize-21.08.3.tar.xz 2045936 BLAKE2B aa57ea5428db59d58352306b9aab2a79eb37e7d62a49132b440e23209f51e5c433d61282326e9d51e66f6770f609fcaa2322c57bcfaaed8183d90e8500705409 SHA512 d4368ccab3cbe3ea360fbd97f099dcbb46caaa4fe6595d7426ff94d34c2023b99dcee62e3634e54e0dc39e02768993b9c414982a2c6c061b230c33a5f337d6ff
 DIST lokalize-21.12.3.tar.xz 2062092 BLAKE2B 2f5d635198d5b9e926afb90bfb89b80df5f18b1afae6eb3d83cf17d50e097b1c8e9ef0555922573ad34a044fa9e8fe4992957462dadb622437d24f07561f8b0a SHA512 f7564cfd726cb925d329223a46b9fa54f11cc86e420c70eda05ed2563f6bc44e39e682861eb9748c625833be1a1c6efd2e17c79f87a0ff90e000f2ae5af8304a
+DIST lokalize-22.04.0.tar.xz 2064648 BLAKE2B 409ec6d798fab909e137a50257fb037284b8864a768bbacd6b384b8806797ebb2c4b827022f92bb610f61aeb0b02ad522773ed6ac1a2685650a4db8c4f1f919c SHA512 732b15f7152b13947f399c147df3eea4afcf8a63053e95fd738d5f6ff083b3703d67cb8e490fd164829148f5d349a4ba94842df71baeec2c4e6bfb8afb1e6dba

kde-apps/lokalize/lokalize-22.04.0.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+PYTHON_COMPAT=( python3_{8..10} )
+KFMIN=5.92.0
+QTMIN=5.15.2
+inherit python-single-r1 ecm kde.org optfeature
+
+DESCRIPTION="Localization tool for KDE software and other free and open source software"
+HOMEPAGE="https://apps.kde.org/lokalize/ https://l10n.kde.org/tools/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="test" # tests are broken, bug 739734
+
+DEPEND="${PYTHON_DEPS}
+	>=app-text/hunspell-1.2.8:=
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5[sqlite]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/translate-toolkit[${PYTHON_USEDEP}]
+	')
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_install() {
+	ecm_src_install
+	rm "${ED}"/usr/share/lokalize/scripts/msgmerge.{py,rc} || die
+	python_fix_shebang "${ED}"/usr/share/${PN}
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "autofetch kde.org translations in new project wizard" dev-vcs/subversion
+		optfeature "spell and grammar checking" app-text/languagetool
+	fi
+	ecm_pkg_postinst
+}