dev-python/pymdown-extensions: add 9.6

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-python/pymdown-extensions/Manifest

@@ -1 +1,2 @@
 DIST pymdown-extensions-9.5.gh.tar.gz 1004601 BLAKE2B 8950ca104edf476e5557eab1effd9ad4e879f2ef58823e1385b5ee000e704b260b20f758578021d4c03492e675027f079363da49429938221fb1c109c9e1fe2d SHA512 b640947b97be4f7592b86125c7de0f36c34052e77103f7d16818b8fc2794cc28d3b7baef84d99434ca1b2810fbe19bc2fc0d2430b8504425cca71677d9c8753c
+DIST pymdown-extensions-9.6.gh.tar.gz 1011446 BLAKE2B 8e334896738de592d8d852f05f165c70d65b6541915bc4d66472b2e2e08a4921e5ed3e0d5873b03e3bbc31179cd2edb367ca0eb3734f1b437b8eff0dc4f9defb SHA512 b806eac4656b1e541753e9e3f4d29bd49dfdfb24ea67633ea232d40833e4ce438b76c71c013d7bc5c3ebfa790b2e314e6f0f76cc3a76f42d5c2b020c32f8dba7

dev-python/pymdown-extensions/pymdown-extensions-9.6.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8..11} )
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="
+	dev-python/mkdocs-git-revision-date-localized-plugin
+	dev-python/mkdocs-minify-plugin
+	dev-python/mkdocs-material
+	dev-python/pymdown-lexers
+	dev-python/pyspelling
+"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="Extensions for Python Markdown"
+HOMEPAGE="
+	https://github.com/facelessuser/pymdown-extensions/
+	https://pypi.org/project/pymdown-extensions/
+"
+SRC_URI="
+	https://github.com/facelessuser/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/markdown-3.2[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/pygments-2.12.0[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# mkdocs-git-revision-date-localized-plugin needs git repo
+	if use doc; then
+		git init || die
+		git config --global user.email "you@example.com" || die
+		git config --global user.name "Your Name" || die
+		git add . || die
+		git commit -m 'init' || die
+	fi
+
+	distutils-r1_python_prepare_all
+}