app-admin/vault: Version bump to 0.8.2

Gentoo-Bug: 627860
Package-Manager: Portage-2.3.8, Repoman-2.3.3
This commit is contained in:
Manuel Rüger
2017-09-18 12:36:11 +02:00
parent d74e2f2530
commit 67ee0a07e7
2 changed files with 68 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST vault-0.7.3.tar.gz 6694636 SHA256 98409ae9c0e081e613a0e2288d2b5653582bb8bf57cb775cbff782d061a25708 SHA512 8632b4b721372cb0f5f684564ebe0749b7c1a9b5d0322b083773b3a2fd1734fb2eedee1aeb4b4c9431ce7f44c711ac0a95960c581165e1bac1a3754f8658e783 WHIRLPOOL d8eae9b3ed5d24a8b30dfec90360d2e5e4c94663b1bb168156b03724d6a2ff5dae1345474a02b67b1cde427419c07cc8a12bcbbe9b3db463a6c4f2a503832041
DIST vault-0.8.2.tar.gz 7293367 SHA256 0e248c6cbf19ce8fb01fd31541d5a28b8c1c534b02256fb72bdc1d4d6aa462f2 SHA512 279056211aefbab09b6533ce5b0fea355511a84c3f21cbbae0fa08b0affd2254fcd0a9479a317d07e9b99c5a2bd6d8c9caa5c32f14f73b21d8c4be3f24345669 WHIRLPOOL f96be6c75a5fc1cf6db26f12270d00c028b665ea37589dba8087ade3e5bcd987cb9914188d990a9c6628045277226823accc4ffabeaf290e62f4f71cbb72a0d7
+67
View File
@@ -0,0 +1,67 @@
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit fcaps golang-base golang-vcs-snapshot systemd user
EGO_PN="github.com/hashicorp/${PN}"
DESCRIPTION="A tool for managing secrets"
HOMEPAGE="https://vaultproject.io/"
SRC_URI="https://${EGO_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
SLOT="0"
LICENSE="MPL-2.0"
KEYWORDS="~amd64"
IUSE=""
RESTRICT="test"
DEPEND=">=dev-lang/go-1.9:=
dev-go/gox"
FILECAPS=(
-m 755 'cap_ipc_lock=+ep' usr/bin/${PN}
)
src_prepare() {
default
# Avoid the need to have a git checkout
sed -e 's:^\(GIT_COMMIT=\).*:\1:' \
-e 's:^\(GIT_DIRTY=\).*:\1:' \
-e s:\'\${GIT_COMMIT}\${GIT_DIRTY}\':: \
-i src/${EGO_PN}/scripts/build.sh || die
sed -e "/hooks/d" -i src/${EGO_PN}/Makefile || die
}
pkg_setup() {
enewgroup ${PN}
enewuser ${PN} -1 -1 -1 ${PN}
}
src_compile() {
mkdir bin || die
export GOPATH=${S}
cd src/${EGO_PN} || die
XC_ARCH=$(go env GOARCH) \
XC_OS=$(go env GOOS) \
XC_OSARCH=$(go env GOOS)/$(go env GOARCH) \
emake
}
src_install() {
dodoc src/${EGO_PN}/{CHANGELOG.md,CONTRIBUTING.md,README.md}
newinitd "${FILESDIR}/${PN}.initd" "${PN}"
newconfd "${FILESDIR}/${PN}.confd" "${PN}"
insinto /etc/logrotate.d
newins "${FILESDIR}/${PN}.logrotated" "${PN}"
systemd_dounit "${FILESDIR}/${PN}.service"
keepdir /etc/${PN}.d
insinto /etc/${PN}.d
doins "${FILESDIR}/"*.json.example
keepdir /var/log/${PN}
fowners ${PN}:${PN} /var/log/${PN}
dobin bin/${PN}
}