dev-util/pkgdev: add 0.2.10

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-util/pkgdev/Manifest

@@ -1 +1,2 @@
+DIST pkgdev-0.2.10.tar.gz 85476 BLAKE2B 2002daa38d445f90cbc2f17ad0e42045b32b5dcefdd85a3485b6e253d9703ad7e59119873718259874de32e7c50e4f5acbacc6c3b40770d55f4d38dbbd7805c4 SHA512 aa9f6465ba44ff67f2b160bc9249583c355e7cc807ce4c797cc8b6d2a4858414a82e702e47ff5b87dc0f6ba70b9c83d515c59a732406437e5325aa3ae7ff95aa
 DIST pkgdev-0.2.9.tar.gz 85237 BLAKE2B db50d7f29313830986443e8e3b3fe6ae202049b1a25b3537de407d13ef7b547a8bc25afe5b520ac29b616e9dba8029d0a50a917f84728473f53a7621b8b7dcc9 SHA512 ff534eaa3ad039998541d7e4bbe39d9bece0a2401652880826c7639829efec3db38bc37352ea1c901121a0092a83518b803e14b484b08ba62462046d51bc81c7

dev-util/pkgdev/pkgdev-0.2.10.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..12} )
+inherit distutils-r1 optfeature
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_BRANCH="main"
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/pkgcore/pkgdev.git
+		https://github.com/pkgcore/pkgdev.git"
+	inherit git-r3
+else
+	inherit pypi
+	KEYWORDS="amd64 arm arm64 hppa ~ia64 ~loong ppc ppc64 ~riscv sparc x86 ~x64-macos"
+fi
+
+DESCRIPTION="Collection of tools for Gentoo development"
+HOMEPAGE="https://github.com/pkgcore/pkgdev"
+
+LICENSE="BSD MIT"
+SLOT="0"
+IUSE="doc"
+
+if [[ ${PV} == *9999 ]] ; then
+	RDEPEND="
+		~dev-python/snakeoil-9999[${PYTHON_USEDEP}]
+		~dev-util/pkgcheck-9999[${PYTHON_USEDEP}]
+		~sys-apps/pkgcore-9999[${PYTHON_USEDEP}]
+	"
+else
+	RDEPEND="
+		>=dev-python/snakeoil-0.10.5[${PYTHON_USEDEP}]
+		>=sys-apps/pkgcore-0.12.23[${PYTHON_USEDEP}]
+		>=dev-util/pkgcheck-0.10.25[${PYTHON_USEDEP}]
+	"
+fi
+
+RDEPEND+="
+	dev-vcs/git
+"
+BDEPEND="
+	>=dev-python/flit-core-3.8[${PYTHON_USEDEP}]
+	>=dev-python/snakeoil-0.10.5[${PYTHON_USEDEP}]
+	test? (
+		x11-misc/xdg-utils
+	)
+"
+
+distutils_enable_sphinx doc \
+	">=dev-python/snakeoil-0.10.5" \
+	dev-python/tomli
+distutils_enable_tests pytest
+
+python_compile_all() {
+	use doc && emake PYTHON="${EPYTHON}" man
+
+	sphinx_compile_all # HTML pages only
+}
+
+python_install_all() {
+	# If USE=doc, there'll be newly generated docs which we install instead.
+	if use doc || [[ ${PV} != *9999 ]]; then
+		doman build/sphinx/man/*
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "sending email support" x11-misc/xdg-utils
+	optfeature "tatt subcommand" "app-portage/nattka dev-python/jinja"
+}