dev-python/pdm-pep517: Bump to 0.10.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/pdm-pep517/Manifest

@@ -1,2 +1,3 @@
 DIST pdm-pep517-0.10.0.gh.tar.gz 189457 BLAKE2B 5a51b62dbc828aec5bca6ada8c7ecb479dd7491f22251392198a3d8e183f2d3d86fd4264addd9a428c37a24041365f3eeecec0a33c3f1a39ea8a1a8e6827be91 SHA512 7eb76bdf3db99ec1cf76a467617ce15423eaa465800efa9ccb248efb3c3cb5644b8e6a9ce04d6181dc9f3b5287a167f62f25d5e3334929f3e947a62ca9633d01
 DIST pdm-pep517-0.10.1.gh.tar.gz 189525 BLAKE2B 10d80fee2ac45fd68c61baf9a8ee7365da19a5daa085fdecd3164b3271cf0c0ee8ad110b1f96a33a4eecdceace72c2d4ee1ce789331c208eb4a67e3b4e3fe56a SHA512 acdf36eeb2baf90c1c80b676901ac06946fbb32f2a5c2bfbdfd85d0889ae22a0851dede4f5898d109d20583504b311cbec6903deadfb77e3f1dd7ff6a1098e04
+DIST pdm-pep517-0.10.2.gh.tar.gz 189817 BLAKE2B 47e773ac38197d898c50821d272c155d6749952bcce1492416291c02fa370965ca438e68268a56b8366b18f8a786883c9101e4dc325c9d4741f6cc509862d823 SHA512 6cdbd2cd96a784317356f4c5c52697279b720de03e7059c287872725baa10333b2f352e9a1c5ace727907bd6179cd879fcb4f6770eae1dd23294bf1b60cc233b

dev-python/pdm-pep517/pdm-pep517-0.10.2.ebuild

@@ -0,0 +1,55 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+	https://pypi.org/project/pdm-pep517/
+	https://github.com/pdm-project/pdm-pep517/
+"
+SRC_URI="
+	https://github.com/pdm-project/pdm-pep517/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/cerberus-1.3.4[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.0[${PYTHON_USEDEP}]
+	>=dev-python/toml-0.10.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-vcs/git
+	)
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm -r pdm/pep517/_vendor || die
+	find -name '*.py' -exec sed \
+		-e 's:from pdm\.pep517\._vendor\.:from :' \
+		-e 's:from pdm\.pep517\._vendor ::' \
+		-i {} + || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "Test User" || die
+	distutils-r1_src_test
+}