mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-01 23:28:08 -07:00
sys-devel/binutils-hppa64: 2.31.1 revbump, no keywords, needs testing
Package-Manager: Portage-2.3.62, Repoman-2.3.12 Signed-off-by: Andreas K. Hüttel <dilfridge@gentoo.org>
This commit is contained in:
Andreas K. Hüttel
@@ -15,6 +15,7 @@ DIST binutils-2.29.tar.bz2 29073316 BLAKE2B 0eb7bbefa1ac5f4d753ca9328d339a466d4f
|
||||
DIST binutils-2.30-patches-5.tar.xz 590864 BLAKE2B 71de4d08f92ab1898ad576a21763f955067cbbed543250888e0c5d51f4ef77d0d829049e9a835691cf2de03965fbcc9bcfa092eb304c03f9b885e7a3dadab286 SHA512 029b3be6ae9b8620f8580a35701bd4517b4e0232ff3cf9983b3808475c7443cbf500b6cace2c052df0bd1e47202838f4d2453238db28709a947117071d9ae804
|
||||
DIST binutils-2.30.tar.xz 20286700 BLAKE2B 2dd5436a15a601011a1950e6082ec00082f5916fb82ce95ceab424fd8dc19f6daa7ac32a149f222ccdcc603354165cc206fde070eaa44fe2cc5e57486efc7868 SHA512 e747ea20d8d79fcd21b9d9f6695059caa7189d60f19256da398e34b789fea9a133c32b192e9693b5828d27683739b0198431bf8b3e39fb3b04884cf89d9aa839
|
||||
DIST binutils-2.31.1-patches-5.tar.xz 65896 BLAKE2B 7fb2c4c71336a77f3fef57a0430c511ef7326f8196d8f3a57a6d56aed464953172eeb0755f020387739cf27f709d0bc3de9c3c8b972a94f1480639465158e180 SHA512 c254f22b8ca662cf49cd5fc076d3e9b82d7f421420408c960c54310fc49462600325e7bc50f863cab7c8c49caebac3ac353dc24ab5947e8f01b98c11f43f57d2
|
||||
DIST binutils-2.31.1-patches-6.tar.xz 76196 BLAKE2B e3c8de07dad62bb3093846389bc1fae0921dd6e63ee2458a85051d298cd1dd52487f83affa33d899e4ddd34b6fd3e28c79a525854c0432d576f83f855d843588 SHA512 6ddfe7b0dc9f340fb1dde3bbc426d087241738b15a5f16a336569b45b2c8ac4077e81e19168c5b165bd4abbaed419e2f290291ef7438a0ecde1f8a6a72217d4c
|
||||
DIST binutils-2.31.1.tar.xz 20467996 BLAKE2B 6b914df1fbb7cf54f2159f71b2c2b09f3f6a569b7a3cb4cf9790d0a3733a7548bc0ea32334a178ed3b56e8b97656ae99c7abaf212601beeaeae9a0884c0f6051 SHA512 0fca326feb1d5f5fe505a827b20237fe3ec9c13eaf7ec7e35847fd71184f605ba1cefe1314b1b8f8a29c0aa9d88162849ee1c1a3e70c2f7407d88339b17edb30
|
||||
DIST binutils-2.32-patches-1.tar.xz 93252 BLAKE2B 80d229be60c3377fe52ff3e74ee911b5dcfb9456d3f42a57662fbda3184ac1c63e698e592f804ac05c459527d0cd4bae7d8c9ef8caef02fdf4f17aa783f4ff81 SHA512 69999f60d89589dcf9e3cb18e50f153ab4ce05bdf3f3758fa322b5c4cb468aeda46c416da540995ddff1ea5e96354c264fa5ff0156c53685816d35117eb481e0
|
||||
DIST binutils-2.32.tar.xz 20774880 BLAKE2B d1bdbd9c8487c091665c197974ce4bdf520b7a67ed6997a81b87e6a0af9514a091458244f583acec5ae580ac2ee5e908f67f483b8e5263cd18ced794cb235da6 SHA512 d326408f12a03d9a61a9de56584c2af12f81c2e50d2d7e835d51565df8314df01575724afa1e43bd0db45cfc9916b41519b67dfce03232aa4978704492a6994a
|
||||
|
||||
443
sys-devel/binutils-hppa64/binutils-hppa64-2.31.1-r5.ebuild
Normal file
443
sys-devel/binutils-hppa64/binutils-hppa64-2.31.1-r5.ebuild
Normal file
@@ -0,0 +1,443 @@
|
||||
# Copyright 1999-2019 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=6
|
||||
|
||||
export CTARGET=hppa64-${CHOST#*-}
|
||||
|
||||
inherit eutils libtool flag-o-matic gnuconfig multilib versionator
|
||||
|
||||
DESCRIPTION="Tools necessary to build programs"
|
||||
HOMEPAGE="https://sourceware.org/binutils/"
|
||||
LICENSE="GPL-3+"
|
||||
# USE="+cxx" is a transitional flag until llvm migrates to new flags:
|
||||
# bug #677888
|
||||
IUSE="+cxx default-gold doc +gold multitarget +nls +plugins static-libs test"
|
||||
REQUIRED_USE="cxx? ( gold plugins ) default-gold? ( gold )"
|
||||
|
||||
# Variables that can be set here:
|
||||
# PATCH_VER - the patchset version
|
||||
# Default: empty, no patching
|
||||
# PATCH_BINUTILS_VER - the binutils version in the patchset name
|
||||
# - Default: PV
|
||||
# PATCH_DEV - Use download URI https://dev.gentoo.org/~{PATCH_DEV}/distfiles/...
|
||||
# for the patchsets
|
||||
# Default: slyfox
|
||||
|
||||
PATCH_VER=6
|
||||
PATCH_DEV=dilfridge
|
||||
|
||||
case ${PV} in
|
||||
9999)
|
||||
EGIT_REPO_URI="https://sourceware.org/git/binutils-gdb.git"
|
||||
inherit git-r3
|
||||
S=${WORKDIR}/binutils
|
||||
EGIT_CHECKOUT_DIR=${S}
|
||||
SLOT=${PV}
|
||||
;;
|
||||
*.9999)
|
||||
EGIT_REPO_URI="https://sourceware.org/git/binutils-gdb.git"
|
||||
inherit git-r3
|
||||
S=${WORKDIR}/binutils
|
||||
EGIT_CHECKOUT_DIR=${S}
|
||||
EGIT_BRANCH=$(get_version_component_range 1-2)
|
||||
EGIT_BRANCH="binutils-${EGIT_BRANCH/./_}-branch"
|
||||
SLOT=$(get_version_component_range 1-2)
|
||||
;;
|
||||
*)
|
||||
SRC_URI="mirror://gnu/binutils/binutils-${PV}.tar.xz"
|
||||
SLOT=$(get_version_component_range 1-2)
|
||||
;;
|
||||
esac
|
||||
SLOT=$(get_version_component_range 1-2)
|
||||
#KEYWORDS="-* ~hppa"
|
||||
|
||||
#
|
||||
# The Gentoo patchset
|
||||
#
|
||||
PATCH_BINUTILS_VER=${PATCH_BINUTILS_VER:-${PV}}
|
||||
PATCH_DEV=${PATCH_DEV:-slyfox}
|
||||
|
||||
[[ -z ${PATCH_VER} ]] || SRC_URI="${SRC_URI}
|
||||
https://dev.gentoo.org/~${PATCH_DEV}/distfiles/binutils-${PATCH_BINUTILS_VER}-patches-${PATCH_VER}.tar.xz"
|
||||
|
||||
#
|
||||
# The cross-compile logic
|
||||
#
|
||||
export CTARGET=${CTARGET:-${CHOST}}
|
||||
if [[ ${CTARGET} == ${CHOST} ]] ; then
|
||||
if [[ ${CATEGORY} == cross-* ]] ; then
|
||||
export CTARGET=${CATEGORY#cross-}
|
||||
fi
|
||||
fi
|
||||
is_cross() { [[ ${CHOST} != ${CTARGET} ]] ; }
|
||||
|
||||
#
|
||||
# The dependencies
|
||||
#
|
||||
RDEPEND="
|
||||
>=sys-devel/binutils-config-3
|
||||
sys-libs/zlib
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
doc? ( sys-apps/texinfo )
|
||||
test? ( dev-util/dejagnu )
|
||||
nls? ( sys-devel/gettext )
|
||||
sys-devel/flex
|
||||
virtual/yacc
|
||||
"
|
||||
|
||||
MY_BUILDDIR=${WORKDIR}/build
|
||||
S=${WORKDIR}/${P/-hppa64/}
|
||||
|
||||
src_unpack() {
|
||||
case ${PV} in
|
||||
*9999)
|
||||
git-r3_src_unpack
|
||||
;;
|
||||
*)
|
||||
;;
|
||||
esac
|
||||
default
|
||||
mkdir -p "${MY_BUILDDIR}"
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
if [[ ! -z ${PATCH_VER} ]] ; then
|
||||
einfo "Applying binutils-${PATCH_BINUTILS_VER} patchset ${PATCH_VER}"
|
||||
eapply "${WORKDIR}/patch"/*.patch
|
||||
fi
|
||||
|
||||
# This check should probably go somewhere else, like pkg_pretend.
|
||||
if [[ ${CTARGET} == *-uclibc* ]] ; then
|
||||
if grep -qs 'linux-gnu' "${S}"/ltconfig ; then
|
||||
die "sorry, but this binutils doesn't yet support uClibc :("
|
||||
fi
|
||||
fi
|
||||
|
||||
# Make sure our explicit libdir paths don't get clobbered. #562460
|
||||
sed -i \
|
||||
-e 's:@bfdlibdir@:@libdir@:g' \
|
||||
-e 's:@bfdincludedir@:@includedir@:g' \
|
||||
{bfd,opcodes}/Makefile.in || die
|
||||
|
||||
# Fix locale issues if possible #122216
|
||||
if [[ -e ${FILESDIR}/binutils-configure-LANG.patch ]] ; then
|
||||
einfo "Fixing misc issues in configure files"
|
||||
for f in $(find "${S}" -name configure -exec grep -l 'autoconf version 2.13' {} +) ; do
|
||||
ebegin " Updating ${f/${S}\/}"
|
||||
patch "${f}" "${FILESDIR}"/binutils-configure-LANG.patch >& "${T}"/configure-patch.log \
|
||||
|| eerror "Please file a bug about this"
|
||||
eend $?
|
||||
done
|
||||
fi
|
||||
|
||||
# Fix conflicts with newer glibc #272594
|
||||
if [[ -e libiberty/testsuite/test-demangle.c ]] ; then
|
||||
sed -i 's:\<getline\>:get_line:g' libiberty/testsuite/test-demangle.c
|
||||
fi
|
||||
|
||||
# Apply things from PATCHES and user dirs
|
||||
default
|
||||
|
||||
# Run misc portage update scripts
|
||||
gnuconfig_update
|
||||
elibtoolize --portage --no-uclibc
|
||||
}
|
||||
|
||||
toolchain-binutils_bugurl() {
|
||||
printf "https://bugs.gentoo.org/"
|
||||
}
|
||||
toolchain-binutils_pkgversion() {
|
||||
printf "Gentoo ${PV}"
|
||||
[[ -n ${PATCH_VER} ]] && printf " p${PATCH_VER}"
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
# Setup some paths
|
||||
LIBPATH=/usr/$(get_libdir)/binutils/${CTARGET}/${PV}
|
||||
INCPATH=${LIBPATH}/include
|
||||
DATAPATH=/usr/share/binutils-data/${CTARGET}/${PV}
|
||||
if is_cross ; then
|
||||
TOOLPATH=/usr/${CHOST}/${CTARGET}
|
||||
else
|
||||
TOOLPATH=/usr/${CTARGET}
|
||||
fi
|
||||
BINPATH=${TOOLPATH}/binutils-bin/${PV}
|
||||
|
||||
# Make sure we filter $LINGUAS so that only ones that
|
||||
# actually work make it through #42033
|
||||
strip-linguas -u */po
|
||||
|
||||
# Keep things sane
|
||||
strip-flags
|
||||
|
||||
local x
|
||||
echo
|
||||
for x in CATEGORY CBUILD CHOST CTARGET CFLAGS LDFLAGS ; do
|
||||
einfo "$(printf '%10s' ${x}:) ${!x}"
|
||||
done
|
||||
echo
|
||||
|
||||
cd "${MY_BUILDDIR}"
|
||||
local myconf=()
|
||||
|
||||
if use plugins ; then
|
||||
myconf+=( --enable-plugins )
|
||||
fi
|
||||
# enable gold (installed as ld.gold) and ld's plugin architecture
|
||||
if use gold ; then
|
||||
myconf+=( --enable-gold )
|
||||
if use default-gold; then
|
||||
myconf+=( --enable-gold=default )
|
||||
fi
|
||||
fi
|
||||
|
||||
if use nls ; then
|
||||
myconf+=( --without-included-gettext )
|
||||
else
|
||||
myconf+=( --disable-nls )
|
||||
fi
|
||||
|
||||
myconf+=( --with-system-zlib )
|
||||
|
||||
# For bi-arch systems, enable a 64bit bfd. This matches
|
||||
# the bi-arch logic in toolchain.eclass. #446946
|
||||
# We used to do it for everyone, but it's slow on 32bit arches. #438522
|
||||
case $(tc-arch) in
|
||||
ppc|sparc|x86) myconf+=( --enable-64-bit-bfd ) ;;
|
||||
esac
|
||||
|
||||
use multitarget && myconf+=( --enable-targets=all --enable-64-bit-bfd )
|
||||
|
||||
[[ -n ${CBUILD} ]] && myconf+=( --build=${CBUILD} )
|
||||
|
||||
is_cross && myconf+=(
|
||||
--with-sysroot="${EPREFIX}"/usr/${CTARGET}
|
||||
--enable-poison-system-directories
|
||||
)
|
||||
|
||||
# glibc-2.3.6 lacks support for this ... so rather than force glibc-2.5+
|
||||
# on everyone in alpha (for now), we'll just enable it when possible
|
||||
has_version ">=${CATEGORY}/glibc-2.5" && myconf+=( --enable-secureplt )
|
||||
has_version ">=sys-libs/glibc-2.5" && myconf+=( --enable-secureplt )
|
||||
|
||||
# mips can't do hash-style=gnu ...
|
||||
if [[ $(tc-arch) != mips ]] ; then
|
||||
myconf+=( --enable-default-hash-style=gnu )
|
||||
fi
|
||||
|
||||
myconf+=(
|
||||
--prefix="${EPREFIX}"/usr
|
||||
--host=${CHOST}
|
||||
--target=${CTARGET}
|
||||
--datadir="${EPREFIX}"${DATAPATH}
|
||||
--datarootdir="${EPREFIX}"${DATAPATH}
|
||||
--infodir="${EPREFIX}"${DATAPATH}/info
|
||||
--mandir="${EPREFIX}"${DATAPATH}/man
|
||||
--bindir="${EPREFIX}"${BINPATH}
|
||||
--libdir="${EPREFIX}"${LIBPATH}
|
||||
--libexecdir="${EPREFIX}"${LIBPATH}
|
||||
--includedir="${EPREFIX}"${INCPATH}
|
||||
--enable-obsolete
|
||||
--enable-shared
|
||||
--enable-threads
|
||||
# Newer versions (>=2.27) offer a configure flag now.
|
||||
--enable-relro
|
||||
# Newer versions (>=2.24) make this an explicit option. #497268
|
||||
--enable-install-libiberty
|
||||
--disable-werror
|
||||
--with-bugurl="$(toolchain-binutils_bugurl)"
|
||||
--with-pkgversion="$(toolchain-binutils_pkgversion)"
|
||||
$(use_enable static-libs static)
|
||||
${EXTRA_ECONF}
|
||||
# Disable modules that are in a combined binutils/gdb tree. #490566
|
||||
--disable-{gdb,libdecnumber,readline,sim}
|
||||
# Strip out broken static link flags.
|
||||
# https://gcc.gnu.org/PR56750
|
||||
--without-stage1-ldflags
|
||||
# Change SONAME to avoid conflict across
|
||||
# {native,cross}/binutils, binutils-libs. #666100
|
||||
--with-extra-soversion-suffix=gentoo-${CATEGORY}-${PN}-$(usex multitarget mt st)
|
||||
)
|
||||
echo ./configure "${myconf[@]}"
|
||||
"${S}"/configure "${myconf[@]}" || die
|
||||
|
||||
# Prevent makeinfo from running if doc is unset.
|
||||
if ! use doc ; then
|
||||
sed -i \
|
||||
-e '/^MAKEINFO/s:=.*:= true:' \
|
||||
Makefile || die
|
||||
fi
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
cd "${MY_BUILDDIR}"
|
||||
# see Note [tooldir hack for ldscripts]
|
||||
emake tooldir="${EPREFIX}${TOOLPATH}" all
|
||||
|
||||
# only build info pages if the user wants them
|
||||
if use doc ; then
|
||||
emake info
|
||||
fi
|
||||
|
||||
# we nuke the manpages when we're left with junk
|
||||
# (like when we bootstrap, no perl -> no manpages)
|
||||
find . -name '*.1' -a -size 0 -delete
|
||||
}
|
||||
|
||||
src_test() {
|
||||
cd "${MY_BUILDDIR}"
|
||||
|
||||
# bug 637066
|
||||
filter-flags -Wall -Wreturn-type
|
||||
|
||||
emake -k check
|
||||
}
|
||||
|
||||
src_install() {
|
||||
local x d
|
||||
|
||||
cd "${MY_BUILDDIR}"
|
||||
# see Note [tooldir hack for ldscripts]
|
||||
emake DESTDIR="${D}" tooldir="${EPREFIX}${LIBPATH}" install
|
||||
rm -rf "${ED}"/${LIBPATH}/bin
|
||||
use static-libs || find "${ED}" -name '*.la' -delete
|
||||
|
||||
# Newer versions of binutils get fancy with ${LIBPATH} #171905
|
||||
cd "${ED}"/${LIBPATH}
|
||||
for d in ../* ; do
|
||||
[[ ${d} == ../${PV} ]] && continue
|
||||
mv ${d}/* . || die
|
||||
rmdir ${d} || die
|
||||
done
|
||||
|
||||
# Now we collect everything intp the proper SLOT-ed dirs
|
||||
# When something is built to cross-compile, it installs into
|
||||
# /usr/$CHOST/ by default ... we have to 'fix' that :)
|
||||
if is_cross ; then
|
||||
cd "${ED}"/${BINPATH}
|
||||
for x in * ; do
|
||||
mv ${x} ${x/${CTARGET}-}
|
||||
done
|
||||
|
||||
if [[ -d ${ED}/usr/${CHOST}/${CTARGET} ]] ; then
|
||||
mv "${ED}"/usr/${CHOST}/${CTARGET}/include "${ED}"/${INCPATH}
|
||||
mv "${ED}"/usr/${CHOST}/${CTARGET}/lib/* "${ED}"/${LIBPATH}/
|
||||
rm -r "${ED}"/usr/${CHOST}/{include,lib}
|
||||
fi
|
||||
fi
|
||||
insinto ${INCPATH}
|
||||
local libiberty_headers=(
|
||||
# Not all the libiberty headers. See libiberty/Makefile.in:install_to_libdir.
|
||||
demangle.h
|
||||
dyn-string.h
|
||||
fibheap.h
|
||||
hashtab.h
|
||||
libiberty.h
|
||||
objalloc.h
|
||||
splay-tree.h
|
||||
)
|
||||
doins "${libiberty_headers[@]/#/${S}/include/}" || die
|
||||
if [[ -d ${ED}/${LIBPATH}/lib ]] ; then
|
||||
mv "${ED}"/${LIBPATH}/lib/* "${ED}"/${LIBPATH}/
|
||||
rm -r "${ED}"/${LIBPATH}/lib
|
||||
fi
|
||||
|
||||
# Generate an env.d entry for this binutils
|
||||
insinto /etc/env.d/binutils
|
||||
cat <<-EOF > "${T}"/env.d
|
||||
TARGET="${CTARGET}"
|
||||
VER="${PV}"
|
||||
LIBPATH="${EPREFIX}${LIBPATH}"
|
||||
EOF
|
||||
newins "${T}"/env.d ${CTARGET}-${PV}
|
||||
|
||||
# Handle documentation
|
||||
if ! is_cross ; then
|
||||
cd "${S}"
|
||||
dodoc README
|
||||
docinto bfd
|
||||
dodoc bfd/ChangeLog* bfd/README bfd/PORTING bfd/TODO
|
||||
docinto binutils
|
||||
dodoc binutils/ChangeLog binutils/NEWS binutils/README
|
||||
docinto gas
|
||||
dodoc gas/ChangeLog* gas/CONTRIBUTORS gas/NEWS gas/README*
|
||||
docinto gprof
|
||||
dodoc gprof/ChangeLog* gprof/TEST gprof/TODO gprof/bbconv.pl
|
||||
docinto ld
|
||||
dodoc ld/ChangeLog* ld/README ld/NEWS ld/TODO
|
||||
docinto libiberty
|
||||
dodoc libiberty/ChangeLog* libiberty/README
|
||||
docinto opcodes
|
||||
dodoc opcodes/ChangeLog*
|
||||
fi
|
||||
|
||||
# Remove shared info pages
|
||||
rm -f "${ED}"/${DATAPATH}/info/{dir,configure.info,standards.info}
|
||||
|
||||
# Trim all empty dirs
|
||||
find "${ED}" -depth -type d -exec rmdir {} + 2>/dev/null
|
||||
|
||||
# the hppa64 hack; this should go into 9999 as a PN-conditional
|
||||
# tweak the default fake list a little bit
|
||||
cd "${D}"/etc/env.d/binutils
|
||||
sed -i '/FAKE_TARGETS=/s:"$: hppa64-linux":' ${CTARGET}-${PV} || die
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
# Make sure this ${CTARGET} has a binutils version selected
|
||||
[[ -e ${EROOT}/etc/env.d/binutils/config-${CTARGET} ]] && return 0
|
||||
binutils-config ${CTARGET}-${PV}
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
local current_profile=$(binutils-config -c ${CTARGET})
|
||||
|
||||
# If no other versions exist, then uninstall for this
|
||||
# target ... otherwise, switch to the newest version
|
||||
# Note: only do this if this version is unmerged. We
|
||||
# rerun binutils-config if this is a remerge, as
|
||||
# we want the mtimes on the symlinks updated (if
|
||||
# it is the same as the current selected profile)
|
||||
if [[ ! -e ${EPREFIX}${BINPATH}/ld ]] && [[ ${current_profile} == ${CTARGET}-${PV} ]] ; then
|
||||
local choice=$(binutils-config -l | grep ${CTARGET} | awk '{print $2}')
|
||||
choice=${choice//$'\n'/ }
|
||||
choice=${choice/* }
|
||||
if [[ -z ${choice} ]] ; then
|
||||
binutils-config -u ${CTARGET}
|
||||
else
|
||||
binutils-config ${choice}
|
||||
fi
|
||||
elif [[ $(CHOST=${CTARGET} binutils-config -c) == ${CTARGET}-${PV} ]] ; then
|
||||
binutils-config ${CTARGET}-${PV}
|
||||
fi
|
||||
}
|
||||
|
||||
# Note [slotting support]
|
||||
# -----------------------
|
||||
# Gentoo's layout for binutils files is non-standard as Gentoo
|
||||
# supports slotted installation for binutils. Many tools
|
||||
# still expect binutils to reside in known locations.
|
||||
# binutils-config package restores symlinks into known locations,
|
||||
# like:
|
||||
# /usr/bin/${CTARGET}-<tool>
|
||||
# /usr/bin/${CHOST}/${CTARGET}/lib/ldscrips
|
||||
# /usr/include/
|
||||
#
|
||||
# Note [tooldir hack for ldscripts]
|
||||
# ---------------------------------
|
||||
# Build system does not allow ./configure to tweak every location
|
||||
# we need for slotting binutils hence all the shuffling in
|
||||
# src_install(). This note is about SCRIPTDIR define handling.
|
||||
#
|
||||
# SCRIPTDIR defines 'ldscripts/' directory location. SCRIPTDIR value
|
||||
# is set at build-time in ld/Makefile.am as: 'scriptdir = $(tooldir)/lib'
|
||||
# and hardcoded as -DSCRIPTDIR='"$(scriptdir)"' at compile time.
|
||||
# Thus we can't just move files around after compilation finished.
|
||||
#
|
||||
# Our goal is the following:
|
||||
# - at build-time set scriptdir to point to symlinked location:
|
||||
# ${TOOLPATH}: /usr/${CHOST} (or /usr/${CHOST}/${CTARGET} for cross-case)
|
||||
# - at install-time set scriptdir to point to slotted location:
|
||||
# ${LIBPATH}: /usr/$(get_libdir)/binutils/${CTARGET}/${PV}
|
||||
Reference in New Issue
Block a user