Merge updates from master

app-text/zathura-cb/Manifest

@@ -1,2 +1,3 @@
 DIST zathura-cb-0.1.11.tar.xz 6748 BLAKE2B 59abd86594ede671b65e03c5a3577804edd7235ce74b7242907b3e744fa0982e12490c6ed98e556aa6c79c30e21b1683e3dea96d2a884f04bfd50f592c80e0ee SHA512 f927c4021937505bbc83d47959f4275701449dc4e889dd4a92ef7feecfcdf5ae772d34bb787ef8638c5fe209a1851ce355740c2b80921139f10fc059bd67f39d
 DIST zathura-cb-2026.02.03.tar.xz 6844 BLAKE2B 3f6b4ba63ffa78aed469a960246fdd3e5c9db9ae4984a3dd0ecf222415e96879460e73d625938c5b54d40a69ad292edc222f15bce742b78b16fd93f81608dfbc SHA512 54a307cc68212c8c1e6e4e95c9ef17544e94973774e08c6b21f5d44eb9748b405d75ed69faeef3c9a42746c982ed2452e48eded5dd8ccdf5b558d3b06002a1a6
+DIST zathura-cb-2026.07.18.tar.xz 7472 BLAKE2B cf0c21c46de0ec967366e1ee6b4dc75738b7868c842a31b1bcb2e500e930e0c9ca5ff2a87a34555df49edf6d4ccf42b40c44242364a9299195b8617bc31abce2 SHA512 acb2a3550cbf03b6ed2d3fcfb01c31c885e379f7735376dfc1bed84d0aa1448536615a96243d6cb215914bb6e8a2aa4bee6a5df26726757a4eee1f10763647c7

app-text/zathura-cb/zathura-cb-2026.07.18.ebuild

@@ -0,0 +1,36 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/pwmt/zathura-cb.git"
+else
+	KEYWORDS="~amd64 ~arm ~riscv ~x86"
+	SRC_URI="https://pwmt.org/projects/zathura-cb/download/${P}.tar.xz"
+fi
+
+DESCRIPTION="Comic book plug-in for zathura with 7zip, rar, tar and zip support"
+HOMEPAGE="https://pwmt.org/projects/zathura-cb/"
+
+LICENSE="ZLIB"
+SLOT="0"
+
+# Tests currently only validating data files
+RESTRICT="test"
+
+RDEPEND="app-arch/libarchive:=
+	>=app-text/zathura-2026.07.18:=
+	dev-libs/girara:=
+	dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2[jpeg]
+	x11-libs/gtk+:3"
+
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+
+BDEPEND="virtual/pkgconfig"

app-text/zathura-cb/zathura-cb-9999.ebuild

@@ -23,7 +23,7 @@ SLOT="0"
 RESTRICT="test"
 
 RDEPEND="app-arch/libarchive:=
-	>=app-text/zathura-2026.01.30:=
+	>=app-text/zathura-2026.07.18:=
 	dev-libs/girara:=
 	dev-libs/glib:2
 	x11-libs/cairo

app-text/zathura-djvu/Manifest

@@ -1,2 +1,3 @@
 DIST zathura-djvu-0.2.10.tar.xz 9408 BLAKE2B f779eeeba40abe444960716b8c14c51c32a3830a3f779074ea773bd9ff0d71736433ed29862bdf137a34ebb934bb562aa14031c07dda5cf97ddf278e47feb750 SHA512 c743e60588e07fe18f7da8db1ae9ae997ffb50ef696258f1901523159ff4d29e5649b13d6e52f53cf79f19429083308390c0b4923081451bf5c4bfb9ac6e8903
 DIST zathura-djvu-2026.02.03.tar.xz 9536 BLAKE2B 05b2d53769de604e18ea143b5896e8779365c87421ecb79201870383790475c2857d17f495c87511829440755d17be5e2708066dd7ac430ec236ed4140011a6d SHA512 1f72c2958282618b79828c9c726a954833b382ca87d926b6439e47ad27fdd5657da520e3baa780ad4ec1f2e84dd65bd9cd7e9617bb27fb56a5da6a586bd27454
