dev-python/pygame: Bump to 2.1.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/pygame/Manifest

@@ -1 +1,2 @@
 DIST pygame-2.1.2.gh.tar.gz 6100415 BLAKE2B 4b81c2f0abc2c2c4732ddb8f8e6d4bffa5169e3d3ee2d9ea2798d294623a9c70e2ff004825030606285124ef1347177b46adc676db450785e8420de45f37db34 SHA512 531cb0371853def7a3ddb8eb0110fbd58acaf1b2351d7518402c9a960baca705bb34da879015e7a6cd5f2f8af98c57e7bc732021a8f62ed9f90cacf068c9c2d6
+DIST pygame-2.1.3.gh.tar.gz 6517003 BLAKE2B 9f2062b24ef2e97995207fbf7572a8aa4d3475356e8646356758ad72b0b744fcf911adaa78bb730ed43c95fa23b8ed733a5573882bd83e112ae5e7e6ef099de9 SHA512 28f46826f58f73607b28c1411c6f2b71796cd4f98103df2dd47db842f578fe7f26dac01cb60d1cb00ac9dacfa62c6c3b913a244379ce70bd03265424e29052e6

dev-python/pygame/pygame-2.1.3.ebuild

@@ -0,0 +1,91 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for SDL multimedia library"
+HOMEPAGE="
+	https://www.pygame.org/
+	https://github.com/pygame/pygame/
+	https://pypi.org/project/pygame/
+"
+SRC_URI="
+	https://github.com/pygame/pygame/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="examples opengl test X"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	media-libs/freetype
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng:=
+	media-libs/portmidi
+	media-libs/sdl2-image
+	media-libs/sdl2-mixer
+	media-libs/sdl2-ttf
+	X? ( media-libs/libsdl2[opengl?,threads,video,X] )
+	!X? ( media-libs/libsdl2[threads] )
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		media-libs/sdl2-image[gif,jpeg,png,tiff,webp]
+		media-libs/sdl2-mixer[mp3,vorbis,wav]
+	)
+"
+# fontconfig used for fc-list
+RDEPEND+="
+	media-libs/fontconfig
+"
+# util-linux provides script
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		media-libs/fontconfig
+		sys-apps/util-linux
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/pygame-2.1.2-libsdl2-2.26-tests.patch
+)
+
+python_configure() {
+	PORTMIDI_INC_PORTTIME=1 LOCALBASE="${EPREFIX}/usr" \
+		"${EPYTHON}" "${S}"/buildconfig/config.py || die
+}
+
+python_configure_all() {
+	find src_c/cython -name '*.pyx' -exec touch {} + || die
+	"${EPYTHON}" setup.py cython_only || die
+}
+
+python_test() {
+	local -x PYTHONPATH=${BUILD_DIR}/install/lib
+	local -x SDL_VIDEODRIVER=dummy
+	local -x SDL_AUDIODRIVER=disk
+	script -eqc "${EPYTHON} -m pygame.tests -v" || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Bug #497720
+	rm -fr "${D}$(python_get_sitedir)"/pygame/{docs,examples,tests}/ || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use examples && dodoc -r examples
+}