dev-python/django: Bump to 4.2.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/django/Manifest

@@ -4,3 +4,5 @@ DIST Django-4.1.10.checksum.txt 2559 BLAKE2B 103d1de6ec0da3a2440ea339388e2525ef5
 DIST Django-4.1.10.tar.gz 10513572 BLAKE2B 0f1ef14fcf40cb6952fc459855a4e633e2d21c252a4732b27f8e980af6277ef69869a65a7bd0508fd7cdbd82742cb838170d965219b2919679ac92abfef087b6 SHA512 f31ad6fcce3bea0e0f895ec14b063485edec70872aa9c317243a38fb49b6c863159afc5aa31fb5c7a824c737f520f25cfbef55781c23fa0a204b61cefc66fb01
 DIST Django-4.2.3.checksum.txt 2549 BLAKE2B 8cd57d91bc05c4ae7c5fad7682668cb132c587cff63871173a7f3e9f9adada203544b93e017f743b7c7916ec97b4d7bb7bac06d1c875410a8836c49ea1627774 SHA512 d8e9c3f90fccfddb6b0284fc37d22e67476e49f58f80151e70d2640ed311e9657ab8aa60eebd509751b24c2f4102f33d496460a335f1adbba4ee0082d2d5c2fe
 DIST Django-4.2.3.tar.gz 10419003 BLAKE2B 393cf4d01865a6ff84de5d18860bedea6a28c8df9e1a3769026b308215e9373bf2c8d86e75914d76e2d104b5c1411aff0757682e0129b1dbef29a5dd3836bbc6 SHA512 33c84a3fe16f8188a2c8090177d6bfd235004271ee1cee9c840e33dd22f60e0d54276c0dbc4127faaba82ae7d6a219a07c5638b19c701c3f36db238d2aae33f0
+DIST Django-4.2.4.checksum.txt 2571 BLAKE2B 062b53fc43bc12343a11161904c8938fe852f8868c4de6282f567b495992ce06494d327b495b03c8dc92cccf76396efe4b12dfbd0616d2b3c58c2e6239760e63 SHA512 0d4599816935645f141d1267b6ca22db238b614576c7225da9ba2cc84957e5668be25654a10a1bfc715e9e6e355db9a6f824dc11303fcb14af10a60a056950d4
+DIST Django-4.2.4.tar.gz 10393648 BLAKE2B 1c0c19f58bc3e02d12593b942eca23f5eaf8ee5106f6d518d97fad46f0c65dcdd94b192142969d95be9537fb1cca08a0ca55e089702d8bd51122f381adc0a319 SHA512 e773a54ce6ad82abfac462f543c54e414c216ecb28025fab9bf92e4f1add4fbc9acf831e765b638f560a71f6d7591eaa1a8ed6175c3379d5662a94b6a64f2c77

dev-python/django/django-4.2.4.ebuild

@@ -0,0 +1,98 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://github.com/django/django/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	<dev-python/asgiref-4[${PYTHON_USEDEP}]
+	>=dev-python/asgiref-3.6.0[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.3.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20230606 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/django-4.0-bashcomp.patch
+	"${FILESDIR}"/django-4.2.3-py312.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+}