+DIST zathura-djvu-2026.07.18.tar.xz 10164 BLAKE2B e0536cc1c77c2f7c3d19bb3b326e081debafe15384203d143fc26af633f3677104860882ec7398491a33cd91aaccf86e0808246c0bef2fb5215c7873011b26f0 SHA512 debd4eba1f303e509628ccbaba499cba46cdc145778d4705927b21e89773ad7f5a61f6a047d17a6dee7b835037b4e2ba9af8ee1d118cccb8a6b5e25062d3222e

app-text/zathura-djvu/zathura-djvu-2026.07.18.ebuild

@@ -0,0 +1,33 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/pwmt/zathura-djvu.git"
+else
+	KEYWORDS="~amd64 ~arm ~riscv ~x86"
+	SRC_URI="https://pwmt.org/projects/zathura-djvu/download/${P}.tar.xz"
+fi
+
+DESCRIPTION="DjVu plug-in for zathura"
+HOMEPAGE="https://pwmt.org/projects/zathura-djvu/"
+
+LICENSE="ZLIB"
+SLOT="0"
+
+# Tests currently only validating data files
+RESTRICT="test"
+
+RDEPEND="app-text/djvu
+	>=app-text/zathura-2026.07.18:=
+	dev-libs/girara:=
+	dev-libs/glib:2
+	x11-libs/cairo"
+
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+	virtual/pkgconfig"

app-text/zathura-djvu/zathura-djvu-9999.ebuild

@@ -23,7 +23,7 @@ SLOT="0"
 RESTRICT="test"
 
 RDEPEND="app-text/djvu
-	>=app-text/zathura-2026.02.03:=
+	>=app-text/zathura-2026.07.18:=
 	dev-libs/girara:=
 	dev-libs/glib:2
 	x11-libs/cairo"

app-text/zathura-pdf-mupdf/Manifest

@@ -1,2 +1,3 @@
 DIST zathura-pdf-mupdf-0.4.4.tar.gz 10100 BLAKE2B aa969ac9a702150d05e8c1dfc7f0f6752c0371c812a208f33ab19c14423b12636345544ce898eda3ab5517b895c832a91f3a6866468049e03b2d36a67d198c06 SHA512 c6297b8ed68a0797db2e7b295d7fc7cb4d099f24cd9faea49e1e2d0c61818b071297b57f6472c057010caf104053cc0866685349b33a61302280cb52bac055cf
 DIST zathura-pdf-mupdf-2026.02.03.tar.gz 10995 BLAKE2B a0a615e02d19a6d957a550159d761c38c7f0d9678bc00a010b763427dcb083471132e1199c6858e7d6d01f4a44ff1354f16654586833c12d67c6f3f83229c62b SHA512 25cddec7445669c24cc7f75374857947744f041227416d7027ddd7affc5b186ef048f3570f80c0bb0af66dc90669e035b75609bb8619d10ec34348e0c93878b8
+DIST zathura-pdf-mupdf-2026.07.18.tar.gz 11786 BLAKE2B 810ac696b67033b48c29cea71f0acc35a89e0a8fc7e15a27cde1ac5fde47f2433ea60490e79c40ad8908124987dff9d0f7a8490a2d8f5f18f8728404ba28f6bd SHA512 cec5771582475d2379507e91ea571b203a8fbd4861d86754108746603e4ec58a441442e0b5e6c9c707c8c8f45a05571b0535acc0bc2023631c8955e1112dda0d

app-text/zathura-pdf-mupdf/zathura-pdf-mupdf-2026.07.18.ebuild

