app-xemacs/ebuild-mode: add 1.81

Signed-off-by: Ulrich Müller <ulm@gentoo.org>

app-xemacs/ebuild-mode/Manifest

@@ -1 +1,2 @@
 DIST ebuild-mode-1.80.tar.xz 51640 BLAKE2B fa9d42898131f0f62a51bb0b172b2ab076aafb8e6d999eb58c3f328bdadd698909589aa9cd58fbb9a166d4441414762a15be841133aa1b9c08354db41cdd2df6 SHA512 8b22a8a8f012e24410e419e28d42d1b38b016fc392390270baea0e26fc101207b0c727787b57f01b61e9cc3b149390fca08e75e651dc76dfb35b80574d650d3f
+DIST ebuild-mode-1.81.tar.xz 52380 BLAKE2B b088e0e40e73c3eb1d8b0584a13e581cda1f1e7fc65050c0a1dd3e25fa81baf554efbf8719e5987794387d4a85c7a012bef50e9dbc109cdf4b3cddc9c7d65035 SHA512 3817f99037a4f143a5016c0bb8f895bc96e3330dd3eb698bbaf65767bcebcb6a06edc3f769dc6abef59296ec13e1e2f8d637deb390120b008d273992f2e840d1

app-xemacs/ebuild-mode/ebuild-mode-1.81.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit optfeature
+
+if [[ ${PV} = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/ebuild-mode.git"
+	EGIT_BRANCH="master"
+	EGIT_CHECKOUT_DIR="${WORKDIR}/${PN}"
+	S="${WORKDIR}/${PN}"
+else
+	SRC_URI="https://dev.gentoo.org/~ulm/emacs/${P}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Emacs modes for editing ebuilds and other Gentoo specific files"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Emacs"
+
+LICENSE="GPL-2+"
+SLOT="0"
+
+RDEPEND=">=app-editors/xemacs-21.5.35
+	app-xemacs/sh-script
+	app-xemacs/tty-format"
+BDEPEND="${RDEPEND}"
+
+EMACS="${EPREFIX}/usr/bin/xemacs"
+EMACSFLAGS="-batch -q -no-site-file"
+
+src_compile() {
+	${EMACS} ${EMACSFLAGS} \
+		-eval "(add-to-list 'load-path nil)" \
+		-f batch-byte-compile \
+		ebuild-mode.el gentoo-newsitem-mode.el || die
+
+	${EMACS} ${EMACSFLAGS} \
+		-eval "(setq autoload-package-name \"${PN}\")" \
+		-eval "(setq generated-autoload-file \"${S}/auto-autoloads.el\")" \
+		-l autoload -f batch-update-autoloads \
+		ebuild-mode.el gentoo-newsitem-mode.el || die
+}
+
+src_test() {
+	emake check EMACS="${EMACS}" EMACSFLAGS="${EMACSFLAGS}"
+}
+
+src_install() {
+	insinto /usr/lib/xemacs/site-packages/lisp/${PN}
+	doins ebuild-mode.{el,elc} ebuild-mode-keywords.el \
+		gentoo-newsitem-mode.{el,elc} ebuild-mode-kw-gen.el \
+		auto-autoloads.el
+}
+
+pkg_postinst() {
+	optfeature "ebuild commands support" sys-apps/portage
+	optfeature "additional development tools" dev-util/pkgdev
+	optfeature "ebuild QA utilities" dev-util/pkgcheck
+}