dev-ada/gpr: add 24.2.0

Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

dev-ada/gpr/Manifest

@@ -1,2 +1,3 @@
+DIST gpr-24.2.0-next.tar.gz 1524692 BLAKE2B 0e395f7d913b5b6344bb2d89d7471971ea7fb382bcba8123bcbd3703371b145493ed17560f0b7602f8fa5e89fbbd1a5e24d93763fcf493832a332b9463e96e16 SHA512 4d824a2eddd74fca5b2f51336bc2b8e3a35fac4901ff41ac0d7704aa81474357e0733b96da0fe9d3a09a4b21885812bf29bdeb330025ae466089c9dbefcd8d51
 DIST gpr2-with-gprconfig_kb-25.0.tgz 1772855 BLAKE2B f4bcde7f2ad951d00b7b03b2d49120c301836a2bc676de0c0f7c493573a03b15bc20a6fd7f8d3034a063f6227b47f54468efe14260de1bb52a1da6bc4d5b87d6 SHA512 70fe0fcf541f6d3d90a34cab1638bbc0283dcd765c000406e0cfb73bae1817b30ddfe73f3672247a97c6b6bfc41900bc96a4440ca0c660f9c2f7b9d3cc8f8dcf
 DIST gpr2-with-lkparser-24.0.tgz 2030278 BLAKE2B ae42fd876a08a654db2db919e6d777ba603d54d6db618e8b8dbdfcfd9313decad092e0a9feae09ca46ec324cd860eaffbb6fa670290d454414677ad7e4a61dc7 SHA512 eda3c693393763da31312733e2bc06e852b867a32b42da6afdddd623051a1d29f7243aabaef3ae50052b22686dce6db62d9823652ce516d79822e4215f4d87b1

dev-ada/gpr/gpr-24.2.0.ebuild

@@ -0,0 +1,70 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ADA_COMPAT=( gcc_14 )
+
+inherit ada multiprocessing
+
+DESCRIPTION="LibGPR2 - Parser for GPR Project files"
+HOMEPAGE="https://github.com/AdaCore/gpr"
+SRC_URI="https://github.com/AdaCore/${PN}/archive/refs/tags/v${PV}-next.tar.gz
+	-> ${P}-next.tar.gz"
+
+S="${WORKDIR}"/${P}-next
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="static-libs static-pic"
+REQUIRED_USE="${ADA_REQUIRED_USE}"
+
+RDEPEND="${ADA_DEPS}
+	dev-ada/xmlada[${ADA_USEDEP},shared,static-libs?,static-pic?]
+	dev-ada/gnatcoll-core[${ADA_USEDEP},shared,static-libs?,static-pic?]
+	dev-ada/gnatcoll-bindings[${ADA_USEDEP},shared,static-libs?,static-pic?]
+	dev-ada/gnatcoll-bindings[iconv(+),gmp]
+"
+
+DEPEND="${RDEPEND}
+	dev-ada/gprconfig_kb[${ADA_USEDEP}]
+	dev-ada/gprbuild[${ADA_USEDEP}]"
+
+src_compile() {
+	emake GPR2KBDIR=/usr/share/gprconfig .build/kb/config.kb
+	build () {
+		gprbuild -j$(makeopts_jobs) -m -p -v -XLIBRARY_TYPE=$1 \
+			-XGPR2_BUILD=release -XXMLADA_BUILD=$1 gpr2.gpr \
+			-largs ${LDFLAGS} \
+			-cargs ${ADAFLAGS} || die "gprbuild failed"
+	}
+	build relocatable
+	use static-libs && build static
+	use static-pic  && build static-pic
+
+	gprbuild -p -m -v -j$(makeopts_jobs) -aP . -XGPR2_BUILD=release \
+		-XLIBRARY_TYPE=relocatable -XXMLADA_BUILD=relocatable \
+		tools/gpr2-tools.gpr \
+		-largs ${LDFLAGS} -cargs ${ADAFLAGS} || die
+}
+
+src_install() {
+	build () {
+		gprinstall -XLIBRARY_TYPE=$1 -f -p -v -XGPR2_BUILD=release \
+			--prefix="${D}/usr" -XXMLADA_BUILD=$1 \
+			--build-name=$1 --build-var=LIBRARY_TYPE \
+			--build-var=GPR2_LIBRARY_TYPE gpr2.gpr || die
+	}
+	build relocatable
+	use static-libs && build static
+	use static-pic  && build static-pic
+	gprinstall -p -f -v -aP . -XGPR2_BUILD=release --prefix="${D}/usr" \
+		-XLIBRARY_TYPE=relocatable -XXMLADA_BUILD=relocatable \
+		--build-name=relocatable --mode=usage tools/gpr2-tools.gpr || die
+
+	einstalldocs
+
+	rm "${D}"/usr/bin/gprconfig || die
+	rm -r "${D}"/usr/share/gpr/manifests
+}