@@ -0,0 +1,35 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/pwmt/zathura-pdf-mupdf.git"
+else
+	KEYWORDS="~amd64 ~arm ~x86"
+	SRC_URI="https://github.com/pwmt/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+DESCRIPTION="PDF support for zathura using the mupdf PDF rendering library"
+HOMEPAGE="https://pwmt.org/projects/zathura-pdf-mupdf/"
+
+LICENSE="ZLIB"
+SLOT="0"
+
+# Tests currently only validating data files
+RESTRICT="test"
+
+DEPEND="
+	>=app-text/mupdf-1.26.0:=
+	>=app-text/zathura-2026.07.18:=
+	dev-libs/girara:=
+	dev-libs/glib:2
+	x11-libs/cairo
+"
+
+RDEPEND="${DEPEND}"
+
+BDEPEND="virtual/pkgconfig"

app-text/zathura-pdf-mupdf/zathura-pdf-mupdf-9999.ebuild

@@ -24,7 +24,7 @@ RESTRICT="test"
 
 DEPEND="
 	>=app-text/mupdf-1.26.0:=
-	>=app-text/zathura-2026.01.30:=
+	>=app-text/zathura-2026.07.18:=
 	dev-libs/girara:=
 	dev-libs/glib:2
 	x11-libs/cairo

app-text/zathura-pdf-poppler/Manifest

@@ -1,2 +1,3 @@
 DIST zathura-pdf-poppler-0.3.3.tar.gz 10554 BLAKE2B b49f2d1cdab426f0e0c41d901af38fdb1931eea28d8d442f08a076945e6801b1a4032ed5e97c2fc6b96f361e9188b3c0c50d1d0e0c9a5a1bf7c427461cc92a3f SHA512 791b0e6cac29358226b2416e22527449d89b8544242d1b492b6017d52eb996aa9647e10259d475c5c84bbf4a19b680c160ac7e822e331c466c3ff5697913b003
 DIST zathura-pdf-poppler-2026.02.03.tar.gz 10423 BLAKE2B 83e3fff91b3c3d7645357719886a51458c42d0eea6ac34adafe98b39b86cd94140987ad119c40958b46963c6dd218bf9f5ef95d6d0a887d2f89240d192f267d5 SHA512 4c6c32bb213f99b6f3d61fcce317d6be289530ad6ec0a6df4f599abcb4109c75da44822563346ee55828ead504d0a49f9fdbe846c2f4f17d2718d0631d2cee88
+DIST zathura-pdf-poppler-2026.07.18.tar.gz 11094 BLAKE2B d7daef9c057f13339471498756376f02f8c0f8b371eb18e2cbbd90a4b6b3a8255dfe22bd29cef107febf7e64aff0777f28f728299629c412a007fe73e2f09b35 SHA512 6a1ca54a3041f1bcc591cd26c496d6e8868bd0f25336d78268724e4b65fa1fb4839660aca6fb93e5b8a0367da656185868186d1f7d033a3cd90075f197409c2e

app-text/zathura-pdf-poppler/zathura-pdf-poppler-2026.07.18.ebuild

@@ -0,0 +1,41 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg-utils
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/pwmt/zathura-pdf-poppler.git"
+else
+	KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+	SRC_URI="https://github.com/pwmt/zathura-pdf-poppler/archive/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+DESCRIPTION="PDF plug-in for zathura"
+HOMEPAGE="https://pwmt.org/projects/zathura-pdf-poppler/"
+
+LICENSE="ZLIB"
+SLOT="0"
+
+# Tests currently only validating data files
+RESTRICT="test"
+
+DEPEND=">=app-text/poppler-21.12.0:=[cairo]
+	>=app-text/zathura-2026.07.18:=
+	dev-libs/girara:=
+	dev-libs/glib:2
+	x11-libs/cairo"
+
+RDEPEND="${DEPEND}"
+
+BDEPEND="virtual/pkgconfig"
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}

app-text/zathura-pdf-poppler/zathura-pdf-poppler-9999.ebuild

@@ -14,7 +14,7 @@ else
 fi
 
 DESCRIPTION="PDF plug-in for zathura"
-HOMEPAGE="https://pwmt.org/projects/zathura-pdf-poppler"
+HOMEPAGE="https://pwmt.org/projects/zathura-pdf-poppler/"
 
 LICENSE="ZLIB"
 SLOT="0"
