dev-util/nihtest: add 1.5.1

Signed-off-by: Alexander Miller <alex.miller@gmx.de>
Closes: https://github.com/gentoo/gentoo/pull/35801
Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-util/nihtest/Manifest

@@ -1 +1,2 @@
 DIST nihtest-1.5.0.tar.gz 39258 BLAKE2B 6f2bf228d080a705ac9c7a56e7f73cd6000e03fae09dc9076eb7c9003f8cd9629690ccc2860c7939461edc089f8e73419232ed08bc131f9b526f141b434f33f8 SHA512 aac6167c18b5af3f49f5b43b6a218f3f3921d5b0bfe74df546a6808cf826debbe587de44b04baf1d4abd8e0c193da1b86a1f6490cc6bd7888b7707e261a1ebcf
+DIST nihtest-1.5.1.tar.gz 39866 BLAKE2B 6e499db71d894e6fe3a5bcd2fe42b89c588edbec451b4c580feac1e07fe7b3cfa9e658dd52d21b0bda3a13be305a240698654eba672b22d9593af7a7335081ff SHA512 269b21c6e4baf2c00b01e799394361631f96a7876c5df7f08e8d97ab640312f77251b5024804cb66a3aa5cb5dd0e43f8e54eb4644d985038fe25de24de30f93a

dev-util/nihtest/nihtest-1.5.1.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit cmake distutils-r1 pypi
+
+DESCRIPTION="A testing tool for command line utilities"
+HOMEPAGE="
+	https://nih.at/nihtest/
+	https://github.com/nih-at/nihtest
+	https://pypi.org/project/nihtest/
+"
+SRC_URI+="
+	https://nih.at/nihtest/${P}.tar.gz
+	https://github.com/nih-at/nihtest/releases/download/v${PV}/${P}.tar.gz
+"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	$(python_gen_cond_dep 'dev-python/python-dateutil[${PYTHON_USEDEP}]')
+"
+BDEPEND="test? ( ${RDEPEND} )"
+
+DOCS=( NEWS.md README.md TODO.md )
+
+src_prepare() {
+	distutils-r1_src_prepare
+	if use test; then
+		CMAKE_USE_DIR=${S}/tests
+		BUILD_DIR=${WORKDIR}/tests_build cmake_src_prepare
+	fi
+}
+
+python_test() {
+	local BUILD_DIR=${WORKDIR}/tests_build
+	local mycmakeargs=( -DNIHTEST=nihtest )
+	cmake_src_configure
+	cmake_src_compile
+	cmake_src_test
+}
+
+src_install() {
+	distutils-r1_src_install
+	newman manpages/nihtest.man nihtest.1
+	newman manpages/nihtest.conf.man nihtest.conf.5
+	newman manpages/nihtest-case.man nihtest-case.5
+}