dev-python/pydantic: add 1.9.2

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-python/pydantic/Manifest

@@ -1 +1,2 @@
 DIST pydantic-1.9.1.tar.gz 306846 BLAKE2B c22e892f403b6ca5eff7f888c68f9df5c198fa03c8dab833edc556b3b1a4819fc28c9818a649bf5d9c4bb745b0bde826e164eda7760cd26f88e278c86776ad84 SHA512 19d2a50ef054b76cc7e8756759f3d67a14a58614dd6ff1b4f60e73354b0028e08743aa3bb5944da7ae357ab279134d3685c454d6affa6524b267c7cd9a40375e
+DIST pydantic-1.9.2.tar.gz 307957 BLAKE2B ee3b188dcf058fc81b5f8491a5e757114a3b39db4d9aee3265051559f6ac25cff01bfb3b0536d0f0425534bd9a5a6444b6e6f2ef84b91a6c11085e15ac25265a SHA512 524595aea9401e82d2e985fdb5aa9b4a8b39edfed856d08e057695c786d65c3455991e4f57ce326902ff9cbed328bcb5e6f4133bda769fecea5affb68f3b4345

dev-python/pydantic/pydantic-1.9.2.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Data parsing and validation using Python type hints"
+HOMEPAGE="https://github.com/samuelcolvin/pydantic"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/python-dotenv[${PYTHON_USEDEP}]
+		>=dev-python/python-email-validator-1.2.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/CFLAGS/d' setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	if [[ ${EPYTHON} == pypy3 ]]; then
+		# do not build extensions on PyPy to workaround
+		# https://github.com/cython/cython/issues/4763
+		local -x SKIP_CYTHON=1
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_mock
+
+	local EPYTEST_DESELECT=(
+		# flaky test, known upstream
+		tests/test_hypothesis_plugin.py::test_can_construct_models_with_all_fields
+	)
+	case ${EPYTHON} in
+		python3.8)
+			EPYTEST_DESELECT+=(
+				# Those fail on python 3.8 as None changed typing semantic on >=3.9
+				"tests/test_types.py::test_none[value_type3]"
+				tests/test_typing.py::test_is_none_type
+			)
+			;;
+		pypy3)
+			EPYTEST_DESELECT+=(
+				tests/test_dataclasses.py::test_self_reference_dataclass
+				tests/test_private_attributes.py::test_private_attribute
+				tests/test_private_attributes.py::test_private_attribute_annotation
+				tests/test_private_attributes.py::test_private_attribute_factory
+				tests/test_private_attributes.py::test_private_attribute_multiple_inheritance
+				tests/test_private_attributes.py::test_underscore_attrs_are_private
+			)
+			;;
+	esac
+	rm -rf pydantic || die
+	epytest
+}