mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 22:47:14 -08:00
x11-terms/kitty: drop 0.39.0
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
This commit is contained in:
@@ -4,9 +4,6 @@ DIST kitty-0.35.2.tar.xz.sig 566 BLAKE2B 89e636f2fcd8ee12be37e41187d131d2092e667
|
||||
DIST kitty-0.38.1-vendor.tar.xz 1568124 BLAKE2B 9f8ce2c2a30f95085cd8c9096b586895074a69c1e7a310fbbf586e352423aadb0114cb1e01e6dc99f55b3e38b4c3e35942a3fcb5407c315bfe7bef19d48397fc SHA512 2578a8e1e1abb49f19a1052b12d79772ca3d3385dbf06620ee11af30c427fc89451b2a2b051833a33c51d8992988c292160fadf3f6a90e8513253c5bec6654c7
|
||||
DIST kitty-0.38.1.tar.xz 8935276 BLAKE2B 3cb8cdd8ecdefcbc0317c0ab343df8a71d257f34e0fd961bf9a5991a0a259545cc87adbc4931330eb7ec380608a67a68690f704c35469a57cc82c119bde5d3cb SHA512 273a9fc959973ad73105f5d589e420df9360bb20818165b05e14981c42f7146cec6cbb17539a91089a5af9b94dbb3f416421671bbe20cdb0b876cde5043b784c
|
||||
DIST kitty-0.38.1.tar.xz.sig 566 BLAKE2B 8915e05e08b2950c08afe7a4f79879d13561e5f1293da67f89cb8ba8b5907c2ca86fc0ad7a76cf9a16f1c956f0eeb69f6334766615e2da07e1fa2d63e45cab33 SHA512 844d12c1b3eb9e2fa3ff0b8675c58df14744c391ffd0ef3394a1fce8c8cbe9e9575a96fbbe44ee44486a706b0fb0d23c21ba28a3f1abd65861ff1d312307e43e
|
||||
DIST kitty-0.39.0-vendor.tar.xz 1575432 BLAKE2B e717e8953e59197daac236876b1922e4116d7a2934f5436a06c4f904d1f5fb7fc6cace67ce8f989c87a8c2d4815c6daa1437a7a6b816050a18be204110c2b6ca SHA512 7f24277da1216dd5465606b25b244aa795de9fcc56093310388a3cefd934f14ff5adc1b41ee676a72dbb2ebf1374603f8e908903ce9d1860c689eb78efce4c53
|
||||
DIST kitty-0.39.0.tar.xz 8938592 BLAKE2B bd9bc47e58824e18c9dd61ab83f8322abcd7b296902dde3e4bb66516b7d83991fce45d3f4580cd9cfb26f7f51f427e0f2a47dfbf695e2236b5f7042643c672fc SHA512 765f1c4bd6aa8fe751c4e0d4a44b924858ed1eb97b37beaa60e5a90b16df353e9b7db32990aa93bc960e8f01ae3de88381fe4cbc1a4dc69c0bdf655077fdf3ab
|
||||
DIST kitty-0.39.0.tar.xz.sig 566 BLAKE2B 6cc923fc0654e47bbc1ad856258f545f52f392518c90d876a5310ada6e3dff11d6137efa714647c22c7c7b552222d3f23e41b1e08ae0ebf769c09d7778038f65 SHA512 c92aa044cb1a82832e8fdb172eaeddb14eb869a025b29bcfa7bb34098f11896fe41059ecc8c46e9906a186cd4dcd07f4e8c713a56fa623cfdc11391a7b2c4129
|
||||
DIST kitty-0.39.1-vendor.tar.xz 1575868 BLAKE2B 32187f48becc430eb3ecda990dc8e01977fb80676689caff11c7061434d8b3f1cf26ddeffa26db61d9949f96551dd6d78422a068e03b03c3ac4b9dd0b5cc4e5a SHA512 796b3f91f7539c78a3a2995cb1d73424fdb5159f8328d331ece54a028830f73583bed840b7c0cb75a1cc3e516cdf6a2d1b5a80c545d8b90826f6898430488d3c
|
||||
DIST kitty-0.39.1.tar.xz 8942308 BLAKE2B cb9eec3a8e568ef2caa5d50b52d13c2a0acc5f090dce40d0a6ae1bd4c2d78164506e6416d0d915f2c0028af1d7bbbc8b98bc81b2ff8831f3ce9e33374a0f27a9 SHA512 50d8e083e63fb5ccee5d6a4d7a3d07e775fe609307ad724527cd50ab33a7023d4e6694dd08ce322e643806fdcf92c0e990f14212ad168dbf4f39b8a666634000
|
||||
DIST kitty-0.39.1.tar.xz.sig 566 BLAKE2B ad055db8e0de99ceea2745f795ad629dc7237a7a02527c4dc1de9eba02f2498ef009e088081036c154b9b66e166d89462d1ce31708f30fa167528e61a2d1724b SHA512 0cdca0dac72d3e1679858efffd5dc30fa224ec40b774922778cb33d39974713a5847d7b41b485cdb4db5e33e0c084d36d1b2aa27434414ae2c4b3dd97e1883ee
|
||||
|
||||
@@ -1,187 +0,0 @@
|
||||
# Copyright 1999-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
PYTHON_COMPAT=( python3_{10..13} )
|
||||
inherit edo go-env optfeature multiprocessing
|
||||
inherit python-single-r1 toolchain-funcs xdg
|
||||
|
||||
if [[ ${PV} == 9999 ]]; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://github.com/kovidgoyal/kitty.git"
|
||||
else
|
||||
inherit verify-sig
|
||||
SRC_URI="
|
||||
https://github.com/kovidgoyal/kitty/releases/download/v${PV}/${P}.tar.xz
|
||||
https://dev.gentoo.org/~ionen/distfiles/${P}-vendor.tar.xz
|
||||
verify-sig? ( https://github.com/kovidgoyal/kitty/releases/download/v${PV}/${P}.tar.xz.sig )
|
||||
"
|
||||
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/kovidgoyal.gpg
|
||||
KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
|
||||
fi
|
||||
|
||||
DESCRIPTION="Fast, feature-rich, GPU-based terminal"
|
||||
HOMEPAGE="https://sw.kovidgoyal.net/kitty/"
|
||||
|
||||
LICENSE="GPL-3 ZLIB"
|
||||
LICENSE+=" Apache-2.0 BSD BSD-2 MIT MPL-2.0" # go
|
||||
SLOT="0"
|
||||
IUSE="+X test wayland"
|
||||
REQUIRED_USE="
|
||||
${PYTHON_REQUIRED_USE}
|
||||
|| ( X wayland )
|
||||
test? ( X wayland )
|
||||
"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
# dlopen: fontconfig,libglvnd
|
||||
RDEPEND="
|
||||
${PYTHON_DEPS}
|
||||
dev-libs/openssl:=
|
||||
dev-libs/xxhash
|
||||
media-fonts/symbols-nerd-font
|
||||
media-libs/fontconfig
|
||||
media-libs/harfbuzz:=[truetype]
|
||||
media-libs/lcms:2
|
||||
media-libs/libglvnd[X?]
|
||||
media-libs/libpng:=
|
||||
sys-apps/dbus
|
||||
sys-libs/zlib:=
|
||||
x11-libs/libxkbcommon[X?]
|
||||
x11-misc/xkeyboard-config
|
||||
~x11-terms/kitty-shell-integration-${PV}
|
||||
~x11-terms/kitty-terminfo-${PV}
|
||||
X? (
|
||||
x11-libs/libX11
|
||||
x11-libs/libXcursor
|
||||
)
|
||||
wayland? ( dev-libs/wayland )
|
||||
!sci-mathematics/kissat
|
||||
"
|
||||
DEPEND="
|
||||
${RDEPEND}
|
||||
amd64? ( >=dev-libs/simde-0.8.0-r1 )
|
||||
arm64? ( dev-libs/simde )
|
||||
x86? ( dev-libs/simde )
|
||||
X? (
|
||||
x11-base/xorg-proto
|
||||
x11-libs/libXi
|
||||
x11-libs/libXinerama
|
||||
x11-libs/libXrandr
|
||||
)
|
||||
wayland? ( dev-libs/wayland-protocols )
|
||||
"
|
||||
# bug #919751 wrt go subslot
|
||||
BDEPEND="
|
||||
${PYTHON_DEPS}
|
||||
>=dev-lang/go-1.23:=
|
||||
sys-libs/ncurses
|
||||
virtual/pkgconfig
|
||||
test? ( $(python_gen_cond_dep 'dev-python/pillow[${PYTHON_USEDEP}]') )
|
||||
wayland? ( dev-util/wayland-scanner )
|
||||
"
|
||||
[[ ${PV} == 9999 ]] || BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-kovidgoyal )"
|
||||
|
||||
QA_FLAGS_IGNORED="usr/bin/kitten" # written in Go
|
||||
|
||||
src_unpack() {
|
||||
if [[ ${PV} == 9999 ]]; then
|
||||
git-r3_src_unpack
|
||||
cd "${S}" || die
|
||||
edo go mod vendor
|
||||
else
|
||||
use verify-sig &&
|
||||
verify-sig_verify_detached "${DISTDIR}"/${P}.tar.xz{,.sig}
|
||||
default
|
||||
fi
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# sed unfortunately feels easier on maintenance than patches here
|
||||
local sedargs=(
|
||||
-e "/num_workers =/s/=.*/= $(makeopts_jobs)/"
|
||||
-e "s/cflags.append.*-O3.*/pass/" -e 's/-O3//'
|
||||
-e "s/cflags.append(fortify_source)/pass/" # use toolchain's _f_s
|
||||
-e "s/ld_flags.append('-[sw]')/pass/"
|
||||
)
|
||||
|
||||
# kitty is often popular on wayland-only setups, try to allow this
|
||||
use !X && sedargs+=( -e '/gl_libs =/s/=.*/= []/' ) #857918
|
||||
use !X || use !wayland &&
|
||||
sedargs+=( -e "s/'x11 wayland'/'$(usex X x11 wayland)'/" )
|
||||
|
||||
# skip docs for live version, missing dependencies
|
||||
[[ ${PV} == 9999 ]] && sedargs+=( -e '/exists.*_build/,/docs(ddir)/d' )
|
||||
|
||||
sed -i setup.py "${sedargs[@]}" || die
|
||||
|
||||
local skiptests=(
|
||||
# relies on 'who' command which doesn't detect users with pid-sandbox
|
||||
kitty_tests/utmp.py
|
||||
# may fail/hang depending on environment and shell initialization
|
||||
kitty_tests/{shell_integration,ssh}.py
|
||||
# relies on /proc/self/fd and gets confused when ran from here
|
||||
tools/utils/tpmfile_test.go
|
||||
)
|
||||
use !test || rm "${skiptests[@]}" || die
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
tc-export CC
|
||||
local -x PKGCONFIG_EXE=$(tc-getPKG_CONFIG)
|
||||
|
||||
go-env_set_compile_environment
|
||||
local -x GOFLAGS="-p=$(makeopts_jobs) -v -x -buildvcs=false"
|
||||
use ppc64 && [[ $(tc-endian) == big ]] || GOFLAGS+=" -buildmode=pie"
|
||||
|
||||
local conf=(
|
||||
--disable-link-time-optimization
|
||||
--ignore-compiler-warnings
|
||||
--libdir-name=$(get_libdir)
|
||||
--shell-integration="enabled no-rc no-sudo"
|
||||
--update-check-interval=0
|
||||
--verbose
|
||||
)
|
||||
|
||||
edo "${EPYTHON}" setup.py linux-package "${conf[@]}"
|
||||
use test && edo "${EPYTHON}" setup.py build-launcher "${conf[@]}"
|
||||
|
||||
rm -r linux-package/share/terminfo || die # provided by kitty-terminfo
|
||||
|
||||
if [[ ${PV} == 9999 ]]; then
|
||||
mkdir -p linux-package/share/doc/${PF} || die
|
||||
else
|
||||
mv linux-package/share/doc/{${PN},${PF}} || die
|
||||
fi
|
||||
|
||||
# generate default config as reference, command taken from docs/conf.rst
|
||||
if ! tc-is-cross-compiler; then
|
||||
linux-package/bin/kitty +runpy \
|
||||
'from kitty.config import *; print(commented_out_default_config())' \
|
||||
> linux-package/share/doc/${PF}/kitty.conf || die
|
||||
fi
|
||||
}
|
||||
|
||||
src_test() {
|
||||
KITTY_CONFIG_DIRECTORY=${T} ./test.py || die # shebang is kitty
|
||||
}
|
||||
|
||||
src_install() {
|
||||
edo mv linux-package "${ED}"/usr
|
||||
|
||||
# kitty currently detects and copies the system's nerd font at build
|
||||
# time, then uses that rather than the system's at runtime
|
||||
dosym -r /usr/share/fonts/symbols-nerd-font/SymbolsNerdFontMono-Regular.ttf \
|
||||
/usr/"$(get_libdir)"/kitty/fonts/SymbolsNerdFontMono-Regular.ttf
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
|
||||
optfeature "audio-based terminal bell support" media-libs/libcanberra
|
||||
use X && optfeature "X11 startup notification support" x11-libs/startup-notification
|
||||
optfeature "opening links from the terminal" x11-misc/xdg-utils
|
||||
}
|
||||
Reference in New Issue
Block a user