@@ -23,7 +23,7 @@ SLOT="0"
 RESTRICT="test"
 
 DEPEND=">=app-text/poppler-21.12.0:=[cairo]
-	>=app-text/zathura-2026.01.30:=
+	>=app-text/zathura-2026.07.18:=
 	dev-libs/girara:=
 	dev-libs/glib:2
 	x11-libs/cairo"

app-text/zathura-ps/Manifest

@@ -1,2 +1,3 @@
 DIST zathura-ps-0.2.8.tar.xz 4716 BLAKE2B d9377a00fcc9e45fae413676947ff2067c80362bd9f9f1573f9962459d9a636ed0743decbe437bf90ab9e65dcdb8b5d0b19ad1794085c313fa473f0241a101bf SHA512 29ed9d5585df1151af50835daa75a11befbd0fe10e95b4a37c7b548e1442edd3f52a7d0afce8cca93ce70ced6381cdf23311cea004e3e38a6cb323ba13eb7039
 DIST zathura-ps-2026.02.03.tar.xz 4808 BLAKE2B 83c0389d993f23876969600679bad9c45ad77a66791dc1ddac347491c177f60b72f9e77430e408cf7edc67d16148189214e4cd46d23726fee8b1fc374785ec1c SHA512 beed875741c0c9d8cb24e23136f4801417b58342e9c1007c4c2699424b03ac0126a25e9aed650a564951bab68c96a40d31ef8d7002012db59e94b4ec87e7bbd3
+DIST zathura-ps-2026.07.18.tar.xz 5404 BLAKE2B 62eb3fb198572abda018422df3cdb992f3cbaba17c433e3a9f24d47b98c98a3daf5ac58d1b81214e33e7ff1cd087ce23df24271af4d3aaae16af5b9ba079dc47 SHA512 7628595a9138bb522ae4c247a56f6f83df77905dbace827b257144a0ef187879dcd05b383a8ad627eadd8e16aa71d0c2259326937ad420bdf7cfc2afb6fe4b69

app-text/zathura-ps/zathura-ps-2026.07.18.ebuild

@@ -0,0 +1,41 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg-utils
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/pwmt/zathura-ps.git"
+else
+	KEYWORDS="~amd64 ~arm ~riscv ~x86"
+	SRC_URI="https://pwmt.org/projects/zathura-ps/download/${P}.tar.xz"
+fi
+
+DESCRIPTION="PostScript plug-in for zathura"
+HOMEPAGE="https://pwmt.org/projects/zathura-ps/download/"
+
+LICENSE="ZLIB"
+SLOT="0"
+
+# Tests currently only validating data files
+RESTRICT="test"
+
+DEPEND="app-text/libspectre
+	>=app-text/zathura-2026.07.18
+	dev-libs/girara:=
+	dev-libs/glib:2
+	x11-libs/cairo"
+
+RDEPEND="${DEPEND}"
+
+BDEPEND="virtual/pkgconfig"
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}

app-text/zathura-ps/zathura-ps-9999.ebuild

@@ -23,7 +23,7 @@ SLOT="0"
 RESTRICT="test"
 
 DEPEND="app-text/libspectre
-	>=app-text/zathura-2026.01.30
+	>=app-text/zathura-2026.07.18
 	dev-libs/girara:=
 	dev-libs/glib:2
 	x11-libs/cairo"

app-text/zathura/Manifest

