dev-libs/libgweather: drop 4.2.0

Signed-off-by: Mart Raudsepp <leio@gentoo.org>
This commit is contained in:
Mart Raudsepp
2024-03-03 00:40:38 +02:00
parent 87a590f88a
commit 6e2008bbf3
2 changed files with 0 additions and 89 deletions
-1
View File
@@ -1,2 +1 @@
DIST libgweather-4.2.0.tar.xz 2752164 BLAKE2B 9cc51363d6a2a09497269760701e0e0c1beb68c0096262fb6e2885414f838b41c151df7b057def457fdd49f9036d853ab624a9683a5cf57bbdefaed5376fe69f SHA512 cd95c6714575c0afc52455bb99c9116af27716868648debe0e5309904cfaf7516cf2379e415b3d9dd57b5dd223bae8e8acbaf705a3867dad8f75aec22eea908e
DIST libgweather-4.4.0.tar.xz 2808680 BLAKE2B d3bfabd7936a5dc5f6f77cbb5acb3a7b80cebe1f08ff48582e1609cad04051ce8b84959c27576c928233e4625db8831c99d049378908cbe562b48221b6f37392 SHA512 dd232d36b168132a7c7cf06ffff16e88eb6e3e9e003e39b975df3d294ada401ab7d34de386dcc53452de6b0f8c68ff7f0cf6a94492e353828e00d4a1204b5d00
@@ -1,88 +0,0 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
DESCRIPTION="Location and timezone database and weather-lookup library"
HOMEPAGE="https://wiki.gnome.org/Projects/LibGWeather"
LICENSE="GPL-2+"
SLOT="4/4-0" # subslot = 4-(libgweather-4 soname suffix)
IUSE="gtk-doc +introspection test +vala"
RESTRICT="!test? ( test )"
REQUIRED_USE="
vala? ( introspection )
gtk-doc? ( introspection )
"
KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux"
RDEPEND="
>=dev-libs/glib-2.68.0:2
>=net-libs/libsoup-2.99.2:3.0
sci-geosciences/geocode-glib:2
>=dev-libs/libxml2-2.6.0:2
dev-libs/json-glib
introspection? ( >=dev-libs/gobject-introspection-1.54:= )
"
DEPEND="${RDEPEND}"
BDEPEND="
dev-util/glib-utils
gtk-doc? ( >=dev-util/gi-docgen-2021.6 )
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
${PYTHON_DEPS}
$(python_gen_any_dep 'dev-python/pygobject[${PYTHON_USEDEP}]')
vala? ( $(vala_depend) )
"
python_check_deps() {
python_has_version -b "dev-python/pygobject[${PYTHON_USEDEP}]"
}
pkg_setup() {
python-any-r1_pkg_setup
}
src_prepare() {
default
gnome2_environment_reset
use vala && vala_setup
# The metar test requires network access
if has network-sandbox ${FEATURES}; then
sed -i -e '/metar/d' libgweather/tests/meson.build || die
fi
}
src_configure() {
local emesonargs=(
$(meson_use vala enable_vala)
$(meson_use gtk-doc gtk_doc)
$(meson_use introspection)
$(meson_use test tests)
-Dsoup2=false
)
meson_src_configure
}
src_install() {
meson_src_install
if use gtk-doc; then
mkdir -p "${ED}"/usr/share/gtk-doc/ || die
mv "${ED}"/usr/share/doc/libgweather-4.0 "${ED}"/usr/share/gtk-doc/ || die
fi
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}