media-gfx/digikam: 7.4.0 version bump

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2021-12-16 17:59:39 +01:00
parent cecff9745e
commit 6c8c0fdcdc
2 changed files with 146 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST digiKam-7.4.0.tar.xz 339575096 BLAKE2B b7a556cd8d86bbc60530d697d8ffe42c497cd8ff5dd408f7a2afd1106c96804908e15b6faf1d8090f12aaea62e99d90751ea36c6e36a7bbec62b5f194452d0f1 SHA512 aea494c4636255e25db1cee7968cdec49530064f737897940b9e2184d214b77024f31226fa76e099362966e687e5ed05bc8486ae0645c2c18d9bbcc452dd1b6e
DIST digikam-7.3.0.tar.xz 256985340 BLAKE2B 9eb9802340f4d071a8378019eba007a25f1e5eeaf9d6acfa9b062c5ecf308a4e59408e078e53cea4d4ed3624d73181f3bb7973622512167bcc44748e063b13ed SHA512 71cb07de32fb9b07e0f9989a718b2a307618eaaeba6566dc6802b79e48c61f3ab00ca44e12c3971c2efc41448192a2e5a652d2cfd09be058d2bc98f40b5ebaad
+145
View File
@@ -0,0 +1,145 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
KFMIN=5.88.0
QTMIN=5.15.2
inherit ecm kde.org toolchain-funcs
if [[ ${KDE_BUILD_TYPE} != live ]]; then
if [[ ${PV} =~ beta[0-9]$ ]]; then
SRC_URI="mirror://kde/unstable/${PN}/"
else
SRC_URI="mirror://kde/stable/${PN}/${PV}/"
fi
SRC_URI+="digiKam-${PV/_/-}.tar.xz"
KEYWORDS="~amd64 ~x86"
S="${WORKDIR}/${PN}-${PV/_/-}"
fi
DESCRIPTION="Digital photo management application"
HOMEPAGE="https://www.digikam.org/"
LICENSE="GPL-2"
SLOT="5"
IUSE="addressbook calendar gphoto2 heif +imagemagick +lensfun marble mediaplayer mysql opengl openmp +panorama scanner semantic-desktop X"
# bug 366505
RESTRICT="test"
COMMON_DEPEND="
dev-libs/expat
>=dev-qt/qtconcurrent-${QTMIN}:5
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5[-gles2-only]
>=dev-qt/qtnetwork-${QTMIN}:5
>=dev-qt/qtprintsupport-${QTMIN}:5
>=dev-qt/qtsql-${QTMIN}:5[mysql?]
>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
>=dev-qt/qtwidgets-${QTMIN}:5
>=dev-qt/qtxml-${QTMIN}:5
>=dev-qt/qtxmlpatterns-${QTMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kiconthemes-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/knotifications-${KFMIN}:5
>=kde-frameworks/knotifyconfig-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kwindowsystem-${KFMIN}:5
>=kde-frameworks/kxmlgui-${KFMIN}:5
>=kde-frameworks/solid-${KFMIN}:5
>=media-gfx/exiv2-0.27:=
media-libs/lcms:2
media-libs/liblqr
media-libs/libpng:0=
>=media-libs/opencv-3.3.0:=[contrib,contribdnn]
media-libs/tiff:0
virtual/jpeg:0
addressbook? (
>=kde-apps/akonadi-contacts-19.04.3:5
>=kde-frameworks/kcontacts-${KFMIN}:5
)
calendar? ( >=kde-frameworks/kcalendarcore-${KFMIN}:5 )
gphoto2? ( media-libs/libgphoto2:= )
heif? ( media-libs/x265:= )
imagemagick? ( media-gfx/imagemagick:= )
lensfun? ( media-libs/lensfun )
marble? (
>=dev-qt/qtconcurrent-${QTMIN}:5
>=kde-apps/marble-19.04.3:5
>=kde-frameworks/kbookmarks-${KFMIN}:5
)
mediaplayer? (
media-libs/qtav[opengl(+)]
media-video/ffmpeg:=
)
opengl? (
>=dev-qt/qtopengl-${QTMIN}:5
virtual/opengl
)
panorama? ( >=kde-frameworks/threadweaver-${KFMIN}:5 )
scanner? ( >=kde-apps/libksane-19.04.3:5 )
semantic-desktop? ( >=kde-frameworks/kfilemetadata-${KFMIN}:5 )
X? (
>=dev-qt/qtx11extras-${QTMIN}:5
x11-libs/libX11
)
"
DEPEND="${COMMON_DEPEND}
dev-cpp/eigen:3
dev-libs/boost[threads(+)]
"
RDEPEND="${COMMON_DEPEND}
mysql? ( virtual/mysql[server(+)] )
panorama? ( media-gfx/hugin )
"
BDEPEND="
sys-devel/gettext
panorama? (
sys-devel/bison
sys-devel/flex
)
"
pkg_pretend() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
ecm_pkg_pretend
}
pkg_setup() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
ecm_pkg_setup
}
# FIXME: Unbundle libraw (libs/rawengine/libraw)
src_configure() {
local mycmakeargs=(
-DBUILD_TESTING=OFF # bug 698192
-DENABLE_APPSTYLES=ON
-DCMAKE_DISABLE_FIND_PACKAGE_Jasper=ON
-DENABLE_QWEBENGINE=ON
-DENABLE_AKONADICONTACTSUPPORT=$(usex addressbook)
$(cmake_use_find_package calendar KF5CalendarCore)
$(cmake_use_find_package gphoto2 Gphoto2)
$(cmake_use_find_package heif X265)
$(cmake_use_find_package imagemagick ImageMagick)
$(cmake_use_find_package lensfun LensFun)
$(cmake_use_find_package marble Marble)
-DENABLE_MEDIAPLAYER=$(usex mediaplayer)
$(cmake_use_find_package mediaplayer QtAV)
-DENABLE_MYSQLSUPPORT=$(usex mysql)
-DENABLE_INTERNALMYSQL=$(usex mysql)
$(cmake_use_find_package opengl OpenGL)
$(cmake_use_find_package panorama KF5ThreadWeaver)
$(cmake_use_find_package scanner KF5Sane)
$(cmake_use_find_package semantic-desktop KF5FileMetaData)
$(cmake_use_find_package X X11)
)
ecm_src_configure
}