dev-util/shards: bump up to 0.13.0

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

dev-util/shards/Manifest

@@ -1,2 +1,3 @@
 DIST crystal-molinillo-0.1.0.tar.gz 23932 BLAKE2B c9bcd707a3208f5d80e6e3030523d50f86cb5977799de8ea6035d014094e3c2fff9bb189fa98f566e72e1e7ad161e47e44c89d9b264d47f109b2e891ecb469e5 SHA512 8d74d95896cd7ff510c87e2ffba6ae5f04ceeddde574930ee609851312b65d713a315cc24f9aa3fab02f9447ccb25ef2dd2e8179640b8c5cfb3d7d6b52d1ded5
 DIST shards-0.12.0.tar.gz 52205 BLAKE2B 6aed0be06f1f7e336861705fc0e29fbc3a97336f37d3a1eef09d3ea2ebaf2e61f1e5594f893974a6c13114ee575a69cf6a71fce0cc5f8985b8c365392735e8ca SHA512 3dfdf09be8701e568614923ffd5be90c63bdefc06f310c35b1b38e4b92f8bc1f432398656c08cadd36be52491f2ae8fda3c9b4117dbc4d53dbc8068b78300468
+DIST shards-0.13.0.tar.gz 55407 BLAKE2B 430abf54b5b035e966112a5b300a8924e0d6c6c4866e4cefba816c1b901876210990678a2d9b0c6bbc9da095decc217b64da32da61a5501e6045dfe64e10bfdf SHA512 7b5540b009f23cfc9630b206884a81c80a63991f64e84eed29545fef0e6a888e3854c6b0c8d958d4af3d6cef4718d7cb08d7948dcd2c9629c82b552776500b2b

dev-util/shards/shards-0.13.0.ebuild

@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multiprocessing toolchain-funcs
+
+CRYSTAL_MOLINILLO_PV=0.1.0
+CRYSTAL_MOLINILLO_P=crystal-molinillo-${CRYSTAL_MOLINILLO_PV}
+
+DESCRIPTION="Dependency manager for the Crystal language"
+HOMEPAGE="https://github.com/crystal-lang/shards"
+SRC_URI="
+	https://github.com/crystal-lang/shards/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/crystal-lang/crystal-molinillo/archive/v${CRYSTAL_MOLINILLO_PV}.tar.gz -> ${CRYSTAL_MOLINILLO_P}.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	>dev-lang/crystal-0.11.1[yaml]
+"
+RDEPEND="${DEPEND}"
+
+RESTRICT=test # missing files in tarball
+
+src_prepare() {
+	default
+
+	# bundle crystal-molinillo to bootstrap 'shards'
+	mkdir -p lib || die
+	ln -s ../../${CRYSTAL_MOLINILLO_P} lib/molinillo || die
+
+	tc-export CC
+}
+
+src_compile() {
+	emake release=1 FLAGS="--link-flags=\"${LDFLAGS}\" --verbose --threads $(makeopts_jobs)"
+}
+
+src_install() {
+	dobin bin/${PN}
+	dodoc README.md
+}