net-misc/youtube-dl: Version 2019.03.01

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

net-misc/youtube-dl/Manifest

@@ -1 +1,2 @@
 DIST youtube-dl-2019.02.18.tar.gz 3114830 BLAKE2B f948fc68d9bc2b7e400d22b4d2980b7f56bf734476a54b3e30b6ee33d5e4a0950233dfd74b0db26108a5759e3589acde4fe104d41ea856c88f68e165f330132b SHA512 86a321003b9e0bdc852294c8ac75d601141177f3469330c6ab01fa821758ee848dfcdf0e9dd514ca2da7b7e3c2a7f2dcddab9929f7fa8be2ab3c86d6eccbd5e3
+DIST youtube-dl-2019.03.01.tar.gz 3117441 BLAKE2B 92beb16920b6d9c3ead89d5ff930b73635f74d7aeba62a4ee8159e28b448931810f340857bc223ab587610704405083768137a62d7c92814a7525825adc60919 SHA512 ff037b2288b937ebc70bfa880a4c0cd10cb4a615725e25f8db998c828d4b505461088b5aaa926aa47f148189496275f1a70e03e187325c15d6ff425ed4da2dc7

net-misc/youtube-dl/youtube-dl-2019.03.01.ebuild

@@ -0,0 +1,64 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=(python{2_7,3_4,3_5,3_6})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://rg3.github.com/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+LICENSE="public-domain"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+RESTRICT="test"
+SLOT="0"
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+"
+S="${WORKDIR}/${PN}"
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+	elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+	elog "videos can be retrieved in a higher quality format without sound."
+	elog "${PN} will detect whether avconv/ffmpeg is present and"
+	elog "automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}