media-libs/glycin-loaders: Bump to 1.2.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

media-libs/glycin-loaders/Manifest

@@ -1 +1,2 @@
 DIST glycin-1.2.1.tar.xz 37164676 BLAKE2B b2dc127a174b71fb4e4bb3070bf7dded3a6011aa4c1bcb11bad831ff6cf866b14ce7f20dbc8b5190d476dbfdf2c742d9505ab3c40c22b03336ba133159a9d49a SHA512 dd69e123f517ded3686b98a833451e58a26a6dde8976e582520de04c8fb075039c676a426b39c41639273a15b7c32012e0288664d8a854ba44eeb65f35827e06
+DIST glycin-1.2.2.tar.xz 37165060 BLAKE2B e710af8e09c224ef119f09f9ae2702add688c65c78ab06b7b8daebaaef5b40b5e55fa3c1bfbf8bd5446b70250a315c3bb415c301f5183264141c789f254336d0 SHA512 f6a358d0809679c3000ff7720e450f19550c44c5c044964e7fe235524f8fafb061fe929fad4dfd1c9d067d1984d44fdb10717add7ace15df53d5a2039a3b6adb

media-libs/glycin-loaders/glycin-loaders-1.2.2.ebuild

@@ -0,0 +1,95 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# crates vendored upstream
+CRATES="
+"
+
+RUST_MIN_VERSION=1.80.0
+
+inherit cargo meson
+
+MY_P=glycin-${PV/_/.}
+DESCRIPTION="Loaders for glycin clients (glycin crate or libglycin)"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/glycin/"
+SRC_URI="
+	https://download.gnome.org/sources/glycin/$(ver_cut 1-2)/${MY_P}.tar.xz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="|| ( LGPL-2.1+ MPL-2.0 )"
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD GPL-3+ ISC LGPL-3+
+	MIT Unicode-3.0
+	|| ( LGPL-2.1+ MPL-2.0 )
+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="heif jpegxl svg test"
+REQUIRED_USE="test? ( heif jpegxl )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.60:2
+	>=sys-libs/libseccomp-2.5.0
+	heif? ( >=media-libs/libheif-1.17.0:= )
+	jpegxl? ( >=media-libs/libjxl-0.10.0:= )
+	svg? (
+		>=gnome-base/librsvg-2.52.0:2
+		>=x11-libs/cairo-1.17.0
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		>=gui-libs/gtk-4.16.0:4
+		>=media-libs/lcms-2.14:2
+	)
+"
+BDEPEND="
+	test? (
+		sys-apps/bubblewrap
+		sys-apps/dbus
+	)
+"
+
+ECARGO_VENDOR=${S}/vendor
+
+QA_FLAGS_IGNORED="usr/libexec/glycin-loaders/.*"
+
+src_prepare() {
+	default
+
+	# https://gitlab.gnome.org/GNOME/glycin/-/issues/81
+	sed -i -e '\|/fonts|d' tests/tests.rs || die
+}
+
+src_configure() {
+	local formats=(
+		$(usev heif glycin-heif)
+		$(usev jpegxl glycin-jxl)
+		$(usev svg glycin-svg)
+		glycin-image-rs
+	)
+	local formats_s=${formats[*]}
+	local emesonargs=(
+		-Dprofile=$(usex debug dev release)
+		-Dglycin-loaders=true
+		-Dloaders="${formats_s// /,}"
+		-Dtests=$(usex test true false)
+		-Dlibglycin=false
+	)
+
+	meson_src_configure
+	ln -s "${CARGO_HOME}" "${BUILD_DIR}/cargo-home" || die
+}
+
+src_test() {
+	# tests write to /proc/*/uid_map
+	# apparently, "addpredict /" in Portage breaks it
+	local -x SANDBOX_ON=0
+	meson_src_test
+}