games-emulation/mgba: Bump to version 0.9.2

Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

games-emulation/mgba/Manifest

@@ -1,2 +1,3 @@
 DIST mgba-0.8.4.tar.gz 12347906 BLAKE2B 7cea3bc3d291df5ac430685d261de1817798d24abbc2ea4d1fbffb55083ba130a80b6baec75513d616523daf28d0a74a53b5a1a657c1420b73caf6c5058093f8 SHA512 fe9c022211d03eb8a5db23901b2f99a5ee75a40f104e5edb2c6fd1a2860a37d9a3ba8d3b724b35ef958840986dd09002c58740a176290b415826e1a345d90390
 DIST mgba-0.9.1.tar.gz 12795893 BLAKE2B ec2308721683b8f00ada740f5020bef5eb0ef2fc8fc241dae0d81f92c51c4d91bfa23950370e2f9a4184daa31552d8f03bcccef9abe10bb7657b8bffec529486 SHA512 f818bbcb8d38a2caced9ccb96aa81b392c5f75860af0c16848c9ce2046f17328829cf45a00b211326bfab86c3cac76ae341dc54ab91e1b548085b1d1198a2578
+DIST mgba-0.9.2.tar.gz 12761919 BLAKE2B f0f3ca5f47d38c8018541426a229d52a2ebc9e47dc07fe4b739bde3f7ef2a4d75e6db5ca5f8dfaee01ae9648035f24c9d02556078b0b5eb51aefecfc9305432d SHA512 ea9868c104996c44a2fcfdf9d3f4d6177b853dec478ab7a2dd19a0f127b597a887150200bfbf14de593328217ff5493ca675bfcb4f0b2ee6a5097e0cdf0e2997

games-emulation/mgba/mgba-0.9.2.ebuild

@@ -0,0 +1,128 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake desktop xdg
+
+DESCRIPTION="Game Boy Advance emulator written in C"
+HOMEPAGE="https://mgba.io"
+if [[ "${PV}" == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mgba-emu/mgba.git"
+else
+	MY_PV="${PV/_beta/-b}"
+	SRC_URI="https://github.com/${PN}-emu/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	[[ "${PV}" == *_beta* ]] || \
+	KEYWORDS="~amd64 ~arm64 ~x86"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+fi
+LICENSE="MPL-2.0"
+SLOT="0"
+IUSE="debug discord elf ffmpeg gles2 gles3 opengl qt5 +sdl sqlite"
+REQUIRED_USE="|| ( qt5 sdl )
+		qt5? ( opengl )"
+
+RDEPEND="
+	media-libs/libpng:0=
+	sys-libs/zlib[minizip]
+	debug? ( dev-libs/libedit )
+	elf? ( dev-libs/elfutils )
+	ffmpeg? ( media-video/ffmpeg:= )
+	opengl? ( media-libs/libglvnd )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtmultimedia:5
+		dev-qt/qtwidgets:5
+		opengl? ( dev-qt/qtopengl:5 )
+	)
+	sdl? ( media-libs/libsdl2[X,sound,joystick,video,opengl?] )
+	sqlite? ( dev-db/sqlite:3 )
+"
+DEPEND="${RDEPEND}
+	gles2? ( media-libs/libglvnd )
+	gles3? ( media-libs/libglvnd )
+"
+
+src_prepare() {
+	xdg_environment_reset
+	cmake_src_prepare
+
+	# Get rid of any bundled stuff we don't want
+	local pkg
+	for pkg in libpng lzma sqlite3 zlib ; do
+		rm -r src/third-party/${pkg} || die
+	done
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_GL="$(usex opengl)"
+		-DBUILD_GLES2="$(usex gles2)"
+		-DBUILD_GLES3="$(usex gles3)"
+		-DBUILD_PYTHON=OFF
+		-DBUILD_QT="$(usex qt5)"
+		-DBUILD_SDL="$(usex sdl)"
+		-DBUILD_SHARED=ON
+		# test suite fails to build (>=0.6.0)
+		-DBUILD_SUITE=OFF
+		-DBUILD_TEST=OFF
+		-DM_CORE_GB=ON
+		-DM_CORE_GBA=ON
+		-DUSE_DEBUGGERS="$(usex debug)"
+		-DUSE_DISCORD_RPC="$(usex discord)"
+		-DUSE_EDITLINE="$(usex debug)"
+		-DUSE_ELF="$(usex elf)"
+		-DUSE_EPOXY=OFF
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_GDB_STUB="$(usex debug)"
+		-DUSE_LIBZIP=OFF
+		-DUSE_LZMA=OFF
+		-DUSE_MINIZIP=ON
+		-DUSE_PNG=ON
+		-DUSE_SQLITE3="$(usex sqlite)"
+		-DUSE_ZLIB=ON
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_install() {
+	if use qt5 ; then
+		dobin ${BUILD_DIR}/qt/${PN}-qt
+		doman doc/${PN}-qt.6
+		domenu res/${PN}-qt.desktop
+		for size in 16 24 32 48 64 96 128 256 ; do
+			newicon -s ${size} res/${PN}-${size}.png ${PN}.png
+		done
+	fi
+	if use sdl ; then
+		doman doc/${PN}.6
+		newbin ${BUILD_DIR}/sdl/${PN} ${PN}-sdl
+	fi
+
+	dolib.so ${BUILD_DIR}/lib${PN}.so*
+}
+
+pkg_preinst() {
+	if use qt5 ; then
+		xdg_pkg_preinst
+	fi
+}
+
+pkg_postinst() {
+	if use qt5 ; then
+		xdg_pkg_postinst
+	fi
+}
+
+pkg_postrm() {
+	if use qt5 ; then
+		xdg_pkg_postrm
+	fi
+}