dev-python/coverage: Bump to 7.4.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2024-02-21 05:30:05 +01:00
parent b17a5de80e
commit 6d11018657
2 changed files with 99 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST coverage-7.4.0.tar.gz 776507 BLAKE2B ea96db033e711c5b47ebbd585f1eec8e576908dfbecd7df6e555a5e96cdbadf546e0b2b1a5790fd66be386a068ced5a1544dff79601546fe6a4ac0e9b36a05a2 SHA512 7563ca34ed8d0dd3b9f376b20cbaeb9c952ba0dda57d9f1a33abe94ac17ed6411d0d537f039613c310957eb926e8fa102ad888c5de8bdb3f0233668bdf96d395
DIST coverage-7.4.1.tar.gz 780560 BLAKE2B bd23208a3fe86a0476b964150ba5bf7db5e26af3844eb16a36c4aaf96a40056486a906f82016f8a5adb05cca8562adcfa11cb44fdef78587aa575b93d24d54eb SHA512 a5e6a40a9b83a9e3ab88c432305a89caa4a7575f17c35385782a59237cc0464d879222afd524879e3e36a09f185fc6249af6198cbc0a10a6c3e83a19de452e79
DIST coverage-7.4.2.tar.gz 783045 BLAKE2B c4085c8ae59dc0c4ccc5a7cc94e1acc7791c34c7220bc611aae6d4ca4beeffaf3aafdbaa760cb030ec216bb749306146840c964c8bb6f2dc3f69c444576544b2 SHA512 480483d3923d956f23f156e3732a2ac1c03209d55c155b832386b4539a834521604749f35ea1b0a5c2109958fc77d8ae69456604fd5a2d1174fd83c8fddfe407
+98
View File
@@ -0,0 +1,98 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} pypy3 )
PYTHON_REQ_USE="threads(+),sqlite(+)"
inherit distutils-r1 pypi
DESCRIPTION="Code coverage measurement for Python"
HOMEPAGE="
https://coverage.readthedocs.io/en/latest/
https://github.com/nedbat/coveragepy/
https://pypi.org/project/coverage/
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
RDEPEND="
$(python_gen_cond_dep '
dev-python/tomli[${PYTHON_USEDEP}]
' 3.{9..10})
"
BDEPEND="
test? (
dev-python/flaky[${PYTHON_USEDEP}]
dev-python/hypothesis[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
>=dev-python/unittest-mixins-1.4[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
src_prepare() {
sed -i -e '/addopts/s:-q -n auto::' pyproject.toml || die
distutils-r1_src_prepare
}
test_tracer() {
local -x COVERAGE_CORE=${1}
einfo " Testing with the ${COVERAGE_CORE} core ..."
epytest -p flaky -p hypothesis -p xdist tests
}
python_test() {
local EPYTEST_DESELECT=(
# TODO: fails because of additional "Terminated" print on SIGTERM
tests/test_concurrency.py::SigtermTest::test_sigterm_threading_saves_data
# broken because of pytest plugins explicity loaded
tests/test_debug.py::ShortStackTest::test_short_stack{,_skip}
# these expect specific availability of C extension matching
# COVERAGE_CORE (which breaks testing pytracer on CPython)
tests/test_cmdline.py::CmdLineStdoutTest::test_version
tests/test_debug.py::DebugTraceTest::test_debug_sys_ctracer
)
local EPYTEST_IGNORE=(
# pip these days insists on fetching build deps from Internet
tests/test_venv.py
)
"${EPYTHON}" igor.py zip_mods || die
local -x COVERAGE_TESTING=True
# TODO: figure out why they can't be imported inside test env
local -x COVERAGE_NO_CONTRACTS=1
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local prev_opt=$(shopt -p nullglob)
shopt -s nullglob
local c_ext=( "${BUILD_DIR}/install$(python_get_sitedir)"/coverage/*.so )
${prev_opt}
if [[ -n ${c_ext} ]]; then
cp "${c_ext}" coverage/ || die
test_tracer ctrace
fi
test_tracer pytrace
case ${EPYTHON} in
python3.1[01]|pypy3)
;;
*)
# available since Python 3.12
test_tracer sysmon
;;
esac
if [[ -n ${c_ext} ]]; then
rm coverage/*.so || die
fi
}