dev-python/magic-wormhole: Bump to 0.18.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/magic-wormhole/Manifest

@@ -1 +1,2 @@
+DIST magic-wormhole-0.18.0.tar.gz 289799 BLAKE2B ff786e3247dcc382fa35175d6439c6273b420968100cc6e54a06e365b8d6db5a9a5145878d4025f51fe59cf75e18507d5114d04a13123ef62b255a61b3c55698 SHA512 095be448fb654a32ea45808f03b1a0bffd74ee683448085f1e6f14f054c0d2f19f9048270be4ec7b6a0b46872d20613a36e984a0a137bd68ba3d0a237a83d1b2
 DIST magic_wormhole-0.17.0.tar.gz 284056 BLAKE2B f8bd45be5fca5015c7c0b601512ba823025d164172368f60309b74d078dead0f0b7a67bd548974811279728210bee542de1bbd6d7e8e3b568115e8b1d72795ac SHA512 12866b544b375b29cf2f58c59aa0e65000cfae0025b5e7a773b1f57a35c98b38629aaec9cc30cf4232f745b76db642e8bd15c41e8d8ba1a8e112c50b33293eff

dev-python/magic-wormhole/magic-wormhole-0.18.0.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 pypi shell-completion
+
+DESCRIPTION="Get Things From One Computer To Another, Safely"
+HOMEPAGE="
+	https://magic-wormhole.readthedocs.io/en/latest/
+	https://github.com/magic-wormhole/magic-wormhole/
+	https://pypi.org/project/magic-wormhole/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/autobahn-0.14.1[${PYTHON_USEDEP}]
+	dev-python/automat[${PYTHON_USEDEP}]
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/humanize[${PYTHON_USEDEP}]
+	>=dev-python/iterable-io-1.0.0[${PYTHON_USEDEP}]
+	dev-python/noiseprotocol[${PYTHON_USEDEP}]
+	dev-python/pynacl[${PYTHON_USEDEP}]
+	>=dev-python/qrcode-8.0[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	~dev-python/spake2-0.9[${PYTHON_USEDEP}]
+	>=dev-python/tqdm-4.13.0[${PYTHON_USEDEP}]
+	dev-python/twisted[ssl,${PYTHON_USEDEP}]
+	>=dev-python/txtorcon-18.0.2[${PYTHON_USEDEP}]
+	>=dev-python/zipstream-ng-1.7.1[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/versioneer[${PYTHON_USEDEP}]
+	test? (
+		dev-python/magic-wormhole-mailbox-server[${PYTHON_USEDEP}]
+		~dev-python/magic-wormhole-transit-relay-0.3.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+	rm versioneer.py || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		src/wormhole/test/test_transit.py::InboundConnectionFactory::test_log_other_errors
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	newbashcomp "${ED}/usr/wormhole_complete.bash" wormhole
+	newfishcomp "${ED}/usr/wormhole_complete.fish" wormhole.fish
+	newzshcomp "${ED}/usr/wormhole_complete.zsh" _wormhole
+	rm "${ED}/usr"/wormhole_complete* || die
+}