gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-25 07:08:13 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/pikepdf: Bump to 9.3.0

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2024-10-01 06:01:58 +02:00
parent 12426768d4
commit 681082abc0
2 changed files with 75 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/pikepdf/Manifest
View File

@@ -1,3 +1,4 @@
DIST pikepdf-9.1.1.tar.gz 2869514 BLAKE2B b196a61d599db1355695d40ac69e09ea7a020cb10c246685792b7f6f7854b5dce63dd2f675a542fa256ac713c7a7ce49ba7ddd248fbe901fe267641df399ca74 SHA512 0b3c2c89d9226212806791e00470c2c64147f0738d26bfe9c5288414cf515760213e3cdc70a62ef3f53a0ee43b7d8e2cc0076f14fe22bdbac2ff50e0a8984164
DIST pikepdf-9.1.2.tar.gz 2869865 BLAKE2B 74b64d628f12a5335a9dfbe2e15fbbd0a39e266100bcc8b33e94c954aab91150f46649b181bf049cd1084a6d2412ea9485cc57d4d6a23a4678a5ea55ebbb7357 SHA512 676d68f05a506b6aa69e1b01d03164de6731d17b48d2cd4b123221ebe27aef04a75d458c897c53d504a0b3aa7d0bc3e78aaf707a3cfdcdf8d31ee5e537188bd3
DIST pikepdf-9.2.1.tar.gz 2905740 BLAKE2B cee801fcb231f2537ce75555b10d68de9acc62e7824c26a00960293d056ae08dfd79607115ca110204af95bee99b57040ba408d47453636413c1291ba4e8e7cf SHA512 5b99272c3a98499770bb3120ead62ebdda731210e0305ec143809fcea7f978bf5dd4f4f7b90b6392af40b1e2c6e79a83e6a67d54a238fc398e38cf2bd675bc30
DIST pikepdf-9.3.0.tar.gz 2905550 BLAKE2B 62b3a1d655fb5b3e4d315a3feaeb14a043048c5985f5cf99812c07e1d248ae52cb1734dbd091103f36a3fd5a981c89b57208fb50f5c1081e08e3c20ec728ff9c SHA512 3325ab06c285f8f51c66c3815b15f96b0730e38f8023ce5c1e46818c581c38ab3bd89875e5de6ce1064a5929a8c386740d76e662c82d00d9c46961c56da4f0c0

74
dev-python/pikepdf/pikepdf-9.3.0.ebuild Normal file
View File

@@ -0,0 +1,74 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..13} pypy3 )
inherit distutils-r1 pypi
DESCRIPTION="Python library to work with pdf files based on qpdf"
HOMEPAGE="
https://github.com/pikepdf/pikepdf/
https://pypi.org/project/pikepdf/
"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="big-endian"
# Check QPDF_MIN_VERSION in pyproject.toml on bumps, as well as
# https://qpdf.readthedocs.io/en/stable/release-notes.html.
DEPEND="
>=app-text/qpdf-11.5.0:0=
"
RDEPEND="
${DEPEND}
dev-python/deprecated[${PYTHON_USEDEP}]
>=dev-python/lxml-4.0[${PYTHON_USEDEP}]
dev-python/packaging[${PYTHON_USEDEP}]
>=dev-python/pillow-10.0.1[lcms,${PYTHON_USEDEP}]
"
BDEPEND="
>=dev-python/pybind11-2.12.0[${PYTHON_USEDEP}]
>=dev-python/setuptools-scm-7.0.5[${PYTHON_USEDEP}]
test? (
>=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
>=dev-python/hypothesis-6.36[${PYTHON_USEDEP}]
>=dev-python/numpy-1.21.0[${PYTHON_USEDEP}]
>=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
>=dev-python/pytest-timeout-2.1.0[${PYTHON_USEDEP}]
>=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
!big-endian? (
>=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
)
$(python_gen_cond_dep '
dev-python/tomli[${PYTHON_USEDEP}]
' 3.10)
media-libs/tiff[zlib]
)
"
distutils_enable_tests pytest
src_prepare() {
distutils-r1_src_prepare
sed -e '/-n auto/d' -i pyproject.toml || die
}
python_test() {
local EPYTEST_DESELECT=(
# fragile to system load
tests/test_image_access.py::test_random_image
tests/test_image_access.py::test_image_save_compare
tests/test_image_access.py::test_palette_nonrgb
)
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest -p timeout
}