games-emulation/melonds: bump to 0.9.5_p20231231

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

games-emulation/melonds/Manifest

@@ -1 +1,2 @@
 DIST melonDS-0.9.5.tar.gz 2496704 BLAKE2B ac6b75a74df266c6220a15c8775969f19bd6ef19946c913d49b642aa797ca6dc4cd956e7a840fbdbf572a9178a214314549cfe3fc4617a4f0f3877850c6818cd SHA512 115cf04e4e22a20016ac4f2946aef917e5c9566b1a5f18599f7b7c47b0ac71e3645157a8a21622ab83683848c57ab25e6d6fcff0df559087b56642d99ffe40ec
+DIST melonDS-0.9.5_p20231231.tar.gz 3103695 BLAKE2B 36923cf1e7faf58a05eeac2152faf4ac6387a932fc7accf4be339c752171c6e2d6d7a61d5c9de40e02163a5552701c2f313da85515380e529188260b633445dc SHA512 fe99a37ba347eb6aed470d7b93e4ddbcb32ae81045d64509441ce0fa3b08da31d32b42fef7aca5f01556ae7321fb534ebc369f091e1a8852f4a45eaa7bd941a1

games-emulation/melonds/melonds-0.9.5_p20231231.ebuild

@@ -0,0 +1,90 @@
+# Copyright 2019-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="melonDS"
+MY_P="${MY_PN}-${PV}"
+
+[[ "${PV}" == *_p20231231 ]] && COMMIT=8bfc6df8de216eff0be4be1dbe37b19a741bed51
+
+inherit cmake flag-o-matic readme.gentoo-r1 toolchain-funcs xdg
+
+DESCRIPTION="Nintendo DS emulator, sorta"
+HOMEPAGE="http://melonds.kuribo64.net
+	https://github.com/Arisotura/melonDS"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/Arisotura/${MY_PN}.git"
+else
+	SRC_URI="https://github.com/Arisotura/${MY_PN}/archive/${COMMIT}.tar.gz
+		-> ${MY_P}.tar.gz"
+	S="${WORKDIR}/${MY_PN}-${COMMIT}"
+
+	KEYWORDS="~amd64"
+fi
+
+IUSE="+jit +opengl wayland"
+LICENSE="BSD-2 GPL-2 GPL-3 Unlicense"
+SLOT="0"
+
+RDEPEND="
+	app-arch/libarchive
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	media-libs/libsdl2[sound,video]
+	net-libs/libpcap
+	net-libs/libslirp
+	wayland? ( dev-libs/wayland )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="wayland? ( kde-frameworks/extra-cmake-modules:0 )"
+
+# used for JIT recompiler
+QA_EXECSTACK="usr/bin/melonDS"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="You need the following files in order to run melonDS:
+- bios7.bin
+- bios9.bin
+- firmware.bin
+- romlist.bin
+Place them in ~/.config/melonDS
+Those files can be extracted from devices or found somewhere on the Internet ;-)"
+
+src_prepare() {
+	filter-lto
+	append-flags -fno-strict-aliasing
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local -a mycmakeargs=(
+		-DBUILD_SHARED_LIBS=OFF
+		-DENABLE_JIT=$(usex jit)
+		-DENABLE_OGLRENDERER=$(usex opengl)
+		-DENABLE_WAYLAND=$(usex wayland)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	tc-export AR
+	cmake_src_compile
+}
+
+src_install() {
+	readme.gentoo_create_doc
+	cmake_src_install
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	readme.gentoo_print_elog
+}