mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-20 10:17:08 -08:00
dev-python/simsimd: Bump to 5.2.1
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST SimSIMD-5.1.4.gh.tar.gz 149847 BLAKE2B 49aa9cfcee079b415d504989345be48c0b055e34dabd69240fdc02a35f51da81f25ab78fa27831e411d3853bca8b586314eae6840068715ec6a9c76c874162d6 SHA512 a656a71076d35c62cebe3d0cb2fc5eae87d9f13cb7a4427d74cb2959e813b4ff387ec30fe9a68e72e529fd0a76de468178652da1bba3b164eeb9f34df7d5d410
|
||||
DIST SimSIMD-5.2.0.gh.tar.gz 150001 BLAKE2B 6ec61f5f2253782e747658bb52cc0858208912a46eafe87c5a613e9d5924b585243734538b84c3d74d5b755db3907044e2f1b264ea3c28f9605288fba321099c SHA512 8c387c2f7ebd8dcda677a8e4d312528db9cdc7e87ffa9c203f37d8429893b9e5b332c827b8d3f76e216fc17042389d3a548eff074c5b604eaece1d4f8f614264
|
||||
DIST SimSIMD-5.2.1.gh.tar.gz 153081 BLAKE2B 2454d2266ca6d1b3302f4bf347dcc85d5c0750561e7d34906d5e7e2303e4cd0a7279d10f3065a63eeb14aedc6cd584510d29f29e60f7f57cd178a3066a4e28b8 SHA512 8263aada695ce68a1eb671c46a294fd317f9bb5d3a3ec5b4a8ab27b8b8ea5801c639b6bac3ba889bd6153444c76b7fa6d2982c25003af4cdfd0d8bc007b783f8
|
||||
|
||||
@@ -0,0 +1,63 @@
|
||||
# Copyright 2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
DISTUTILS_EXT=1
|
||||
DISTUTILS_USE_PEP517=setuptools
|
||||
PYTHON_COMPAT=( pypy3 python3_{10..13} )
|
||||
|
||||
inherit distutils-r1 toolchain-funcs
|
||||
|
||||
MY_P=SimSIMD-${PV}
|
||||
DESCRIPTION="Fastest SIMD-Accelerated Vector Similarity Functions for x86 and Arm"
|
||||
HOMEPAGE="
|
||||
https://github.com/ashvardanian/SimSIMD/
|
||||
https://pypi.org/project/simsimd/
|
||||
"
|
||||
# no sdist, as of 4.3.1
|
||||
# https://github.com/ashvardanian/SimSIMD/issues/113
|
||||
SRC_URI="
|
||||
https://github.com/ashvardanian/SimSIMD/archive/v${PV}.tar.gz
|
||||
-> ${MY_P}.gh.tar.gz
|
||||
"
|
||||
S=${WORKDIR}/${MY_P}
|
||||
|
||||
LICENSE="Apache-2.0"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64"
|
||||
IUSE="openmp"
|
||||
|
||||
BDEPEND="
|
||||
test? (
|
||||
dev-python/pytest-repeat[${PYTHON_USEDEP}]
|
||||
)
|
||||
"
|
||||
|
||||
distutils_enable_tests pytest
|
||||
|
||||
pkg_pretend() {
|
||||
if [[ ${MERGE_TYPE} != binary ]] && use openmp; then
|
||||
tc-check-openmp
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_setup() {
|
||||
if [[ ${MERGE_TYPE} != binary ]] && use openmp; then
|
||||
tc-check-openmp
|
||||
fi
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
sed -i -e '/-O3/d' setup.py || die
|
||||
if ! use openmp; then
|
||||
sed -i -e '/-fopenmp/d' setup.py || die
|
||||
fi
|
||||
|
||||
distutils-r1_src_prepare
|
||||
}
|
||||
|
||||
python_test() {
|
||||
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
|
||||
epytest -p repeat python/test.py
|
||||
}
|
||||
Reference in New Issue
Block a user