net-irc/irssi: add 1.4.4

Bug: https://bugs.gentoo.org/903623
Closes: https://bugs.gentoo.org/903145
Signed-off-by: Marcel van den Bosch <m.v.d.bosch@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/30551
Signed-off-by: Sam James <sam@gentoo.org>

net-irc/irssi/Manifest

@@ -1,2 +1,3 @@
 DIST irssi-1.4.2.tar.xz 1211740 BLAKE2B 916028948640d264707bf4c8405fe63ee2781b0990abc40c4d60c5fd34bebe38de7d35cf6856c69dab39121ba5d72c962b763fda408cb81326392edc8447d3a8 SHA512 428157b85226b5299f55679d9384d3ae8b1e61f50a528bf21ffdf2f4b56014e0a86bdcf9ce05cf4dedd59d53829323bb62029a570f90ebf3243a06c3ce220caf
 DIST irssi-1.4.3.tar.xz 1212556 BLAKE2B 48091e26bf547e510814d2ce709e2000771b75112fe5706ee328c6436659b7f0157f24058d508fae791175e1ff92de67224412fec18376fefc64a847d4e3bf6d SHA512 d9122180990965e701deb37f212a1ef60fd697ba24c827c2bb15dcd7c4f7f4caf02f6dd99cb5a0cf0b2682325b93ecfd0f00adb296ad832b5a95953ea08567f5
+DIST irssi-1.4.4.tar.xz 1213784 BLAKE2B 5b77ca692130a87228eea05f9a8d2da65a7c483e031d8c12dbd29bb9cd629444aae28bc3ffe0dc862891f59047997a323cea3b4d9d388573d4f06b569abbf950 SHA512 da28ac7a527be301d0615d6d733e4cf4e09bb6d4f5c70bc33ff70e22439a01f197bb5d91b4432ca74d3ac2dbb3235f30d53efc63a4279de8664923c2ccdbdbea

net-irc/irssi/irssi-1.4.4.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+GENTOO_DEPEND_ON_PERL="no"
+inherit perl-module meson
+
+DESCRIPTION="A modular textUI IRC client with IPv6 support"
+HOMEPAGE="https://irssi.org/"
+
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+	inherit git-r3
+else
+	# Keep for _rc compability
+	MY_P="${P/_/-}"
+
+	SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV/_/-}/${MY_P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="otr +perl selinux +proxy"
+
+RDEPEND="
+	>=dev-libs/glib-2.6.0
+	dev-libs/openssl:=
+	sys-libs/ncurses:=
+	otr? (
+		>=dev-libs/libgcrypt-1.2.0:=
+		>=net-libs/libotr-4.1.0
+	)
+	perl? ( dev-lang/perl:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-lang/perl
+	virtual/pkgconfig"
+RDEPEND+=" selinux? ( sec-policy/selinux-irc )"
+
+src_configure() {
+	local emesonargs=(
+		-Ddocdir="${EPREFIX}"/usr/share/doc/${PF}
+		-Dwith-perl-lib=vendor
+		-Dwith-otr=$(usex otr)
+		-Dwith-proxy=$(usex proxy)
+		-Dwith-perl=$(usex perl)
+
+		# Carried over from autotools (for now?), bug #677804
+		-Ddisable-utf8proc=yes
+		-Dwith-fuzzer=no
+		-Dinstall-glib=no
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	# We don't want perl-module's src_test
+	meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	use perl && perl_delete_localpod
+}