@@ -2,3 +2,5 @@ DIST zathura-0.5.13.tar.gz 395362 BLAKE2B e66f10d7b73c6560b2b3215ec620e33e306ff9
 DIST zathura-0.5.14.tar.gz 399930 BLAKE2B fd3396e4a56a484009188d87548743423e3a14060aee2790174d0ca6aadff33c5e66ba668ae3f83f3069baa851571a4bd05a44602ed0fcc3b078df6aaa6a5527 SHA512 1bf77b3e2a24644bbad3bff8a2d603fc3bf5a8803e217c38c0d30ffa2731ff083de7f5cfe0b4ce93923a66b91351118f267a22fea922238bb044634d7c6bc091
 DIST zathura-0.5.8.tar.gz 219371 BLAKE2B c7c163e0c1cd5e344ae566ab71ad66d51b89cacd11ef9b335589c0fa705e7a300adab680b7c13a197da3c10b5161656fbb9c8449667eb05e64f0506bf254e675 SHA512 6954f8bf8c76526e86a4e335c18c3c68f509fbbe1081f7c74d333f8a9ba83bc5da971ad744f91408f8b0fb8f0b647ae07f02601b5efa97961155ba193c8777f6
 DIST zathura-2026.02.22.tar.gz 527036 BLAKE2B c8bfe65d7d3fc492044d36df5c1b14f4b0613d84a20509710b1183f4d12898192f13a8fcd1ba4394a352d2df38ce28a74533cc6650749c3c857d239f5dd7c6cb SHA512 ab5e2df7ec551c13eaa5b86d6a1157b75706d7ccbd268bcdd103af21e2262b5e052cf621f8cf7aeca324c7b6d358bc4fcf278e94827519e06d6891ba007399c6
+DIST zathura-2026.07.18-manpages.tar.xz 11064 BLAKE2B 86e44cb93ce84c2c7a61fb29a37fa386e15a2cd40a7813d8d448937594999b8f360a01d56636e10b454b75ca9d170ba1454398b4a580bffec2bc90ec3eb7a6c2 SHA512 78cd3ba921385c0948c9578bf76ac2446ae6c22e658adeca93d540489244c8afcaa5619d77059813aad00bcf76229b4dcac9a4bf4ba9baa5d29332095a74f49d
+DIST zathura-2026.07.18.tar.gz 524430 BLAKE2B fa60a0a9f4b99c884fdc134fe2b38186e0435014210218012c9b396a5c5235845f450ef913ab2b472550917224121eb7af65154e30f3362db3bdfd5014720dcb SHA512 1d0900e67e43e4bcd6dfcb05918969ff30b0a0c7e0cd214ff09499359e5e61a20440d7b9723192683a540bb9d34a9239a05075558baf26b1a14ccffa383d0200

app-text/zathura/zathura-2026.07.18.ebuild

@@ -0,0 +1,115 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic meson xdg
+
+DESCRIPTION="Highly customizable & functional document viewer"
+HOMEPAGE="https://pwmt.org/projects/zathura/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/pwmt/zathura.git"
+else
+	SRC_URI="
+		https://github.com/pwmt/zathura/archive/${PV}.tar.gz -> ${P}.tar.gz
+		https://oss.turretllc.us/manpages/${P}-manpages.tar.xz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+fi
+
+LICENSE="ZLIB"
+SLOT="0/8.9" # plugin versions api.abi (see meson.build)
+IUSE="+man landlock seccomp synctex test wayland X"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	|| ( wayland X )
+"
+
+RDEPEND="
+	dev-libs/json-glib
+	>=dev-db/sqlite-3.35:3
+	>=dev-libs/girara-2026.07.07:=[X?]
+	>=dev-libs/glib-2.84:2
+	sys-apps/file
+	x11-libs/cairo
+	>=gui-libs/gtk-4.12[wayland?,X?]
+	x11-libs/pango
+	seccomp? ( sys-libs/libseccomp )
+	synctex? ( app-text/texlive-core )
+"
+DEPEND="
+	${RDEPEND}
+	>=sys-kernel/linux-headers-5.13
+"
+BDEPEND="
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? (
+		dev-libs/appstream
+		wayland? ( dev-libs/weston[headless] )
+		X? ( x11-misc/xvfb-run )
+	)
+"
+
+src_configure() {
+	# defang automagic dependencies
+	use X || append-flags -DGENTOO_GTK_HIDE_X11
+	use wayland || append-flags -DGENTOO_GTK_HIDE_WAYLAND
+
+	local emesonargs=(
+		-Dconvert-icon=disabled
+		-Dmanpages=disabled
+		$(meson_feature landlock)
+		$(meson_feature seccomp)
+		$(meson_feature synctex)
+	)
+
+	if use test ; then
+		emesonargs+=(
+			$(meson_feature X tests-x11)
+			$(meson_feature wayland tests-wayland)
+		)
+	else
+		emesonargs+=(
+			-Dtests-x11=disabled
+			-Dtests-wayland=disabled
+		)
+	fi
+
+	meson_src_configure
+}
+
+src_test() {
+	addwrite /dev/dri
+	meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	if use seccomp || use landlock; then
+		mv "${ED}"/usr/bin/zathura{,-full} || die
+		dosym zathura-sandbox /usr/bin/zathura
+	fi
+
+	[[ ${PV} != *9999 ]] && doman "${WORKDIR}"/man/zathura*
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if use seccomp || use landlock; then
+		elog "Zathura has been installed as a symlink to zathura-sandbox due to USE"
+		elog "seccomp or USE landlock.  Some features such as printing or hyperlinks"
+		elog "may be unavailable when running with the default executable (zathura)."
+		elog "If you require these features, you can temporarily switch to using"
+		elog "zathura-full or disable these use flags."
+		if ! use elibc_glibc; then
+			ewarn ""
+			ewarn "Upstream zathura does not test sandboxing rules on non-glibc"
+			ewarn "environments.  Your mileage may vary using the sandboxed variant."
+		fi
+	fi
+}

