net-dns/pdns: Version bump

Package-Manager: Portage-2.3.14, Repoman-2.3.6
Signed-off-by: Sven Wegener <swegener@gentoo.org>
This commit is contained in:
Sven Wegener
2017-11-27 18:20:58 +00:00
parent 1fff78c89b
commit 6efc2fac85
2 changed files with 154 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST pdns-4.0.4.tar.bz2 1320327 BLAKE2B 5c11a0245408f8448b41ed4229718e6f7244e0c8f36b60b07c280f82c7dea0065cce93c3814b3a396666be8d3b012ad4eb646cf55f531d22ce325190e0fd6e22 SHA512 4ef4705cd990b03976775167c7c37850d45907e198549feda5f5701172e008e3f1f74a35a9bebdb24b63dec15ff63cb2cc9dfc8f92e4e1012e0539c5a88b845b
DIST pdns-4.0.5.tar.bz2 1323468 BLAKE2B 7e10cc98177bfa4f81888e2598ab4f0ce83ee45e6349372c065940424a74015302da879536dea8346fe7b86f35c0524a5449489bdf71d1a091b7c6a82fac4b6f SHA512 4b0fa932c1d9caf35b988916447aa21c64ebe2a58bdd84417cf09321a21b264cf1057206dc6993a45a3b591eb1dfa49463710c06b6bdfaf6fb17ae6dec6086d9
DIST pdns-4.1.0-rc3.tar.bz2 1112366 BLAKE2B 8ac9d351ffee81a859b68bc66e989ce4c91804ab134ada3e090aed982df31191f5bfc83f7174873ab34b2a1b6be21f2c938874d94ea0e166b060453b746eec13 SHA512 19485bf95a68cbe2ac4cc826b44c3a8670f66cedc2ab426c589a3f67d96f70bd6dd297bd95301c29cda10ff9a7e429fa702bdc7368ce08862140d7097013ea7f
+153
View File
@@ -0,0 +1,153 @@
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
inherit eutils multilib user toolchain-funcs versionator
DESCRIPTION="The PowerDNS Daemon"
HOMEPAGE="https://www.powerdns.com/"
SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
# other possible flags:
# db2: we lack the dep
# oracle: dito (need Oracle Client Libraries)
# xdb: (almost) dead, surely not supported
IUSE="botan debug doc geoip ldap libressl lua luajit mydns mysql opendbx postgres protobuf remote sqlite systemd tools tinydns test"
REQUIRED_USE="mydns? ( mysql ) ?? ( lua luajit )"
RDEPEND="
libressl? ( dev-libs/libressl:= )
!libressl? ( dev-libs/openssl:= )
>=dev-libs/boost-1.35:=
botan? ( dev-libs/botan:2= )
lua? ( dev-lang/lua:= )
luajit? ( dev-lang/luajit:= )
mysql? ( virtual/mysql )
postgres? ( dev-db/postgresql:= )
ldap? ( >=net-nds/openldap-2.0.27-r4 )
sqlite? ( dev-db/sqlite:3 )
opendbx? ( dev-db/opendbx )
geoip? ( >=dev-cpp/yaml-cpp-0.5.1 dev-libs/geoip )
tinydns? ( >=dev-db/tinycdb-0.77 )
protobuf? ( dev-libs/protobuf )"
DEPEND="${RDEPEND}
virtual/pkgconfig
doc? ( app-doc/doxygen )"
S="${WORKDIR}"/${P/_/-}
src_configure() {
local dynmodules="pipe bind" # the default backends, always enabled
#use db2 && dynmodules+=" db2"
use ldap && dynmodules+=" ldap"
use lua && dynmodules+=" lua"
use mydns && dynmodules+=" mydns"
use mysql && dynmodules+=" gmysql"
use opendbx && dynmodules+=" opendbx"
#use oracle && dynmodules+=" goracle oracle"
use postgres && dynmodules+=" gpgsql"
use remote && dynmodules+=" remote"
use sqlite && dynmodules+=" gsqlite3"
use tinydns && dynmodules+=" tinydns"
use geoip && dynmodules+=" geoip"
#use xdb && dynmodules+=" xdb"
econf \
--disable-static \
--sysconfdir=/etc/powerdns \
--libdir=/usr/$(get_libdir)/powerdns \
--with-modules= \
--with-dynmodules="${dynmodules}" \
--with-pgsql-includes=/usr/include \
--with-pgsql-lib=/usr/$(get_libdir) \
--with-mysql-lib=/usr/$(get_libdir) \
$(use_enable botan) \
$(use_enable debug verbose-logging) \
$(use_enable test unit-tests) \
$(use_enable tools) \
$(use_enable systemd) \
$(use_with lua) \
$(use_with luajit) \
$(use_with protobuf) \
${myconf}
}
src_compile() {
default
use doc && emake -C codedocs codedocs
}
src_install() {
default
mv "${D}"/etc/powerdns/pdns.conf{-dist,}
fperms 0700 /etc/powerdns
fperms 0600 /etc/powerdns/pdns.conf
# set defaults: setuid=pdns, setgid=pdns
sed -i \
-e 's/^# set\([ug]\)id=$/set\1id=pdns/g' \
"${D}"/etc/powerdns/pdns.conf
newinitd "${FILESDIR}"/pdns-r1 pdns
keepdir /var/empty
use doc && dohtml -r codedocs/html/.
# Install development headers
insinto /usr/include/pdns
doins pdns/*.hh
insinto /usr/include/pdns/backends/gsql
doins pdns/backends/gsql/*.hh
if use ldap ; then
insinto /etc/openldap/schema
doins "${FILESDIR}"/dnsdomain2.schema
fi
prune_libtool_files --all
}
pkg_preinst() {
enewgroup pdns
enewuser pdns -1 -1 /var/empty pdns
}
pkg_postinst() {
elog "PowerDNS provides multiple instances support. You can create more instances"
elog "by symlinking the pdns init script to another name."
elog
elog "The name must be in the format pdns.<suffix> and PowerDNS will use the"
elog "/etc/powerdns/pdns-<suffix>.conf configuration file instead of the default."
if use ldap ; then
ewarn "The official LDAP backend module is only compile-tested by upstream."
ewarn "Try net-dns/pdns-ldap-backend if you have problems with it."
fi
local old
for old in ${REPLACING_VERSIONS}; do
version_compare ${old} 3.2
[[ $? -eq 1 ]] || continue
ewarn "To fix a security bug (bug #458018) had the following"
ewarn "files/directories the world-readable bit removed (if set):"
ewarn " ${EPREFIX}/etc/powerdns"
ewarn " ${EPREFIX}/etc/powerdns/pdns.conf"
ewarn "Check if this is correct for your setup"
ewarn "This is a one-time change and will not happen on subsequent updates."
chmod o-rwx "${EPREFIX}"/etc/powerdns/{,pdns.conf}
break
done
}