mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-08 18:27:07 -08:00
sys-apps/fwupd: Bump to version 1.2.10
Package-Manager: Portage-2.3.69, Repoman-2.3.16 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
This commit is contained in:
Lars Wendler
@@ -1,2 +1,3 @@
|
||||
DIST fwupd-1.2.10.tar.gz 1943920 BLAKE2B 5aec740c777d8749901ee35915f3510998b7477d2964ea4adc7079d12702e971a4eb0c4eef1b5c0fec0b34ba5e3fc82c25d7df7800b5bc0aa3d10229370a958e SHA512 4d311d2ed5fbe06e1a8fb22d77e67823f58debd3465dc973945c98746ae00f137d15a0e46e93fa3529b4d8a157558339295f82cacdab9d79c83514300b3b6a22
|
||||
DIST fwupd-1.2.8.tar.gz 1911999 BLAKE2B 61a24ce24f778b96f7ad23496890f7a1d20c09e6bbd707f29d154992668d5c0a25cfd31b5d0d11519740e086c098cbdfd440fe9f5cab4dde0ac43fe6b438e911 SHA512 d603f9f4e5a4c0fc6abb0b75f7d884eff47fb8a16285aa545f7140fe98ce781d127ff3769f9c206bb3bfd084bbc5bf6abf9424f70e727ff79162416fe7881154
|
||||
DIST fwupd-1.2.9.tar.gz 1938008 BLAKE2B 6a16c8e3a2c94dfbe9485d3ed57f3908fa2d7bcd95ac122d4b08e9a869706c01483132015f06cfa3076c861fec903740bed83b7ef763ac9b20147673a25a54a1 SHA512 942c6bad822dc65846d1984850798bec677b6a312100c6f5971fc9d5906c182267182ef29e0834bbd2b83fe72b11c3b6e50855d90388d2bf85e8a3b95d0a5a68
|
||||
|
||||
@@ -0,0 +1,142 @@
|
||||
# Copyright 1999-2019 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
PYTHON_COMPAT=( python3_{5,6,7} )
|
||||
|
||||
inherit meson python-single-r1 vala xdg-utils
|
||||
|
||||
DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
|
||||
HOMEPAGE="https://fwupd.org"
|
||||
SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
|
||||
|
||||
LICENSE="LGPL-2.1+"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~x86"
|
||||
IUSE="agent colorhug consolekit dell doc elogind +gpg +man nvme pkcs7 redfish systemd test thunderbolt uefi"
|
||||
|
||||
REQUIRED_USE="${PYTHON_REQUIRED_USE}
|
||||
^^ ( consolekit elogind systemd )
|
||||
dell? ( uefi )
|
||||
"
|
||||
|
||||
RDEPEND="${PYTHON_DEPS}
|
||||
app-arch/gcab
|
||||
app-arch/libarchive:=
|
||||
dev-db/sqlite
|
||||
>=dev-libs/glib-2.45.8:2
|
||||
dev-libs/json-glib
|
||||
dev-libs/libgpg-error
|
||||
dev-libs/libgudev:=
|
||||
>=dev-libs/libgusb-0.2.9[introspection]
|
||||
>=dev-libs/libxmlb-0.1.7
|
||||
dev-python/pillow[${PYTHON_USEDEP}]
|
||||
dev-python/pycairo[${PYTHON_USEDEP}]
|
||||
dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
|
||||
>=net-libs/libsoup-2.51.92:2.4[introspection]
|
||||
>=sys-auth/polkit-0.103
|
||||
virtual/libelf:0=
|
||||
colorhug? ( >=x11-misc/colord-1.2.12:0= )
|
||||
consolekit? ( >=sys-auth/consolekit-1.0.0 )
|
||||
dell? (
|
||||
sys-libs/efivar
|
||||
>=sys-libs/libsmbios-2.4.0
|
||||
)
|
||||
elogind? ( sys-auth/elogind )
|
||||
gpg? (
|
||||
app-crypt/gpgme
|
||||
dev-libs/libgpg-error
|
||||
)
|
||||
nvme? ( sys-libs/efivar )
|
||||
pkcs7? ( >=net-libs/gnutls-3.4.4.1:= )
|
||||
redfish? ( sys-libs/efivar )
|
||||
systemd? ( >=sys-apps/systemd-211 )
|
||||
thunderbolt? ( sys-apps/thunderbolt-software-user-space )
|
||||
uefi? (
|
||||
media-libs/fontconfig
|
||||
media-libs/freetype
|
||||
sys-boot/gnu-efi
|
||||
>=sys-libs/efivar-33
|
||||
x11-libs/cairo
|
||||
)
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
$(vala_depend)
|
||||
x11-libs/pango[introspection]
|
||||
nvme? ( >=sys-kernel/linux-headers-4.4 )
|
||||
test? ( net-libs/gnutls[tools] )
|
||||
"
|
||||
BDEPEND="
|
||||
>=dev-util/meson-0.47.0
|
||||
virtual/pkgconfig
|
||||
doc? ( dev-util/gtk-doc )
|
||||
man? (
|
||||
app-text/docbook-sgml-utils
|
||||
sys-apps/help2man
|
||||
)
|
||||
"
|
||||
|
||||
# required for fwupd daemon to run.
|
||||
# NOT a build time dependency. The build system does not check for dbus.
|
||||
PDEPEND="sys-apps/dbus"
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
sed -e "s/'--create'/'--absolute-name', '--create'/" \
|
||||
-i data/tests/builder/meson.build || die
|
||||
sed -e "/'-Werror',/d" \
|
||||
-i plugins/uefi/efi/meson.build || die
|
||||
vala_src_prepare
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
xdg_environment_reset
|
||||
local emesonargs=(
|
||||
--localstatedir "${EPREFIX}"/var
|
||||
-Dagent="$(usex agent true false)"
|
||||
-Dconsolekit="$(usex consolekit true false)"
|
||||
-Dgtkdoc="$(usex doc true false)"
|
||||
-Delogind="$(usex elogind true false)"
|
||||
-Dgpg="$(usex gpg true false)"
|
||||
-Dman="$(usex man true false)"
|
||||
-Dpkcs7="$(usex pkcs7 true false)"
|
||||
-Dplugin_dell="$(usex dell true false)"
|
||||
# Requires libflashrom which our sys-apps/flashrom
|
||||
# package does not provide
|
||||
-Dplugin_flashrom="false"
|
||||
# Dependencies are not available (yet?)
|
||||
-Dplugin_modem_manager="false"
|
||||
-Dplugin_nvme="$(usex nvme true false)"
|
||||
-Dplugin_redfish="$(usex redfish true false)"
|
||||
-Dplugin_synaptics="$(usex dell true false)"
|
||||
-Dplugin_thunderbolt="$(usex thunderbolt true false)"
|
||||
-Dplugin_uefi="$(usex uefi true false)"
|
||||
-Dsystemd="$(usex systemd true false)"
|
||||
-Dtests="$(usex test true false)"
|
||||
)
|
||||
|
||||
meson_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
meson_src_install
|
||||
|
||||
sed "s@%SEAT_MANAGER%@$(usex elogind elogind consolekit)@" \
|
||||
"${FILESDIR}"/${PN}-r1 \
|
||||
> "${T}"/${PN} || die
|
||||
doinitd "${T}"/${PN}
|
||||
|
||||
if ! use systemd ; then
|
||||
# Don't timeout when fwupd is running (#673140)
|
||||
sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
|
||||
-i "${ED}"/etc/${PN}/daemon.conf || die
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
elog "In case you are using openrc as init system"
|
||||
elog "and you're upgrading from <fwupd-1.1.0, you"
|
||||
elog "need to start the fwupd daemon via the openrc"
|
||||
elog "init script that comes with this package."
|
||||
}
|
||||
Reference in New Issue
Block a user