media-gfx/photoqt: add 4.8.1

useflag : add test
all options renamed

deps :
qtbase : add sqlite (required), opengl (already implicit), icu (sorting)
qtcharts[qml] : for histogram
imagemagick : add hdri as upstream set it as compile_definitions
graphicsmagick : includedir is fixed

Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr>
Closes: https://github.com/gentoo/gentoo/pull/40562
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Nicolas PARLANT
2025-03-24 05:22:24 +00:00
committed by Sam James
parent 368b2e6903
commit 68a8bb5119
2 changed files with 108 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST photoqt-4.7.tar.gz 3612004 BLAKE2B f4bfd07103e614e3b128668ee7b1dc4767d5c8bd6af4164315e75d537e4054ee2e13fd2f2d8f044669c80bfa31d0651a5a71f07d0947c6b8f1a3088d55123407 SHA512 41274b52ece3a905de7c274183b658b40fdc72ee291b008afdfb2c7e8bb49308ac54c66760397359838bcd9470aa0140bd769137d5a72cd1c11bc4b1a7accb66
DIST photoqt-4.8.1.tar.gz 5422370 BLAKE2B dba86453107445ebbd4236f8c443c73c6416788ba0355d15be677deae9de1c33a4733ea0233d7d10813a6a0ce61e61eb5be2859b6c771cab2770c1cbd6fa8fa4 SHA512 89cc4b87aad4668fa6f44181b164816736ec21a8151fef96959c9a7a5b050173d385d73bd1615a758974abfde4eed338e348f03fce6c902fa6e1a7ff285279f9
+107
View File
@@ -0,0 +1,107 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
inherit cmake optfeature python-single-r1 xdg
DESCRIPTION="Simple but powerful Qt-based image viewer"
HOMEPAGE="https://photoqt.org/"
SRC_URI="https://photoqt.org/downloads/source/${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="barcode chromecast devil exif freeimage geolocation graphicsmagick +imagemagick lcms mpv pdf raw test vips"
REQUIRED_USE="chromecast? ( ${PYTHON_REQUIRED_USE} )"
RESTRICT="!test? ( test )"
COMMON_DEPEND="
app-arch/libarchive:=
dev-libs/pugixml
dev-qt/qtbase:6[concurrent,dbus,gui,icu,network,opengl,sql,sqlite,widgets,xml]
dev-qt/qtdeclarative:6[opengl]
dev-qt/qtimageformats:6
dev-qt/qtmultimedia:6[qml]
dev-qt/qtsvg:6
barcode? ( media-libs/zxing-cpp:= )
chromecast? (
${PYTHON_DEPS}
$(python_gen_cond_dep 'dev-python/pychromecast')
)
devil? ( media-libs/devil )
exif? ( media-gfx/exiv2:=[bmff] )
freeimage? ( media-libs/freeimage )
imagemagick? (
!graphicsmagick? ( media-gfx/imagemagick:=[cxx,hdri] )
graphicsmagick? ( media-gfx/graphicsmagick:=[cxx] )
)
lcms? ( media-libs/lcms:2 )
mpv? ( media-video/mpv:=[libmpv] )
pdf? ( app-text/poppler[qt6] )
raw? ( media-libs/libraw:= )
vips? (
dev-libs/glib:2
media-libs/vips:=
)
"
RDEPEND="${COMMON_DEPEND}
dev-qt/qtcharts:6[qml]
geolocation? (
dev-qt/qtlocation:6
dev-qt/qtpositioning:6[qml]
)
"
DEPEND="${COMMON_DEPEND}
vips? ( x11-base/xorg-proto )
"
BDEPEND="
dev-qt/qttools:6[linguist]
>=kde-frameworks/extra-cmake-modules-6.5.0:*
virtual/pkgconfig
chromecast? ( ${PYTHON_DEPS} )
"
pkg_setup() {
use chromecast && python-single-r1_pkg_setup
}
src_configure() {
local mycmakeargs=(
-DWITH_CHROMECAST=$(usex chromecast)
-DWITH_DEVIL=$(usex devil)
-DWITH_EXIV2=$(usex exif)
-DWITH_EXIV2_ENABLE_BMFF=$(usex exif)
-DWITH_FREEIMAGE=$(usex freeimage)
-DWITH_GRAPHICSMAGICK=$(usex graphicsmagick $(usex imagemagick))
-DWITH_IMAGEMAGICK=$(usex imagemagick $(usex !graphicsmagick))
-DWITH_LCMS2=$(usex lcms)
-DWITH_LOCATION=$(usex geolocation)
-DWITH_VIDEO_MPV=$(usex mpv)
-DWITH_POPPLER=$(usex pdf)
-DWITH_LIBRAW=$(usex raw)
-DWITH_RESVG=OFF # qt5 only
-DWITH_TESTING=$(usex test)
-DWITH_LIBVIPS=$(usex vips)
-DWITH_ZXING=$(usex barcode)
)
cmake_src_configure
}
src_test() {
local -x QT_QPA_PLATFORM=offscreen
# QCollator::setNumericMode is not supported w/ POSIX/C locale or w/o icu
# Unset and source LC_COLLATE from the current system locale.
# Required for PQCTest::getFoldersIn()
unset LC_COLLATE
source "${EPREFIX}"/etc/env.d/02locale
[ -n "${LC_COLLATE}" ] && export LC_COLLATE
"${BUILD_DIR}"/photoqt_test || die
}
pkg_postinst() {
optfeature "additional image formats like AVIF, EPS, HEIF/HEIC, PSD, etc." "kde-frameworks/kimageformats:6"
xdg_pkg_postinst
}