games-util/antimicrox: bump to 3.3.4

Signed-off-by: Maciej Barć <xgqt@gentoo.org>
This commit is contained in:
Maciej Barć
2023-06-03 17:51:04 +02:00
parent 20e83166ae
commit 6ca8ca744e
2 changed files with 75 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST antimicrox-3.3.3.tar.gz 1956700 BLAKE2B 8f385f238bfe03cb294e5970dde63cc3f1668c8dfdd31c751b769e79493bfe86901fdcb6da80beda72fdb1672d3b1246a3e3f509387dba6418e09e1e6ff8bbb4 SHA512 e4e9edf4fdd15c111ee1675a166b70d0ecdcf735adf79d46498a88fe81ebbfd4f35fec10cb831d6506d19db8fd21edc7055d39be362c0f53036dff684841fb5e
DIST antimicrox-3.3.4.tar.gz 2002552 BLAKE2B fbaca20e3d76f048c4d9ef1b0eb8d043ed3d357a8a208d65f26c08b657c18b34c82462ea3e06278194b6b461d9828404cf31ce510b963f5e98e615d1e8934928 SHA512 f6be26facb23f08682e091208aa3a4210666b89a50533c0970b2447d3c7a229fd705c2a5adeecb156708ce5cbef145b63db9f2244a98961ee8fa9fa063a03b3a
@@ -0,0 +1,74 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit udev xdg cmake
DESCRIPTION="Graphical program used to map keyboard buttons and mouse controls to a gamepad"
HOMEPAGE="https://github.com/AntiMicroX/antimicrox/"
SRC_URI="https://github.com/AntiMicroX/${PN}/archive/${PV}.tar.gz
-> ${P}.tar.gz"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc"
# Tests fail to build
# https://github.com/AntiMicroX/antimicrox/issues/530
RESTRICT="test"
RDEPEND="
dev-qt/qtconcurrent:5
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5
dev-qt/qtwidgets:5
media-libs/libsdl2[X,joystick]
virtual/udev
x11-libs/libX11
x11-libs/libXi
x11-libs/libXtst
"
DEPEND="${RDEPEND}"
BDEPEND="
dev-qt/linguist-tools:5
kde-frameworks/extra-cmake-modules
doc? ( app-doc/doxygen[dot] )
"
PATCHES=( "${FILESDIR}"/${PN}-man_gz.patch )
DOCS=( CHANGELOG.md README.md )
src_configure() {
local mycmakeargs=(
-DAPPDATA=OFF
-DCHECK_FOR_UPDATES=OFF
-DINSTALL_UINPUT_UDEV_RULES=OFF # Install in src_install
-DWITH_TESTS=OFF
-DWITH_UINPUT=ON
-DWITH_X11=ON
-DWITH_XTEST=ON
-DBUILD_DOCS=$(usex doc ON OFF)
)
cmake_src_configure
}
src_install() {
cmake_src_install
rm -r "${ED}"/usr/share/doc/${PN} || die
udev_dorules "${S}"/other/60-${PN}-uinput.rules
use doc && dodoc -r "${S}"/docs/{html,latex}
}
pkg_postinst() {
udev_reload
xdg_pkg_postinst
}
pkg_postrm() {
udev_reload
xdg_pkg_postrm
}