app-text/zathura/zathura-9999.ebuild

@@ -17,24 +17,23 @@ else
 fi
 
 LICENSE="ZLIB"
-SLOT="0/6.7" # plugin versions api.abi (see meson.build)
+SLOT="0/8.9" # plugin versions api.abi (see meson.build)
 IUSE="+man landlock seccomp synctex test wayland X"
 RESTRICT="!test? ( test )"
 REQUIRED_USE="
-	test? ( wayland X )
 	|| ( wayland X )
 "
 
 RDEPEND="
 	dev-libs/json-glib
-	dev-db/sqlite:3
-	>=dev-libs/girara-2026.02.03:=[X?]
-	>=dev-libs/glib-2.76:2
+	>=dev-db/sqlite-3.35:3
+	>=dev-libs/girara-2026.07.07:=[X?]
+	>=dev-libs/glib-2.84:2
 	sys-apps/file
 	x11-libs/cairo
-	>=x11-libs/gtk+-3.24:3[wayland?,X?]
+	>=gui-libs/gtk-4.12[wayland?,X?]
 	x11-libs/pango
-	man? ( dev-python/sphinx )
+	dev-python/sphinx
 	seccomp? ( sys-libs/libseccomp )
 	synctex? ( app-text/texlive-core )
 "
@@ -47,8 +46,8 @@ BDEPEND="
 	virtual/pkgconfig
 	test? (
 		dev-libs/appstream
-		dev-libs/weston[headless]
-		x11-misc/xvfb-run
+		wayland? ( dev-libs/weston[headless] )
+		X? ( x11-misc/xvfb-run )
 	)
 "
 
@@ -59,12 +58,24 @@ src_configure() {
 
 	local emesonargs=(
 		-Dconvert-icon=disabled
-		$(meson_feature man manpages)
+		-Dmanpages=enabled
 		$(meson_feature landlock)
 		$(meson_feature seccomp)
 		$(meson_feature synctex)
-		$(meson_feature test tests)
 	)
+
+	if use test ; then
+		emesonargs+=(
+			$(meson_feature X tests-x11)
+			$(meson_feature wayland tests-wayland)
+		)
+	else
+		emesonargs+=(
+			-Dtests-x11=disabled
+			-Dtests-wayland=disabled
+		)
+	fi
+
 	meson_src_configure
 }
 
@@ -77,6 +88,11 @@ src_install() {
 	fi
 }
 
