games-board/gnubg: add 1.08.003

Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

games-board/gnubg/Manifest

@@ -1,3 +1,4 @@
 DIST gnubg-release-1.07.001-sources.tar.gz 13729158 BLAKE2B 3c5a0ffd38d2f1a16b3bf188a6ed6ba38e9527d681ad510b2e318b6f5da7d5fb1e0728f4f562fe4d770710489e7eae1396318e26717a51434fa8b4c3258570f9 SHA512 0643af4c3c6e32774e3572462755e7eed094fcc9621dc8262ce0f794657f00a3dbc22d0f916580982a6dacc08488544cd5fec5bf7e2c60ca50f83e2a60804e08
 DIST gnubg-release-1.08.001-sources.tar.gz 14019262 BLAKE2B ac207c54a6b0b4af59eefe0d2d2967393fa6fe6497c29c514baba596a446a0481bc07a4fa74f492de270260c942df81a1ef28bcdc9187cc3b2d3c0507cd6f27c SHA512 a3a547368f8852d0b5186340a3b893842237358b48dc4e6893920d57ea0f2fe72d958b4d0de16be55616fc687889118b016a6d3a859a1651fc77adcefcd7a7eb
 DIST gnubg-release-1.08.002-sources.tar.gz 14045962 BLAKE2B 328639d4ab96d8ab8025971819a2b6c120102ca757f29c8e5e8d0ac8f77a5abb4b75fd006d1c7090c2d04b9d66e1185069ce51c5f90437464d430f9c53d1875c SHA512 0e68c03457ca2cc925fe510752e24b03147db36e2e489c9e2912dd72f55f42514d98568fec1ce81176e7b8e3aafd68034659fe84e89e07b057224095f3be8924
+DIST gnubg-release-1.08.003-sources.tar.gz 14046779 BLAKE2B 6cb9ddcfbc71dbb4461daebb191046f02986a116e45acf09f219598fea6b066c38080c3a2b051de424eadcbe3a6c8a6e30794381d9edfb03dcc36102ed641e05 SHA512 3c006315491a324b7a6fa3adb19af829e9e9b04b231558ed4e88035eb0461602504cd4249a0119d1c89dc8e82b73c99946af3551ddd7c55aa0cd230b0121e527

games-board/gnubg/gnubg-1.08.003.ebuild

@@ -0,0 +1,102 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit autotools desktop python-single-r1 xdg
+
+DESCRIPTION="GNU BackGammon"
+HOMEPAGE="https://www.gnu.org/software/gnubg/"
+SRC_URI="mirror://gnu/${PN}/${PN}-release-${PV}-sources.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+IUSE="
+	cpu_flags_x86_avx cpu_flags_x86_sse cpu_flags_x86_sse2
+	gui opengl python sqlite"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+	opengl? ( gui )"
+
+RDEPEND="
+	dev-libs/cglm
+	dev-libs/glib:2
+	dev-libs/gmp:=
+	media-fonts/dejavu
+	media-libs/freetype:2
+	media-libs/libpng:=
+	net-misc/curl
+	sys-libs/readline:=
+	virtual/libintl
+	x11-libs/cairo[svg(+)]
+	x11-libs/pango
+	gui? (
+		media-libs/libcanberra[gtk3]
+		x11-libs/gdk-pixbuf:2
+		x11-libs/gtk+:3
+	)
+	opengl? ( media-libs/libepoxy )
+	python? ( ${PYTHON_DEPS} )
+	sqlite? ( dev-db/sqlite:3 )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-build/autoconf-archive
+	sys-devel/gettext
+	virtual/pkgconfig
+	python? ( ${PYTHON_DEPS} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	#This was provided by gtkglext before
+	sed -i "s/\$(GTKGLEXT_LIBS)/-lGL/" Makefile.am || die
+
+	sed -i "s|/tmp|${T}|" credits.sh || die #298275
+	sed -i 's/fonts //' Makefile.am || die #335774
+	sed -i 's/gzip/true/' doc/Makefile.am || die
+
+	# use system's copy so py3.10 distutils warning doesn't trigger a fatal error
+	rm m4/ax_python_devel.m4 || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local simd=no
+	use cpu_flags_x86_sse  && simd=sse
+	use cpu_flags_x86_sse2 && simd=sse2
+	use cpu_flags_x86_avx  && simd=avx
+
+	local econfargs=(
+		$(use_with gui gtk)
+		$(use_with gui gtk3)
+		$(use_with opengl board3d)
+		$(use_with python)
+		$(use_with sqlite)
+		--disable-cputest
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}/html
+		--enable-simd=${simd}
+	)
+
+	econf "${econfargs[@]}"
+}
+
+src_install() {
+	default
+
+	mv "${ED}"/usr/share/doc/${PF}{/html/*.pdf,} || die
+
+	insinto /usr/share/${PN}
+	doins ${PN}.weights *.bd
+
+	dosym ../../fonts/dejavu/DejaVuSans.ttf /usr/share/${PN}/fonts/Vera.ttf
+	dosym ../../fonts/dejavu/DejaVuSans-Bold.ttf /usr/share/${PN}/fonts/VeraBd.ttf
+	dosym ../../fonts/dejavu/DejaVuSerif-Bold.ttf /usr/share/${PN}/fonts/VeraSeBd.ttf
+
+	use gui && make_desktop_entry "gnubg -w" "GNU Backgammon"
+}