xfce-base/xfdesktop: Bump to 4.13.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/xfdesktop/Manifest

@@ -1,2 +1,3 @@
 DIST xfdesktop-4.12.4.tar.bz2 1421623 BLAKE2B a18b891d639165d617f2701106dedb2f8577273ece5a4c93f6b5e1ef26f801304ea2014f21bd2821eb9bac9b19e02dd75cd4054a116eefd544f4d8e5d6968879 SHA512 29f170b96836298dc83e3c49650ab7e88a93c1a2fa1599d1d98f3b6c80c9c059748b76a821077eea39b5b4619998bb300ff17f06e88483a59bd5ae2b76d0605e
 DIST xfdesktop-4.13.2.tar.bz2 1486455 BLAKE2B 38ba5da7172212f74281f60688a581e525dcbb91ea381f8fcbdef57f90b54b9c21d08f20f3b1da5c91dcab158c2a7ba415822ec7b1f92f1cef80e53624a1f741 SHA512 0002ed639f8554144d8c921ca5bd9d1c2ed634baa11c98f95685c8a636ae6bdc87f8df19aa138fe4eda591facba964451a10aef6ba303be1fad66013bb06ae13
+DIST xfdesktop-4.13.3.tar.bz2 1487433 BLAKE2B 81c5be8d54da6bfdb121d5632d67abfe6705eeddfb8c247ebf6870261093908660f880c8152d0cff87c912b1f3277d6551993a6a64384e610928c9bc6fda45a9 SHA512 5d828ad653b46ab1edc8300335321bab48e0ad2be1ae02944eff553375a6059513aeb363c73aaec1a6958dd3f1c873920287ad911cfe7b8096b447f1b8165ce3

xfce-base/xfdesktop/xfdesktop-4.13.3.ebuild

@@ -0,0 +1,53 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils
+
+DESCRIPTION="Desktop manager for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug libnotify +thunar"
+
+RDEPEND=">=x11-libs/cairo-1.12:=
+	>=dev-libs/glib-2.42:=
+	>=x11-libs/gtk+-3.22:3=
+	>=x11-libs/libwnck-3.14:3=
+	x11-libs/libX11:=
+	>=xfce-base/exo-0.11:=
+	>=xfce-base/garcon-0.6:=
+	>=xfce-base/libxfce4ui-4.13:=
+	>=xfce-base/libxfce4util-4.13:=
+	>=xfce-base/xfconf-4.12.1:=
+	libnotify? ( >=x11-libs/libnotify-0.7:= )
+	thunar? (
+		>=dev-libs/glib-2.38:=
+		>=xfce-base/thunar-1.7:=
+		)"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		$(use_enable thunar file-icons)
+		$(use_enable thunar thunarx)
+		$(use_enable libnotify notifications)
+	)
+
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}