mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 10:37:22 -08:00
gnome-extra/gnome-software: Version bump to 43.4
Signed-off-by: Guillermo Joandet <gjoandet@gmail.com> Closes: https://github.com/gentoo/gentoo/pull/29524 Signed-off-by: Matt Turner <mattst88@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST gnome-software-43.2.tar.xz 2356928 BLAKE2B 07cc787cc3320f84bc29164c40da8d600f011e1a1d8645be6089375f13658772562061e100f6347fa2019cc21cf27b71bd4c050fcc2850a2bb56d1160e849141 SHA512 d011418536706d2c5693581bd322008b5eb0fdf766ec96f1775135efb0fecec42dbc126ea2a66465b2169afb38b48fed1246516197e3bbf9d75b96e339d6ba33
|
||||
DIST gnome-software-43.3.tar.xz 2367044 BLAKE2B 29b3f104b0ecc6b03c95147f93776ec453bd259da923c40eb2b79827503b48099e4694ac877ee7ed6e5226bab4dd47a3dc71c1212f345eae425b8e72f2bf4d99 SHA512 e80c57d75a1805897913c6e5216c610556cbee2617a3e44dd83c366d10b8ae05ffe5f2ac79490ff77bb7a6f8c25ae91477543da26fa3f7794de01ba93ab26591
|
||||
DIST gnome-software-43.4.tar.xz 2367068 BLAKE2B 9da461876c275a68f75dc5cab15dab1620b084f85115f0695f084f4f85469ede67168feca2123c3303170fbefc00eee59097cca66441c3e01ab3d569fea2c4ec SHA512 3e4c8d29569238ffa116beb8e711f05172572b9b31de7d6f5ff1e26465c9f5be97e465f44ea2f6889e1a6c2b626a2de13b99d2e348a4ef150dca3d56c84ab5cd
|
||||
|
||||
@@ -0,0 +1,102 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit gnome.org gnome2-utils meson virtualx xdg
|
||||
|
||||
DESCRIPTION="Gnome install & update software"
|
||||
HOMEPAGE="https://wiki.gnome.org/Apps/Software https://gitlab.gnome.org/GNOME/gnome-software"
|
||||
|
||||
LICENSE="GPL-2+"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~x86"
|
||||
IUSE="flatpak +firmware gnome gtk-doc sysprof udev test"
|
||||
|
||||
RDEPEND="
|
||||
>=dev-libs/appstream-0.14.0:0=
|
||||
>=x11-libs/gdk-pixbuf-2.32.0:2
|
||||
>=dev-libs/libxmlb-0.1.7:=
|
||||
>=gui-libs/gtk-4.6:4
|
||||
>=dev-libs/glib-2.70.0:2
|
||||
>=dev-libs/json-glib-1.6.0
|
||||
>=net-libs/libsoup-3.0:3.0
|
||||
>=gui-libs/libadwaita-1.0.1:1
|
||||
sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 )
|
||||
gnome? ( >=gnome-base/gsettings-desktop-schemas-3.18.0 )
|
||||
sys-auth/polkit
|
||||
firmware? ( >=sys-apps/fwupd-1.5.6 )
|
||||
flatpak? (
|
||||
>=sys-apps/flatpak-1.14.0-r1
|
||||
dev-util/ostree
|
||||
)
|
||||
udev? ( dev-libs/libgudev )
|
||||
>=gnome-base/gsettings-desktop-schemas-3.11.5
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
test? ( dev-libs/libglib-testing )
|
||||
"
|
||||
BDEPEND="
|
||||
dev-libs/libxml2:2
|
||||
dev-util/gdbus-codegen
|
||||
>=sys-devel/gettext-0.19.8
|
||||
virtual/pkgconfig
|
||||
gtk-doc? (
|
||||
dev-util/gtk-doc
|
||||
app-text/docbook-xml-dtd:4.3
|
||||
)
|
||||
"
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
xdg_environment_reset
|
||||
|
||||
sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
|
||||
# We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
|
||||
sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local emesonargs=(
|
||||
$(meson_use test tests)
|
||||
$(meson_feature gnome gsettings_desktop_schemas) # Honoring of GNOME date format settings.
|
||||
-Dman=true
|
||||
-Dpackagekit=false
|
||||
# -Dpackagekit_autoremove
|
||||
-Dpolkit=true
|
||||
-Deos_updater=false # Endless OS updater
|
||||
$(meson_use firmware fwupd)
|
||||
$(meson_use flatpak)
|
||||
-Dmalcontent=false
|
||||
-Drpm_ostree=false
|
||||
-Dwebapps=true
|
||||
-Dhardcoded_foss_webapps=true
|
||||
-Dhardcoded_proprietary_webapps=true
|
||||
$(meson_use udev gudev)
|
||||
-Dapt=false
|
||||
-Dsnap=false
|
||||
-Dexternal_appstream=false
|
||||
$(meson_use gtk-doc gtk_doc)
|
||||
-Dhardcoded_curated=true
|
||||
-Ddefault_featured_apps=false # TODO: Will this be beneficial to us with flatpak at least? If enabled, it shows some apps under installed (probably merely due to /usr/share/app-info presence), but launching and removal of them is broken
|
||||
-Dmogwai=false #TODO?
|
||||
$(meson_feature sysprof)
|
||||
-Dprofile=''
|
||||
-Dsoup2=false
|
||||
)
|
||||
meson_src_configure
|
||||
}
|
||||
|
||||
src_test() {
|
||||
virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
gnome2_schemas_update
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
xdg_pkg_postrm
|
||||
gnome2_schemas_update
|
||||
}
|
||||
Reference in New Issue
Block a user