media-video/xine-ui: bump to 0.99.13

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Alexis Ballier <aballier@gentoo.org>

media-video/xine-ui/Manifest

@@ -1 +1,2 @@
 DIST xine-ui-0.99.12.tar.xz 1980672 BLAKE2B ac1a9b17b48005c667d53129e51f4db2cfe2933c0fca9ba8b6f1d999f903568217a061c84806abfec31d4afcc238579c232a1ae6f4b04afcac465c340826f037 SHA512 bc04cb8df730abce147485b488250331a304e4318fc28ebab890c6485242a5edeafd953547c637622e2312c65aa1e36aaae6117d608dd668781d841804f2ae86
+DIST xine-ui-0.99.13.tar.xz 2156892 BLAKE2B edb4cb082faeba5f9f64ea06f6561d471fddfc7672dd92ec1a0a99b5c8eb10f46c15df2044fa2a4eaafdeab1fa56d990afa443f912602fdc676d1e34e3cf6c84 SHA512 a0802d767a805c462f7ae05fa5c4860af5c281ffa74c70a6c2c8a3ecbf8060e6f3f40fed215e27a823985c7d5c3484715cbbe5e4bf43655353f59fa2230b41e7

media-video/xine-ui/xine-ui-0.99.13.ebuild

@@ -0,0 +1,100 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools gnome2-utils xdg-utils
+
+DESCRIPTION="Xine movie player"
+HOMEPAGE="https://xine-project.org/home"
+SRC_URI="mirror://sourceforge/xine/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~riscv ~x86"
+IUSE="aalib curl debug libcaca lirc nls readline vdr X xinerama"
+
+RDEPEND="
+	|| ( app-arch/tar app-arch/libarchive )
+	media-libs/libpng:0=
+	>=media-libs/xine-lib-1.2:=[aalib?,libcaca?]
+	virtual/jpeg:0
+	aalib? ( media-libs/aalib:= )
+	curl? ( >=net-misc/curl-7.10.2:= )
+	libcaca? ( media-libs/libcaca:= )
+	lirc? ( app-misc/lirc:= )
+	nls? ( virtual/libintl )
+	readline? ( >=sys-libs/readline-6.2:= )
+	X? (
+		x11-libs/libICE:=
+		x11-libs/libSM:=
+		x11-libs/libX11:=
+		x11-libs/libXext:=
+		x11-libs/libXft:=
+		x11-libs/libXrender:=
+		x11-libs/libXScrnSaver:=
+		x11-libs/libXtst:=
+		x11-libs/libXv:=
+		x11-libs/libXxf86vm:=
+		xinerama? ( x11-libs/libXinerama:= )
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( >=sys-devel/gettext-0.18.3 )
+	X? (
+		x11-base/xorg-proto
+		x11-libs/libXt
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.99.10-desktop.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+	rm misc/xine-bugreport || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		$(use_enable xinerama) \
+		$(use_enable lirc) \
+		$(use_enable vdr vdr-keys) \
+		--disable-nvtvsimple \
+		$(use_enable debug) \
+		$(use_with X x) \
+		$(use_with readline) \
+		$(use_with curl) \
+		$(use_with aalib) \
+		$(use_with libcaca caca) \
+		--without-fb
+}
+
+src_install() {
+	# xine-list apparently may cause sandbox violation, bug 654394
+	addpredict /dev/dri
+
+	emake \
+		DESTDIR="${D}" \
+		docdir="/usr/share/doc/${PF}" \
+		docsdir="/usr/share/doc/${PF}" \
+		install
+
+	einstalldocs
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}