kde-apps/marble: 20.04.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2020-07-09 17:36:33 +02:00
parent 73bff488e2
commit 69ee9149fd
2 changed files with 100 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST marble-19.12.3.tar.xz 52306988 BLAKE2B 728b731b066c8fbec442059dbbe5697d610218b7733f365a655462f05d49f84497c6e7c4425929d2972201680d6b705f6a77652953cba937f55218d430a5bc1f SHA512 e6b693b15be53f590bbfbd97648113bad696339544350640699e890bc4f891c4a06215ee09f21cf4968dc8d2cb104c06f43380470145397fc5abc7daa0e02639
DIST marble-20.04.2.tar.xz 52206460 BLAKE2B ad7f9a30a8c75b4978fa5f015c9bc38a6bd16c95f4f92a9fb73f5f0126cf11a4b985aafd249052aa141365c498549db2265f50a894b4b8a95944394340cbcf75 SHA512 44a0a6ad7aa77452482d86ffc88083ed1adc187b1ecb34dd5d5c211e6a692019cfa06579647a7943c423fdc911300e0efb8352de95da84ce9c27aeb4f1365b55
DIST marble-20.04.3.tar.xz 52200548 BLAKE2B 83388e292487dbbe10bde4f4d67337b8d8606df26fda3621640cf49a1a930b6cdb9357a96568fc33597f0ee2627a22a2f2920a7dad45bab1502e5a8869934de1 SHA512 5c29b0a25164b50f197c826258d8de8b4e1a386d91fa7a6f67eb3da64197b2cefef31b0759c3bd19e9a5b0f0c639adc779d71a7ef1d7b51fca4e58cc3c8530cd
+99
View File
@@ -0,0 +1,99 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
ECM_HANDBOOK="optional" # see src/apps/marble-kde/CMakeLists.txt
ECM_TEST="forceoptional"
KFMIN=5.70.0
QTMIN=5.14.2
VIRTUALX_REQUIRED="test"
inherit ecm kde.org
DESCRIPTION="Virtual Globe and World Atlas to learn more about Earth"
HOMEPAGE="https://marble.kde.org/"
LICENSE="GPL-2" # TODO: CHECK
SLOT="5/$(ver_cut 1-2)"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE="aprs +dbus designer gps +kde nls phonon +geolocation shapefile +webengine"
# FIXME (new package): libwlocate, WLAN-based geolocation
BDEPEND="
aprs? ( dev-lang/perl )
nls? ( >=dev-qt/linguist-tools-${QTMIN}:5 )
"
DEPEND="
>=dev-qt/qtconcurrent-${QTMIN}:5
>=dev-qt/qtdeclarative-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtnetwork-${QTMIN}:5
>=dev-qt/qtprintsupport-${QTMIN}:5
>=dev-qt/qtsql-${QTMIN}:5
>=dev-qt/qtsvg-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=dev-qt/qtxml-${QTMIN}:5
sys-libs/zlib
aprs? ( >=dev-qt/qtserialport-${QTMIN}:5 )
dbus? ( >=dev-qt/qtdbus-${QTMIN}:5 )
designer? ( >=dev-qt/designer-${QTMIN}:5 )
geolocation? ( >=dev-qt/qtpositioning-${QTMIN}:5 )
gps? ( sci-geosciences/gpsd )
kde? (
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kcrash-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/knewstuff-${KFMIN}:5
>=kde-frameworks/kparts-${KFMIN}:5
>=kde-frameworks/krunner-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/kwallet-${KFMIN}:5
)
phonon? ( media-libs/phonon[qt5(+)] )
shapefile? ( sci-libs/shapelib:= )
webengine? (
>=dev-qt/qtwebchannel-${QTMIN}:5
>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
)
"
RDEPEND="${DEPEND}"
# bug 588320
RESTRICT+=" test"
src_prepare() {
ecm_src_prepare
rm -rf src/3rdparty/zlib || die "Failed to remove bundled libs"
if use kde; then
sed -e "/add_subdirectory(marble-qt)/ s/^/#DONT/" \
-i src/apps/CMakeLists.txt || die "Failed to disable marble-qt"
fi
}
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package aprs Perl)
$(cmake_use_find_package geolocation Qt5Positioning)
-DBUILD_MARBLE_TESTS=$(usex test)
-DWITH_DESIGNER_PLUGIN=$(usex designer)
-DWITH_libgps=$(usex gps)
-DWITH_KF5=$(usex kde)
-DWITH_Phonon4Qt5=$(usex phonon)
-DWITH_libshp=$(usex shapefile)
$(cmake_use_find_package webengine Qt5WebEngine)
$(cmake_use_find_package webengine Qt5WebEngineWidgets)
-DWITH_libwlocate=OFF
# bug 608890
-DKDE_INSTALL_CONFDIR="/etc/xdg"
)
if use kde; then
ecm_src_configure
else
cmake_src_configure
fi
}