dev-python/sympy: add 1.10

Signed-off-by: Sam James <sam@gentoo.org>

dev-python/sympy/Manifest

@@ -1 +1,2 @@
+DIST sympy-1.10.tar.gz 7665598 BLAKE2B 423c501cbdec9369b094156ec4c06c38e52daa0824f61fc2d57b0002473428c7b2df59156bd129c07ea57bb712577568b014b1b48ff0a1d1555ccf25d2fe01df SHA512 0107c68b38809fbcec597339447fa830a9cb3c55863799c41dfb5d122ac7564fdf7c685fe2eedaaa3b8d5c9160b196ef2484fff4c7e99aa17a5a562f3fb73be5
 DIST sympy-1.9.tar.gz 7476018 BLAKE2B 5ab9920bf6d16eaed3af30100e7593551a4dce29dc76605ccf87d55e8a7c14514b5733c9456353403cfc96008fd5d046ce04f44bb7e69f844d545bdd3e55e7e0 SHA512 139712219ba6bf420ba89b3f8d086ab8883c5ab965e9308ba9ee665ac3ac69a9b16fa30c6f5dfbc77dd34873ff3ff95c0d058954d7f9d853f5e9537efc24dd3c

dev-python/sympy/sympy-1.10.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Computer Algebra System in pure Python"
+HOMEPAGE="https://www.sympy.org/"
+SRC_URI="https://github.com/sympy/sympy/archive/${P}.tar.gz"
+S="${WORKDIR}/${PN}-${P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="aesara examples imaging ipython latex mathml opengl pdf png pyglet symengine test texmacs"
+
+RDEPEND="
+	dev-python/mpmath[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	aesara? ( dev-python/aesara[${PYTHON_USEDEP}] )
+	imaging? ( dev-python/pillow[${PYTHON_USEDEP}] )
+	ipython? ( dev-python/ipython[${PYTHON_USEDEP}] )
+	latex? (
+		virtual/latex-base
+		dev-texlive/texlive-fontsextra
+		png? ( app-text/dvipng )
+		pdf? ( app-text/ghostscript-gpl )
+	)
+	mathml? ( dev-libs/libxml2:2[${PYTHON_USEDEP}] )
+	opengl? ( dev-python/pyopengl[${PYTHON_USEDEP}] )
+	pyglet? ( dev-python/pyglet[${PYTHON_USEDEP}] )
+	symengine? ( dev-python/symengine[${PYTHON_USEDEP}] )
+	texmacs? ( app-office/texmacs )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	virtx esetup.py test
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS README.md )
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+
+	if use texmacs; then
+		exeinto /usr/libexec/TeXmacs/bin/
+		doexe data/TeXmacs/bin/tm_sympy
+		insinto /usr/share/TeXmacs/plugins/sympy/
+		doins -r data/TeXmacs/progs
+	fi
+}