+src_test() {
+	addwrite /dev/dri
+	meson_src_test
+}
+
 pkg_postinst() {
 	xdg_pkg_postinst
 

dev-libs/girara/Manifest

@@ -1,2 +1,3 @@
 DIST girara-0.4.5.tar.gz 73664 BLAKE2B 91f4ae0e2538d035fbf7816de336584f3c96202c4a4c824147b8cfddb6324d3966fd57bbd083cda7a4ed6859177ceb3240cd5cd1f874c67f4fabc79b5b687532 SHA512 38fc0f9b9c232e93786130986e53cbcc83bbcb02575bdbd799026d2dd2f46684c8fe2ac5ea7b1b46012a48f92d78537b50a7e9ac42b036cbbf06eda06de00117
 DIST girara-2026.02.04.tar.gz 21784 BLAKE2B de860ecb1b735f47e6e968b8477e2435c387b55db07d1d92473230644e3bb426d76968b2fb6976b22d39ec336a0ce28e095f38c1a07d4326637736d10b27ee64 SHA512 65b68f5e36b872cd4310e89aabee08344921759804770a0e3a3e9e1717044e871840fe967e28ef6aa5ff971492b38d27448ff44a8f01bee69b60266bab927b76
+DIST girara-2026.07.18.tar.gz 21848 BLAKE2B e86cd8689e702acce040e02889f0dfa3086d7e5a750532fe04069759002391db6dc9e5de6f5def671fc76e22729a2131e80ece533aeefb94d437e2f8d4ca35d4 SHA512 28a9e0fd27fe8788a69a87dfd2609d0a56220a83dba9b18783a409f6bd0044e8404302a94089a06ef1a722c3e901380164a6ce1de76bfdf69fb8a5b467a1b729

dev-libs/girara/girara-2026.07.18.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic meson
+
+DESCRIPTION="UI library that focuses on simplicity and minimalism"
+HOMEPAGE="https://pwmt.org/projects/girara/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/pwmt/${PN}.git"
+	EGIT_BRANCH="develop"
+else
+	SRC_URI="https://github.com/pwmt/girara/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+fi
+
+LICENSE="ZLIB"
+SLOT="0/5.0" # SONAME (see meson.build)
+IUSE="doc X"
+
+RDEPEND="
+	>=dev-libs/glib-2.84:2
+	dev-libs/gobject-introspection
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( app-text/doxygen )
+"
+
+DOCS=( AUTHORS README.md )
+
+src_configure() {
+	# defang automagic dependencies
+	# Currently only needed for X11-specific workarounds
+	use X || append-flags -DGENTOO_GTK_HIDE_X11
+
+	local emesonargs=(
+		$(meson_feature doc docs)
+	)
+	meson_src_configure
+}
+
+src_compile() {
+	meson_src_compile
+	use doc && HTML_DOCS=( "${BUILD_DIR}"/doc/html/. ) # BUILD_DIR is set by meson_src_compile
+}

dev-libs/girara/girara-9999.ebuild

@@ -19,21 +19,13 @@ fi
 
 LICENSE="ZLIB"
 SLOT="0/5.0" # SONAME (see meson.build)
-IUSE="doc test X"
-RESTRICT="!test? ( test )"
+IUSE="doc X"
 
 RDEPEND="
-	>=dev-libs/glib-2.72:2
+	>=dev-libs/glib-2.84:2
 	dev-libs/gobject-introspection
 "
-DEPEND="
-	${RDEPEND}
-	test? (
-		x11-base/xorg-proto
-		x11-libs/gtk+:3[X]
-		x11-misc/xvfb-run
-	)
-"
+DEPEND="${RDEPEND}"
 BDEPEND="
 	sys-devel/gettext
 	virtual/pkgconfig
@@ -49,7 +41,6 @@ src_configure() {
 
 	local emesonargs=(
 		$(meson_feature doc docs)
-		$(meson_feature test tests)
 	)
 	meson_src_configure
 }