net-wireless/bdaddr: new package, add 0_p20210511

Signed-off-by: Florian Schmaus <flow@gentoo.org>

net-wireless/bdaddr/Manifest

@@ -0,0 +1,2 @@
+DIST bdaddr-0_p20210511-idiomatic-makefile.patch 840 BLAKE2B d0be6e61728313517816db440ebb54bbece61f98ffa8d0cf28f23fcc0d3538baec77392b634be74a5ea4d9f72342ebeec99c0c226c52d7f9f8fee983f63b2c21 SHA512 4b67caa9afeeca31e3b3c5c8a61186769f94c7edd34694d9546d8242bc2762f98c7709cf2f1453b68b913e498c8f45003b9ccce7bc1ee8904e585c43c5db2ae9
+DIST bdaddr-0_p20210511.tar.gz 5236 BLAKE2B a445586cc016f57f1922d6cff9dcf3141d35122a0dd4a3c338cc98515dadcf40265c3f4dcb2da03d3cd4214ab3d57172d78677afe9099d380e1241677d13b486 SHA512 956e1207c4b082d6322ab0ce9cdc76c9c2c9f17fe4ecb3d03b4839025b49f102a4e35b05e2489eca3fee6fc4a611d942e598c97cab7db6b530e895818e33a150

net-wireless/bdaddr/bdaddr-0_p20210511.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Utility for changing the Bluetooth device address"
+HOMEPAGE="https://github.com/thxomas/bdaddr"
+
+if [[ ${PV} == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/thxomas/bdaddr"
+else
+	MY_COMMIT=53dae3f6a33bca202ddae0e7b14beeaf2d7d653b
+	SRC_URI="
+		https://github.com/thxomas/bdaddr/archive/${MY_COMMIT}.tar.gz
+			-> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64"
+	S="${WORKDIR}/${PN}-${MY_COMMIT}"
+fi
+
+# https://github.com/thxomas/bdaddr/pull/6
+SRC_URI+="
+	https://github.com/Flowdalic/bdaddr/commit/e5cf5666e00828a3769fcda4717b0ee6f277001d.patch
+		-> ${PN}-0_p20210511-idiomatic-makefile.patch
+"
+
+LICENSE="GPL-2+"
+SLOT="0"
+
+COMMON_DEPEND="
+	net-wireless/bluez:=
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	sys-apps/hwdata
+"
+DEPEND="
+	${COMMON_DEPEND}
+"
+BDEPEND="dev-go/go-md2man"
+
+PATCHES=(
+	"${DISTDIR}"/${PN}-0_p20210511-idiomatic-makefile.patch
+)
+
+src_compile() {
+	emake
+
+	go-md2man -in README.md -out ${PN}.1 || die
+}
+
+src_install() {
+	dobin ${PN}
+	doman ${PN}.1
+	dosym ../hwdata/oui.txt usr/share/misc/oui.txt
+}

net-wireless/bdaddr/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<name>Florian Schmaus</name>
+		<email>flow@gentoo.org</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">thxomas/bdaddr</remote-id>
+	</upstream>
+</pkgmetadata>