dev-python/pyx: bump to 0.15, +p3_7 +p3_8

Package-Manager: Portage-2.3.92, Repoman-2.3.20
Signed-off-by: Andrey Grozin <grozin@gentoo.org>

dev-python/pyx/Manifest

@@ -1 +1,2 @@
 DIST PyX-0.14.1.tar.gz 2475186 BLAKE2B 5e18b2a052c586cfdcfcc46f5351683ce7c3ec41d508b6fd5e085be543ac3730ee866b636d3ab9663e782b95efafcc340260826c82a77955b586ad7a55676c5b SHA512 16265bbdcaf28ce194189a2987b32952f296c850b829454bcccce0abd23838bfca0276c3e9c8e96b8cbfaf1473bf14669f9b7f2032ee039b61ae59ea3aa45a20
+DIST PyX-0.15.tar.gz 2559840 BLAKE2B df9079778ff30dd2f71631abce492259dc4bad12a854972fc890f69df1bbdd2bd987f63940297d3bb32e7eb85b5902430933d9c7c04aa3a45da36e8c8cf01ffd SHA512 c312b38b9f204b8a8832ab71da5be8c9afc417a095c8ccf242b3d3ebec63338a9d55abab4e548d1718abadf12ea7652cdad51731acdc8f6acd3d8608aa919919

dev-python/pyx/files/pyx-0.15-unicode-latex.patch

@@ -0,0 +1,10 @@
+diff -r -U1 PyX-0.15.orig/faq/general_aspects_pyx.rst PyX-0.15/faq/general_aspects_pyx.rst
+--- PyX-0.15.orig/faq/general_aspects_pyx.rst	2018-11-16 15:17:19.000000000 +0700
++++ PyX-0.15/faq/general_aspects_pyx.rst	2020-03-08 17:57:38.719772919 +0700
+@@ -15,4 +15,4 @@
+ Despite the ties between TeX and PyX, their pronunciation is quite different.
+-According to the developers of PyX, it should be pronounced as [pʏks]. Please do
+-not pronounce it as [pʏx] or [pʏç].
++According to the developers of PyX, it should be pronounced as [pyks]. Please do
++not pronounce it as [pyx] or [pyç].
+ 

dev-python/pyx/pyx-0.15.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+MY_PN=PyX
+MY_P="${P/pyx/PyX}"
+DESCRIPTION="Python package for the generation of encapsulated PostScript figures"
+HOMEPAGE="https://pyx.sourceforge.net/
+	https://pypi.org/project/PyX/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="virtual/tex-base
+		dev-texlive/texlive-basic"
+
+DEPEND="${RDEPEND}
+	doc? ( virtual/latex-base
+		dev-python/sphinx_selective_exclude[${PYTHON_USEDEP}]
+		dev-python/sphinx[latex,${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+PATCHES=( "${FILESDIR}"/${P}-unicode-latex.patch )
+
+src_prepare() {
+	distutils-r1_src_prepare
+	sed -i \
+		-e 's/^build_t1code=.*/build_t1code=1/' \
+		-e 's/^build_pykpathsea=.*/build_pykpathsea=1/' \
+		setup.cfg || die "setup.cfg fix failed"
+}
+
+python_compile_all() {
+	if use doc; then
+		VARTEXFONTS="${T}"/fonts
+		emake -C "${S}"/manual latexpdf
+		emake -C "${S}"/faq latexpdf
+	fi
+}
+
+python_install_all() {
+	use doc && dodoc manual/_build/latex/manual.pdf faq/_build/latex/pyxfaq.pdf
+	distutils-r1_python_install_all
+}