xfce-extra/xfce4-screensaver: Bump to 4.18.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-extra/xfce4-screensaver/Manifest

@@ -1,3 +1,4 @@
 DIST xfce4-screensaver-4.16.0-mem.patch 3265 BLAKE2B 38436c7c2047453109702fd54aee874dfb489819024e61899b807ea98686bdd491e578b65be89dfbd53ee89976bb215790df4fce6559f7ee4f5ff92b449374fe SHA512 dc9e289aa91ea4a5b65d2381bfabdbb48a6b07c67782afc53b003ffd2a07c0d225f4bb2ea48bcd478f14ab4c29a2521a0436085b40589e5a059e5561f7bcb42d
 DIST xfce4-screensaver-4.16.0.tar.bz2 687978 BLAKE2B 1656027af61a50ab97fd3d5744f0ab5f1a81353c64a2fd935a6113dbe2fce5c4b2a22c5f81f15d06d09c3b292f82afa95ce34a07facb5fffef7e6fef712cae63 SHA512 5fa0381395b48fdfb5bdd9b4cafe1ec625d0b7fb9600d59c22c42fe0248fb4b99dd18a94045df3ecdc77635f7271676329c658f25003a9d8d6f9a9a66739dbe9
 DIST xfce4-screensaver-4.18.0.tar.bz2 705730 BLAKE2B 190ef60167abe41021e2140ca9efcb8a2021c6e5f18f2ffb81aae1e8e9efee5a2b4da968f96d135ac74255281f8079c5705ac2fbf2d535f0bc14d56562b9a1cc SHA512 06d32c81411d41f96d5fd822e31fb8f256193114b7e60472a32ecb5f369c14780dfcd316c1698904c46c90713e25fd42b947357d3bf5edf65a25fc3a7cdaa45c
+DIST xfce4-screensaver-4.18.1.tar.bz2 706002 BLAKE2B 2976c977d0ad1f292564e257dbfa01ab90ed5ae5a02fb93aa247363e81bdd60407ddd4cfbe8ccae0f37cffc03d37151ac77a7857fbd8b3d0ce6c6278b488550f SHA512 5b9fab018db6f933480e6da4a3b62fab0c3744f657db76df0631ac2468c20f5169c54a0b09bfa59b3311357a8effcddc40ba49d6baa2b5fec6c5815e72c63701

xfce-extra/xfce4-screensaver/xfce4-screensaver-4.18.1.ebuild

@@ -0,0 +1,92 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="Screen saver and locker (port of MATE screensaver)"
+HOMEPAGE="
+	https://docs.xfce.org/apps/screensaver/start
+	https://gitlab.xfce.org/apps/xfce4-screensaver/
+"
+SRC_URI="
+	https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2
+"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="elogind +locking opengl pam systemd"
+
+# Xrandr: optional but automagic
+DEPEND="
+	>=dev-libs/dbus-glib-0.30
+	>=dev-libs/glib-2.50:2
+	>=x11-libs/gtk+-3.22:3
+	>=x11-libs/libwnck-3.20:3
+	x11-libs/libICE:=
+	x11-libs/libX11:=
+	x11-libs/libXScrnSaver:=
+	x11-libs/libXext:=
+	x11-libs/libXxf86vm:=
+	>=x11-libs/libXrandr-1.3:=
+	>=x11-libs/libxklavier-5.2:=
+	>=xfce-base/garcon-0.5.0:=
+	>=xfce-base/libxfce4ui-4.12.1:=
+	>=xfce-base/libxfce4util-4.12.1:=
+	>=xfce-base/xfconf-4.12.1:=
+	elogind? ( sys-auth/elogind )
+	locking? (
+		pam? ( sys-libs/pam )
+	)
+	opengl? ( virtual/opengl )
+	systemd? ( sys-apps/systemd:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-util/glib-utils
+	dev-util/intltool
+	sys-apps/dbus
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		# disable docbook for now
+		ac_cv_path_XMLTO=no
+
+		# xscreensaver dirs autodetection doesn't seem to work
+		--with-xscreensaverdir=/usr/share/xscreensaver/config
+		--with-xscreensaverhackdir=/usr/$(get_libdir)/misc/xscreensaver
+		--without-console-kit
+
+		$(use_with opengl libgl)
+		$(use_enable locking)
+		$(use_enable pam)
+		$(use_with elogind)
+		$(use_with systemd)
+	)
+
+	if use pam; then
+		myconf+=( --with-pam-auth-type=system )
+	fi
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}