sci-mathematics/cgal: version bump to 5.1

* also build shared libraries

Closes: https://bugs.gentoo.org/734662
Closes: https://bugs.gentoo.org/663232
Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Aisha Tammy <gentoo@aisha.cc>
Signed-off-by: David Seifert <soap@gentoo.org>

sci-mathematics/cgal/Manifest

@@ -1,2 +1,4 @@
 DIST CGAL-4.11.3-doc_html.tar.xz 30576756 BLAKE2B 6d32f3bca1c5aee4ed09eb96a35113a8a71bf14679e204683268ccee56f4a4799ef696bebd5ec0fd6add964e23273efc87167c122a5dc781c9cc7b2f5b938c29 SHA512 a729bea11a9b853a8197cc7ebb089005f98868e393e91142946d45a485e2e9ac9eacce1b230d91240080033b5c31bfd0195820ee5ae7f621bdd75f1abf19244f
 DIST CGAL-4.11.3.tar.xz 14657412 BLAKE2B a10457d255fcdd822f90419ff6af5389c50e88b254ed7f37471e24bb8523732b5aa6bd1ee5e67f14fcf0d8e79abf86e798ddeb3e0ce965dc2cde5667377bf5e0 SHA512 44cdd5fb313841d208ffeb9a96aa8db5111defd581b749c80f655390b5468f7c18b61df0ac2bdeb5259507341cc451fcd8cd50f7ff0571efdcb76eb920f92f7e
+DIST CGAL-5.1-doc_html.tar.xz 50630976 BLAKE2B 559287263b189ec5ac4a0b3445e1cc5862471285f28caca40f48b25b64eaef3426c42a178e4cb4db69a1e324963a9af665e84ca8f44da8b55ebb344f18f56fdc SHA512 ada944d73d3e6465a14d87ee87d1cabaee2c4848622b5360c14d6a9b5ff5ba3e19859943ecb7595b0dec7e950f214aa47b6ab389c23dd5f2794fc21a9e3a17db
+DIST CGAL-5.1.tar.xz 22850692 BLAKE2B 42320e07e222c3f69febe7dc478c74ef6cde0de723ea2d84c891b6e598d02c38026e9246edd467cadea8d66e527000a9b4af296ab026dd42c7876acea9824ccb SHA512 41085eeb113cec0eede2e21df05c9d2530db5988b4f9d0379f8de7c655cab09266620eebe017e0141c0ccdbcbafe8c074fd5bec46a40aaba95aa7521732e4423

sci-mathematics/cgal/cgal-5.1.ebuild

@@ -0,0 +1,79 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+MY_P=CGAL-${PV}
+
+DESCRIPTION="C++ library for geometric algorithms and data structures"
+HOMEPAGE="https://www.cgal.org/"
+SRC_URI="
+	https://github.com/CGAL/cgal/releases/download/v${PV}/${MY_P}.tar.xz
+	doc? ( https://github.com/CGAL/cgal/releases/download/v${PV}/${MY_P}-doc_html.tar.xz )"
+
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="LGPL-3 GPL-3 Boost-1.0"
+SLOT="0/14"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples +gmp mpfi ntl qt5"
+
+RDEPEND="
+	dev-cpp/eigen
+	dev-libs/boost:=[threads]
+	dev-libs/mpfr:=
+	sys-libs/zlib
+	x11-libs/libX11:=
+	virtual/glu:=
+	virtual/opengl:=
+	gmp? ( dev-libs/gmp:=[cxx] )
+	mpfi? ( sci-libs/mpfi )
+	ntl? ( dev-libs/ntl )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtopengl:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-arch/xz-utils
+	virtual/pkgconfig
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-4.11.1-fix-buildsystem.patch )
+
+src_prepare() {
+	cmake_src_prepare
+	# modules provided by dev-cpp/eigen
+	rm cmake/modules/FindEigen3.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCGAL_INSTALL_LIB_DIR="$(get_libdir)"
+		-DCGAL_INSTALL_CMAKE_DIR="$(get_libdir)/cmake/CGAL"
+		-DCGAL_HEADER_ONLY=OFF
+		-DWITH_LEDA=OFF
+		-DWITH_Eigen3=ON
+		-DWITH_ZLIB=ON
+		-DWITH_GMP=$(usex gmp)
+		-DWITH_GMPXX=$(usex gmp)
+		-DWITH_MPFI=$(usex mpfi)
+		-DWITH_NTL=$(usex ntl)
+		-DWITH_CGAL_Qt5=$(usex qt5)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( "${WORKDIR}"/doc_html/. )
+	cmake_src_install
+	if use examples; then
+		dodoc -r examples demo
+	fi
+}