dev-python/anyio: Bump to 4.5.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/anyio/Manifest

@@ -1 +1,2 @@
 DIST anyio-4.4.0.tar.gz 163930 BLAKE2B a37b8bc05e43cf1a4bc3f15ab399c78c7a76235942d776848307b189898973e46ddfb553bd20da154dc740d8b8bb93050ac460e56607b686bc2936c5a1e09332 SHA512 db8ad7a4faf257269de9975c3a6325023a95255a8bfe1a9642221080f44a2487160f3c0e8b220d637816e9eb3641550393a3c80b23bddafc33fd9ebe9a23b33d
+DIST anyio-4.5.0.tar.gz 169376 BLAKE2B be8b68729b9ad3c6ff39844617ebabf2b36facee5b1e4cbc9933fb6315a70daec785d2aebab9dc29d387987bee20bc6bf56f3befa9a997a4caa2ef9d7dffcc23 SHA512 12dbcc59888c555381589a820713c636f0f1a09d7999746ce5fbbdaa9a4cad5644510d036287d202db617ee16d59231a8edc824b003056bad22a189b5863c6f5

dev-python/anyio/anyio-4.5.0.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Compatibility layer for multiple asynchronous event loop implementations"
+HOMEPAGE="
+	https://github.com/agronholm/anyio/
+	https://pypi.org/project/anyio/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/idna-2.8[${PYTHON_USEDEP}]
+	>=dev-python/sniffio-1.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/typing-extensions-4.1[${PYTHON_USEDEP}]
+	' 3.10)
+"
+# On amd64, let's get more test coverage by dragging in uvloop, but let's
+# not bother on other arches where uvloop may not be supported.
+BDEPEND="
+	>=dev-python/setuptools-scm-6.4[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/exceptiongroup-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-4.0[${PYTHON_USEDEP}]
+		>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-3.6.1[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/trio-0.26.1[${PYTHON_USEDEP}]
+		' 3.{10..13})
+		amd64? (
+			$(python_gen_cond_dep '
+				>=dev-python/uvloop-0.21.0_beta1[${PYTHON_USEDEP}]
+			' python3_{10..13})
+		)
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	'>=dev-python/sphinx-rtd-theme-1.2.2' \
+	dev-python/sphinxcontrib-jquery \
+	dev-python/sphinx-autodoc-typehints
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires link-local IPv6 interface
+		tests/test_sockets.py::TestTCPListener::test_bind_link_local
+	)
+
+	local filter=()
+	if ! has_version ">=dev-python/trio-0.26.1[${PYTHON_USEDEP}]"; then
+		filter+=( -k "not trio" )
+		EPYTEST_DESELECT+=(
+			tests/test_pytest_plugin.py::test_plugin
+			tests/test_pytest_plugin.py::test_autouse_async_fixture
+			tests/test_pytest_plugin.py::test_cancel_scope_in_asyncgen_fixture
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -m 'not network' "${filter[@]}"
+}