kde-frameworks/extra-cmake-modules: 6.3.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-frameworks/extra-cmake-modules/Manifest

@@ -1,2 +1,3 @@
 DIST extra-cmake-modules-5.116.0.tar.xz 332248 BLAKE2B 3a9b9afc47279c3f3242f5cc8271596533be347374b59db6af49b6b08368917be4321f33d3721d3a3328f52ad9347556b40611702d7b8c52f86a92c7a23613fe SHA512 c0d73c2a6a155e3f03292335c994ec940892c751334e2336b42640016ebde5a9d72efe6fc6a31b7349504142da01e5974539b82d1e2aa967f448ae3ae80859f6
 DIST extra-cmake-modules-6.2.0.tar.xz 340788 BLAKE2B 69784bc106b7c635e849ae15424904f4c80bbc92c7d3106b8190479cd2d68d98a5e6dc759773356d17f7403925f4ce5ca79429f81e38f7ff7b8016323c47fe35 SHA512 519b412f3c41321d63183d57fc90ed47492e76aeb53295a708f9ea0c6a7797bb7582cfc1e5067a358d643b4f1538d913d2693ca90b5f0367fbe96912a5560d68
+DIST extra-cmake-modules-6.3.0.tar.xz 340764 BLAKE2B cb472913b6dc2ebc4904838555a8ad3322a94d8f0fa10406a1fef089ce3df3d75ed28d47c89d33d2d38bf6369638d6e0569ac47db3bcadca4ebf5894a924de9d SHA512 53a44ca9087825cefd0cb1c5e7bfa77c3668dd6d42fb09e4ef9f533314a40ae47e0e2d4e9949deb755754901815bb3f49fdc75afde2f6d90e691a3d1652d8898

kde-frameworks/extra-cmake-modules/extra-cmake-modules-6.3.0.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+QTMIN=6.6.2
+inherit cmake frameworks.kde.org python-any-r1
+
+DESCRIPTION="Extra modules and scripts for CMake"
+HOMEPAGE="https://invent.kde.org/frameworks/extra-cmake-modules"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="app-arch/libarchive[bzip2]"
+BDEPEND="
+	doc? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
+		>=dev-qt/qttools-${QTMIN}:6[assistant]
+	)
+	test? (
+		>=dev-qt/qttools-${QTMIN}:6[linguist]
+		>=dev-qt/qtbase-${QTMIN}:6
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.49.0-no-fatal-warnings.patch"
+	"${FILESDIR}/${PN}-5.93.0-skip-ecm_add_test-early.patch"
+	"${FILESDIR}/${PN}-5.112.0-disable-tests-requiring-PyQt5.patch" # bug 680256
+	"${FILESDIR}/${PN}-5.245.0-disable-qmlplugindump.patch"
+)
+
+python_check_deps() {
+	python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDOC_INSTALL_DIR=/usr/share/doc/"${PF}"
+		-DBUILD_QTHELP_DOCS=$(usex doc)
+		-DBUILD_HTML_DOCS=$(usex doc)
+		-DBUILD_MAN_DOCS=$(usex doc)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local CMAKE_SKIP_TESTS=(
+		# passes, but then breaks src_install
+		ECMToolchainAndroidTest
+		# broken, bug #627806
+		ECMPoQmToolsTest
+		# can not possibly succeed in releases, bug #764953
+		KDEFetchTranslations
+	)
+	# possible race condition with multiple jobs, bug #701854
+	cmake_src_test -j1
+}