gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/pytest: Bump to 7.0.1

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2022-02-11 20:54:14 +01:00
parent 0641d379b6
commit 6d40f69230
2 changed files with 78 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/pytest/Manifest
View File

@@ -1,2 +1,3 @@
DIST pytest-6.2.5.tar.gz 1118720 BLAKE2B 9dfc87279617be58353566009325f929e6fa53d54fd4c665a75f3b359ab5415972d745a680eb85ab21ca9eaec84450bc1decd50566b0ccdf90d7551f3d03ee70 SHA512 7624563a9d967da4cbf82cfff90bae8c0cca07b32e291dc7c5efa787725ed1a255edd066bf0d5fbd89b8cbed8cf5b619fe7c7017f44a7f8a014e3310c06bdbf9
DIST pytest-7.0.0.tar.gz 1247853 BLAKE2B 3af132da903252323086b21eb052d35973f1e81189972d7f1880a22c5dd8a2b779bf2450f394ef9b1e156b780bcf6f677a0b043db204bcb6038a9a85c7f393e6 SHA512 9e876575d89ee60eccc873b2551464cc8eb7f9abfc6d73b33913efef79906830bdbe08b182ae436f981950cc6384f494935aa6ecb0d63b82e3c9ded77f9655b9
DIST pytest-7.0.1.tar.gz 1249154 BLAKE2B fcaef6afc6e98f6716a80f6451671b2abbf9ad676330a6e66e917a73e018eef966de8e7ef7ab48a1213167476eef1eb37cc5e84ec2bd9e5eab4ec6f1a8071c87 SHA512 21493717159a64fe6467bd096b578b127d81438d04f5b03ba2f4047237054f865a1f50a4e291b9d95b1a144f59bc7a8b3a00008493f4fb4f14bff7fb65c5edc2

77
dev-python/pytest/pytest-7.0.1.ebuild Normal file
View File

@@ -0,0 +1,77 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..10} pypy3 )
inherit distutils-r1 multiprocessing
DESCRIPTION="Simple powerful testing with Python"
HOMEPAGE="https://pytest.org/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
dev-python/iniconfig[${PYTHON_USEDEP}]
>=dev-python/more-itertools-4.0.0[${PYTHON_USEDEP}]
dev-python/packaging[${PYTHON_USEDEP}]
>=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
>=dev-python/py-1.8.2[${PYTHON_USEDEP}]
>=dev-python/tomli-1.0.0[${PYTHON_USEDEP}]
"
BDEPEND="
>=dev-python/setuptools_scm-6.2.3[${PYTHON_USEDEP}]
test? (
${RDEPEND}
dev-python/argcomplete[${PYTHON_USEDEP}]
>=dev-python/hypothesis-3.56[${PYTHON_USEDEP}]
dev-python/mock[${PYTHON_USEDEP}]
dev-python/nose[${PYTHON_USEDEP}]
>=dev-python/pygments-2.7.2[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-python/xmlschema[${PYTHON_USEDEP}]
)"
src_test() {
# workaround new readline defaults
echo "set enable-bracketed-paste off" > "${T}"/inputrc || die
local -x INPUTRC="${T}"/inputrc
distutils-r1_src_test
}
python_test() {
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local -x COLUMNS=80
local EPYTEST_DESELECT=(
# broken by epytest args
testing/test_warnings.py::test_works_with_filterwarnings
# tend to be broken by random pytest plugins
# (these tests patch PYTEST_DISABLE_PLUGIN_AUTOLOAD out)
testing/test_helpconfig.py::test_version_less_verbose
testing/test_helpconfig.py::test_version_verbose
testing/test_junitxml.py::test_random_report_log_xdist
testing/test_junitxml.py::test_runs_twice_xdist
testing/test_terminal.py::TestProgressOutputStyle::test_xdist_normal
testing/test_terminal.py::TestProgressOutputStyle::test_xdist_normal_count
testing/test_terminal.py::TestProgressOutputStyle::test_xdist_verbose
testing/test_terminal.py::TestProgressWithTeardown::test_xdist_normal
testing/test_terminal.py::TestTerminalFunctional::test_header_trailer_info
testing/test_terminal.py::TestTerminalFunctional::test_no_header_trailer_info
# unstable with xdist
testing/test_terminal.py::TestTerminalFunctional::test_verbose_reporting_xdist
)
epytest -p xdist -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
}